Block Back Key in Msgbox

[Roger Garstang]

I have in my keypress event a check for the Back key and a confirmation of Yes or No. If the ans = DialogResponse.NEGATIVE I return True and abort the back. I don't even have a False since it isn't needed like other examples here show with the full if/then/else.

While the MsgBox is showing though the Back key can still be pressed and the app exits without even answering the msgbox. Is there a way to block this? ProgressDialogShow2 has an option to ignore back, but I'm not seeing one in either msgbox...do we need a msgbox3?

The whole purpose of the box is to confirm an accidental press...which could occur twice in a row.

 

[NJDude]

Even if you don't use CANCEL you can still trap it:

Sub Activity_KeyPress(KeyCode As Int) As Boolean

    If KeyCode = KeyCodes.KEYCODE_BACK Then
    
       Selection = Msgbox2("Exit the app?", "Confirmation", "Yes", "", "No", Null)
       
       Select Selection
       
              Case DialogResponse.POSITIVE
              
                   Activity.Finish
                   
              Case DialogResponse.CANCEL
              
                   Return True
                   
              Case DialogResponse.NEGATIVE
              
                   Return True
       
       End Select
    
    End If
    
End Sub

Here you will have to answer either YES or NO to exit, pressing the BACK button will just continue running the app.

 

[Roger Garstang]

Figures it would be something that simple. Changed the If to:
If ans = DialogResponse.NEGATIVE or ans = DialogResponse.CANCEL Then Return True

Something to add to the Beginner's Tip Section- Cancel = Back

I might have to look at the actual values and improve that with some type of bit compare I always hate having an If with two ='s.

 

[Roger Garstang]

If ans < -1 Then Return True

Works.

 

[NJDude]

There's always more than 1 way to skin a cat.

 

[Roger Garstang]

Yup-
If KeyCode = KeyCodes.KEYCODE_BACK AND Msgbox2("Are you sure you wish to Exit?", "Confirmation", "Yes", "", "No", Null) < -1 Then Return True

 

[Mahares]

Hre is another way to skin NJDude's cat, very similar to his and avoids the double equals Roger is concerned about.

Sub Activity_KeyPress(KeyCode As Int) As Boolean
      Dim Selection As Short
    If KeyCode = KeyCodes.KEYCODE_BACK Then    
       Selection = Msgbox2("Exit application?".ToUpperCase, "C o n f i r m a t i o n", "Yes", "", "No", Null)       
       Select Selection   
              Case DialogResponse.POSITIVE              
                   Activity.Finish                   
              Case DialogResponse.CANCEL, DialogResponse.NEGATIVE 
                   Return True                      
       End Select   
    End If   
End Sub

 

[NJDude]

Ok, one more way to skin that pesky cat:

Sub Activity_KeyPress(KeyCode As Int) As Boolean

    If Msgbox2("Exit app?", "Exit", "Yes", "", "No", Null) = DialogResponse.POSITIVE Then Activity.Finish Else Return True

End Sub

Or:

Sub Activity_KeyPress(KeyCode As Int) As Boolean

    If Msgbox2("Exit app?", "Exit", "Yes", "", "No", Null) = -1 Then Activity.Finish Else Return True

End Sub

 

[Roger Garstang]

What are the advantages of using activity.finish vs just letting it close? I thought it let's the OS close when it wants too, so no difference. There was another command to force closing right away, but not recommended, so I can't even remember what it was without docs in front of me.

 

[NJDude]

Activity.Finish closes the activity, now ExitApplication ends the application and stops the process, this is not recommended is better to let the OS to do it.

 

[Mahares]

If Activity.Finish is of concern, you can replace it here with Return False. See below. NJ, you got more pesky cats to skin.

Sub Activity_KeyPress(KeyCode As Int) As Boolean
      Dim Selection As Short
    If KeyCode = KeyCodes.KEYCODE_BACK Then    
       Selection = Msgbox2("Exit application?".ToUpperCase, "C o n f i r m a t i o n", "Yes", "", "No", Null)       
       Select Selection   
              Case DialogResponse.POSITIVE                                
                   Return False 
'                   Activity.Finish                   
              Case DialogResponse.CANCEL, DialogResponse.NEGATIVE 
                   Return True                      
       End Select   
    End If   
End Sub

 

[Gargoyle]

I've been trying this on my app, it displays the msgbox but then quits straight out and you don't have time to give a response.

Any suggestions or additions needed?

(P.S. I'm using B4A 2.02)

Thanks.

 

[Gargoyle]

I've been trying this on my app, it displays the msgbox but then quits straight out and you don't have time to give a response.

After a lot of :BangHead:, I managed to solve my problem...
(Additions/adaptations)

Sub Process_Globals
   Dim exitdelay As Timer
   exitdelay.Initialize("exitdelay",10)
End Sub

Sub Activity_Pause (UserClosed As Boolean)
   'added to END of Sub - seems to be needed.
   If UserClosed Then
      Activity.Finish
   End If
End Sub

Sub Activity_KeyPress(KeyCode As Int) As Boolean
   If KeyCode = KeyCodes.KEYCODE_BACK Then
      exitdelay.Enabled = True
      Return True
   End If
End Sub

Sub exitdelay_tick
   exitdelay.Enabled = False
   If Msgbox2("Exit app?", "Exit", "Yes", "", "No", Null) = -1 Then
      Activity_Pause (True)
   End If
End Sub

Hope this helps someone else.

 

[mred1]

After a lot of :BangHead:, I managed to solve my problem...
(Additions/adaptations)

Sub Process_Globals
   Dim exitdelay As Timer
   exitdelay.Initialize("exitdelay",10)
End Sub

Sub Activity_Pause (UserClosed As Boolean)
   'added to END of Sub - seems to be needed.
   If UserClosed Then
      Activity.Finish
   End If
End Sub

Sub Activity_KeyPress(KeyCode As Int) As Boolean
   If KeyCode = KeyCodes.KEYCODE_BACK Then
      exitdelay.Enabled = True
      Return True
   End If
End Sub

Sub exitdelay_tick
   exitdelay.Enabled = False
   If Msgbox2("Exit app?", "Exit", "Yes", "", "No", Null) = -1 Then
      Activity_Pause (True)
   End If
End Sub

Hope this helps someone else.

 

[mred1]

Thank you very much for this! Although I have been frying many other fish prior to deploying my app soon, this is actually all I was looking for (for quite sometime now), and saved it as my last issue on my dog fooding list. A simple way to determine if the end-user acidently depressed the back key (among a few other things). I believe that many others have been asking for this simple answer, and getting more complex answers than necessary. Thanks again.

 

[DonManfred]

Wrong thread.
You always should create a new thread for any new question.
Especially If the thread is four years old

 

[mred1]

Wrong thread.
You always should create a new thread for any new question.
Especially If the thread is four years old

It wasn't a question, but feedback from an old post from someone that gave me resolution while researching all (old and new) posts?