Third example. Similar to the Android example.
Please try it and report any issues encountered: http://www.b4x.com/android/files/FlickrViewer.jar
The code:
Please try it and report any issues encountered: http://www.b4x.com/android/files/FlickrViewer.jar
The code:
B4X:
#Region Project Attributes
#MainFormWidth: 500
#MainFormHeight: 500
#End Region
Sub Process_Globals
Private MainUrl As String = "http://www.flickr.com/explore/interesting/7days/"
Private fx As JFX
Private MainForm As Form
Dim btnConnect As Button
Dim ivs As List
Private imageLinks As List
Private downloader As ImageDownloader
Dim PB1 As ProgressIndicator
Dim GridPane As Node
End Sub
Sub AppStart (Form1 As Form, Args() As String)
MainForm = Form1
MainForm.Title = "Flickr Viewer"
MainForm.RootPane.LoadLayout("1") 'Load the layout file.
MainForm.Show
imageLinks.Initialize
ivs.Initialize
For Each n As Node In MainForm.RootPane.GetAllViewsRecursive
If n Is ImageView Then
n.MouseCursor = fx.Cursors.HAND
ivs.Add(n)
End If
Next
ResetImagesBackground
PB1.Visible = False
End Sub
Sub btnConnect_Action
ResetImagesBackground
Dim job As HttpJob
job.Initialize("Main page", Me)
job.Download(MainUrl)
PB1.Visible = True
btnConnect.Enabled = False
End Sub
Sub JobDone(Job As HttpJob)
Select Job.JobName
Case "Main page"
HandleMainPage(Job)
End Select
Job.Release
End Sub
'Parse the main page and find the 9 image links
Sub HandleMainPage (Job As HttpJob)
imageLinks.Clear
Dim downloader As ImageDownloader
downloader.Initialize
If Job.Success = False Then
Log("Error downloading main page.")
Return
End If
Dim m As Matcher = Regex.Matcher("data-track=\""thumb\""[^>]+><img src=\""([^""]+)\""", Job.GetString)
Do While m.Find
imageLinks.Add(m.Group(1))
Loop
DownloadImages
End Sub
Sub DownloadImages
Dim m As Map
m.Initialize
For i = 0 To Min(imageLinks.Size, ivs.Size) - 1
m.Put(ivs.Get(i), imageLinks.Get(i))
Next
downloader.Download(m)
btnConnect.Enabled = True
PB1.Visible = False
End Sub
Sub ResetImagesBackground
For Each iv As ImageView In ivs
iv.SetImage(Null)
Next
End Sub
Sub ImageView_MouseClicked (EventData As MouseEvent)
Dim iv As ImageView = Sender
Dim img As Image = iv.GetImage
If img.IsInitialized Then
Dim frm As Form2
frm.Initialize(img, MainForm)
frm.Show
End If
End Sub
Sub GridPane_HeightChanged (Height As Double)
For Each iv As ImageView In ivs
iv.Height = Height / 3
Next
End Sub
Sub GridPane_WidthChanged (Width As Double)
For Each iv As ImageView In ivs
iv.Width = Width / 3
Next
End Sub
