B4J Question How to get WebView 'Page Title'

[SackMcNuts]

Hello,

Does anybody know how to get the Current Page Title from a WebView. This was accomplished in b4a by using the 'WebViewsExtender' Library. Here is the b4a code used from the OAuth example which is my ultimate goal.

Sub wv_PageFinished (Url As String)

    If Url.StartsWith("https://accounts.google.com/o/oauth2/approval") Then
        Dim wv As WebView
        wv = Sender
        Dim w As WebViewXtender
        Dim result As String
        result = w.getTitle(wv)
        wv.RemoveView 'remove the WebView
        If result.StartsWith("Success code") Then
            AuthorizationCode = result.SubString("Success code=".Length)
            GetAccessToken
        Else
            Log("Error: " & result)
            ToastMessageShow(result, True)
        End If
    End If
   
End Sub

Thanks!

 

[Daestrum]

Look at this thread - how to get data from a web page - it may help.
http://www.b4x.com/android/forum/threads/extract-values-from-website.41155/#post-247818

Near the bottom Erel explains how to use HttpUtils2 to get the data.

 

[rwblinn]

Hi,

this Sub gets the title.

Sub getWebPageTitle(wv As WebView) As String
  Dim result As String = ""
  Try
    ' Get the webview
    Dim joWV As JavaObject = wv
    ' Get the webengine from the webview using method getEngine
    Dim joWE As JavaObject = joWV.RunMethod("getEngine", Null)
    ' Obtain the page title from the webengine javaobject using method getTitle
    result = joWE.RunMethod("getTitle", Null)
  Catch
    result = LastException.Message
  End Try
  Return result
End Sub

Example usage:

Private wvwMain As WebView
MainForm.Title = getWebPageTitle(wvwMain)

Here a B4J HOWTO example project using JavaObject Methods with a WebView.