B4J Question Return RBG from ColorPicker

[Mashiane]

Hi

I have noted that the colour picker has an Alpha property but no RBG properties. How can I return the RBG properties from it? or anyone with a method to convert hex values to rgb for B4J?

Thanks

 

[rwblinn]

Hi,

an option is to make use of a JavaObject (requires JavaObject Library) to convert the selected ColorPicker Paint Value into R-G-B.
Example Sub:

'Get the color given as paint as a string in R-G-B
'Example result is 26-51-153
Sub GetColorRGB(ColorValue As Paint) As String
    Dim result As String = ""
    Dim joCV As JavaObject = ColorValue
    Dim R As Double = joCV.RunMethod("getRed", Null)   
    Dim G As Double = joCV.RunMethod("getGreen", Null)   
    Dim B As Double = joCV.RunMethod("getBlue", Null)
    result = Round(R * 255) & "-" & Round(G * 255) & "-" & Round(B * 255)
    Return result
End Sub

 

[Erel]

Another option which is similar to how it is done in B4A and B4i:

Sub GetARGB(ColorValue As Paint) As Int()
    Dim Color As Int = fx.Colors.To32Bit(ColorValue)
    Dim res(4) As Int
    res(0) = Bit.UnsignedShiftRight(Bit.And(Color, 0xff000000), 24)
    res(1) = Bit.UnsignedShiftRight(Bit.And(Color, 0xff0000), 16)
    res(2) = Bit.UnsignedShiftRight(Bit.And(Color, 0xff00), 8)
    res(3) = Bit.And(Color, 0xff)
    Return res
End Sub

 

[Mashiane]

Another option which is similar to how it is done in B4A and B4i:

Sub GetARGB(ColorValue As Paint) As Int()
    Dim Color As Int = fx.Colors.To32Bit(ColorValue)
    Dim res(4) As Int
    res(0) = Bit.UnsignedShiftRight(Bit.And(Color, 0xff000000), 24)
    res(1) = Bit.UnsignedShiftRight(Bit.And(Color, 0xff0000), 16)
    res(2) = Bit.UnsignedShiftRight(Bit.And(Color, 0xff00), 8)
    res(3) = Bit.And(Color, 0xff)
    Return res
End Sub

Hi Erel

In your example, I assume that R = res(0), G = res(1) and B = res(2) and A = (3), is that correct?

 

[Mashiane]

Hi,

an option is to make use of a JavaObject (requires JavaObject Library) to convert the selected ColorPicker Paint Value into R-G-B.
Example Sub:

'Get the color given as paint as a string in R-G-B
'Example result is 26-51-153
Sub GetColorRGB(ColorValue As Paint) As String
    Dim result As String = ""
    Dim joCV As JavaObject = ColorValue
    Dim R As Double = joCV.RunMethod("getRed", Null) 
    Dim G As Double = joCV.RunMethod("getGreen", Null) 
    Dim B As Double = joCV.RunMethod("getBlue", Null)
    result = Round(R * 255) & "-" & Round(G * 255) & "-" & Round(B * 255)
    Return result
End Sub

Thanks a lot!

 

[Erel]

In your example, I assume that R = res(0), G = res(1) and B = res(2) and A = (3), is that correct?

No. The order is the same as the sub name: A, R, G and B.