Android Tutorial HttpUtils - Android web services are now simple!

Status
Not open for further replies.
OkHttpUtils2 is now available. OkHttpUtils2 is an improved version and is recommended for new projects. You shouldn't use HttpUtils (v1)!

HttpUtils is made of a code module and a service module. These two modules make it very simple to download online resources and upload data.

The advantages of using HttpUtils are:
  • Much simpler than working with HttpClient directly.
  • Handles parallel calls efficiently and correctly (protects from RejectedExecutionException exceptions).
  • Downloads are not affected by the activity life cycle.
Using HttpUtils

A simple example of downloading a page and returning the page as string:
B4X:
Sub Globals
 Dim b4a As String
 b4a = "http://www.basic4ppc.com"
End Sub

Sub Activity_Create (FirstTime As Boolean)
 HttpUtils.CallbackActivity = "Main" 'Current activity name.
 HttpUtils.CallbackJobDoneSub = "JobDone"
 HttpUtils.Download("Job1", b4a)
End Sub

Sub JobDone (Job As String)
 Dim s As String
 If HttpUtils.IsSuccess(b4a) Then
  s = HttpUtils.GetString(b4a)
 End If
End Sub
First we configure the callback subs. Then we call HttpUtils.Download or HttpUtils.DownloadList. These calls submit a job request to HttpUtils.
A job is made of one or more links.
HttpUtils raises two types of events while processing a job. The UrlDone event is raised for each successful download with the downloaded url and the JobDone event is raised when the whole job finishes.
You cannot submit a new job while a current job is running (though a job can contain many links).

We have three ways to access a downloaded resource:
  • HttpUtils.GetString(Url As String) - Returns the resource as string
  • HttpUtils.GetBitmap(Url As String) - Returns the resource as bitmap
  • HttpUtils.GetInputStream(Url As String) - Returns an InputStream which allows you to manually read the downloaded resource.
These three methods should only be called after the job is done or inside the UrlDone event sub (for that specific Url).
After downloading a resource the Url serves as the key for that resource.

Inside JobDone event sub you should call HttpUtils.IsSuccess before accessing any Url as it is possible that some or all of the downloads have failed. This is not necessary in UrlDone event as UrlDone is called for each successful download.

Second example:
In this example we first download an image and set it as the activity background. Then we download another 6 Urls and print the last one as string. The code for this example is attached.
B4X:
Sub Process_Globals
    Dim ImageUrl As String
    ImageUrl = "http://www.basic4ppc.com/android/images/logo2.png"
    Dim Job2Links As List
End Sub

Sub Globals

End Sub

Sub Activity_Create(FirstTime As Boolean)
    HttpUtils.CallbackActivity = "Main"
    HttpUtils.CallbackJobDoneSub = "JobDone"
    HttpUtils.CallbackUrlDoneSub = "UrlDone"
    Job2Links.Initialize
    Job2Links.AddAll(Array As String( _
        "http://www.google.com", "http://www.yahoo.com", _
        "http://www.bing.com", "http://www.cnn.com", _
        "http://www.twitter.com", "http://www.facebook.com"))
  
    HttpUtils.Download("Job1", ImageUrl)
End Sub

Sub Activity_Resume
    'Check whether a job has finished while the activity was paused.
    If HttpUtils.Complete = True Then JobDone(HttpUtils.Job)
End Sub
Sub UrlDone(Url As String)
    Log(Url & " done")
End Sub
Sub JobDone (Job As String)
    Select Job
        Case "Job1"
            If HttpUtils.IsSuccess(ImageUrl) Then
                Dim b As Bitmap
                b = HttpUtils.GetBitmap(ImageUrl)
                Activity.SetBackgroundImage(b)
            End If
            'Start the second job
            HttpUtils.DownloadList("Job2", Job2Links)
        Case "Job2"
            For i = 0 To HttpUtils.Tasks.Size - 1
                link = HttpUtils.Tasks.Get(i)
                Log(link & ": success=" & HttpUtils.IsSuccess(link))
            Next
            If HttpUtils.IsSuccess("http://www.google.com") Then
                Log(HttpUtils.GetString("http://www.google.com"))
            End If
    End Select
    HttpUtils.Complete = False 'Turn off the complete flag so we won't handle it again if the activity is resumed.
End Sub
What happens when the user presses on the Home key during a download?
The download will complete successfully (we are using a service for this).
However your activity will be paused and the UrlDone and JobDone events will not fire.

When our activity is resumed we should check if we missed anything. This is done with this code:
B4X:
Sub Activity_Resume
    'Check whether a job has finished while the activity was paused.
    If HttpUtils.Complete = True Then JobDone(HttpUtils.Job)
End Sub
We are calling JobDone ourselves if needed.
In Sub JobDone we reset the Complete flag so we know that this job was handled.
UrlDone event should be considered a "nice to have" feature. Your code should be prepared to handle the case where some UrlDone events were missed due to the activity being paused.

The FlickrViewer example was rewritten and the attached code uses this module.
In this example we first go to the "main" page. In this page we find 9 links to 9 images. We submit a second job with all these links.

We show each image as soon as it is ready by using the UrlDone event.
In JobDone we check if all Urls were handled. We can miss some of these events if the activity was paused during download.

flickr_viewer1.png



HttpUtils, similar to DBUtils, aims to simplify common tasks that many developers face. The code is available for you. So changes can be made as needed.

Updates:

V1.04 - The service is now destroyed when it is no longer needed and recreated when needed again. This version also fixes a bug that caused the application to crash if the service was started after the process was killed.

V1.02 - PostString, PostBytes and PostFile methods added to HttpUtils.
These methods make it easy to post data to a web service (using http POST method).
The behavior of these methods is similar to Download and DownloadList. JobDone event is raised after the response from the server is read.

The latest version (v1.04) is included in HttpUtilsExample.
 

Attachments

  • FlickrViewer.zip
    9.8 KB · Views: 2,901
  • HttpUtilsExample.zip
    7.8 KB · Views: 5,272
Last edited:

Vidar

Member
Licensed User
I love you :D

Just been playing around with the httpclient.

Thanks for this :)
 

Inman

Well-Known Member
Licensed User
Fantastic!

Does this mean even if I send a relatively large list of urls (say 50) to HttpUtils, it will handle the queue correctly and download completely while avoiding RejectedExecutionException completely?
 

ietv

Member
Licensed User
I get an error with this:

java.lang.RuntimeException: Error loading Bitmap.

Debugger finds it in HttpUtilsService at

b = LoadBitmap(HttpUtilsService.TempFolder, SuccessfulUrls.Get(URL))

For what it's worth, I got it to run last night on a different emulator, but when I tried to modify the url to a different page, I got an array out of bounds error (I think, I'm going by memory).
 

Vidar

Member
Licensed User
@Cynikal

No, these are modules, which include some kind of helper-functions. You can add them to your project with: "Project --> Add existing module" and use it, like Erel has described it in his example
 

Kiffi

Well-Known Member
Licensed User
Hello Erel,

works like a charm. Thanks a lot! :sign0098:

Greetings ... Kiffi
 

Erel

Administrator
Staff member
Licensed User
I get an error with this:

java.lang.RuntimeException: Error loading Bitmap.

Debugger finds it in HttpUtilsService at

b = LoadBitmap(HttpUtilsService.TempFolder, SuccessfulUrls.Get(URL))
This can happen if the image file is corrupted or it is not an image file at all. It can also happen when you try to load a large bitmap and there is not enough memory.
 

Cynikal

Member
Licensed User
Getting an error when trying to use the 'GetString'

An error has occured in sub: httputils_issuccess (java line: 113)
java.lang.RuntimeException: Object should first be initialized (Map)
 

NeoTechni

Well-Known Member
Licensed User
Minor alteration:

In HttpUtilsService, inside Sub ProcessNextTask
Line: 41
Replace: req.InitializeGet(link)
With: req.InitializeGet(link.Replace(" ", "%20"))

This stops an error when the URL has a space in it.
 

xalion

Member
Licensed User
I use result=HttpUtils.GetString(loginurl)
and my result is chinese, so result is can't readble.
when I use old response.GetString("UTF8"), it works ok.
can you check it?
 

Erel

Administrator
Staff member
Licensed User
The problem is that the response is not encoded in UTF8.
When you call Response.GetString the encoding parameter is only used if there is no encoding information in the response. In your case there is so the call response.GetString("UTF8") worked correctly.

You should use HttpUtils.GetInputStream together with a TextReader that is initialized with the correct encoding.
 
Status
Not open for further replies.
Top