Android Question Advanced Search - help needed

Private Sub B4XPage_Created (Root1 As B4XView)
    Root = Root1
    Root.LoadLayout("MainPage")

'    Type sortPair(sortfield As Long, fromvalue As String, tovalue As String)
    Dim series As List = File.ReadList(File.DirApp, "xseries.txt")
    Dim sortList As List
    sortList.Initialize
    For Each s As String In series
        Dim v() As String = Regex.Split("-", s)
        sortList.add(CreatesortPair(convert(v(0)), v(0), v(1)))
    Next
    sortList.SortType("sortfield", True)
   
    Dim found As List = findAll("H2312", sortList)
    For Each s As String In found
        Log(s)
    Next
'    H2312    H0001-H3000

    Dim found As List = findAll("0L213", sortList)
    For Each s As String In found
        Log(s)
    Next
'    0L213    0K001-0N718
'    0L213    0001X-1706X

End Sub

Private Sub convert(s As String) As Long
    'convert to base 37
    Dim charset As String = ".0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ"
    Dim resultN As Long
    Dim multiplier As Long = 1
    For i = s.Length - 1 To 0 Step -1
        resultN = resultN + multiplier * charset.indexOf(s.CharAt(i))
        multiplier = charset.Length * multiplier
    Next
    Return resultN
End Sub

Private Sub findAll(s As String, sortlist As List) As List
    Dim found As List
    found.Initialize
    Dim lookfor As Long = convert(s)

    'find first item that has sequence number > lookfor
    'for simplicity I am doing a linear seach, but a binary search would be appropriate here
    For i = 0 To sortlist.Size - 1
        Dim sp As sortPair = sortlist.Get(i)
        If sp.sortfield > lookfor Then Exit            'gone too far
    Next
   
    'working backwards from "too far"
    For j = i - 1 To i - 10 Step -1
        Dim sp As sortPair = sortlist.Get(j)
        If lookfor > convert(sp.tovalue) Then Exit
        found.Add(s & TAB & sp.fromvalue & "-" & sp.toValue)
    Next
    Return found
End Sub

Private Sub B4XPage_Created (Root1 As B4XView)
    Root = Root1
    Root.LoadLayout("MainPage")
    Dim seriesList As List = File.ReadList(File.DirApp, "codeseries.txt")
    Dim markTime As Long = DateTime.now
    Log(BittingTables("H2312", seriesList))         'ignore
    Log(BittingTables("X1234", seriesList))         'ignore
    Log(BittingTables("25AE579", seriesList))         'ignore
    Log(DateTime.now - markTime)                    ' 3 milliseconds
End Sub

Private Sub BittingTables(KeyCode As String, seriesList As List) As List
    Dim result As List
    result.Initialize
    For Each s As String In seriesList
        Dim v() As String = Regex.Split("-", s)
        If KeyCode.CompareTo(v(0)) >=0 And KeyCode.CompareTo(v(1)) <=0 Then result.Add(s)
    Next
    'there could be duplicates series (old and new) they are marked with *
    result.Sort(False)
    For i = 1 To result.Size - 1
        Dim t As String = result.get(i)
        If t = result.Get(i-1) Then result.Set(i, t & "*")
    Next
    Return result
End Sub