Android Question B4XPages.ShowPage acts as a Resumable Sub but actually isn't

[Alessandro71]

consider the following sample code

B4XPages.ShowPage("ConfigWizardPage")
ConfigWizardHasBeenShown = True

code flow continues immediately after line 1
line 2 is executed just after ShowPage as been called just as ShowPage woud be a Resumable Sub
my intended code flow would be just like

Wait For (B4XPages.ShowPage("ConfigWizardPage")) Complete (unused As Boolean)
ConfigWizardHasBeenShown = True

so that line 2 would be executed after the "ConfigWizardPage" has been shown and the ClosePage(Me) from that page has been called
is there a simple way to achieve that?

 

[toby]

so that line 2 would be executed after the "ConfigWizardPage" has been shown and the ClosePage(Me) from that page has been called
is there a simple way to achieve that?

This is because B4XPages.ShowPage() is not defined as a resumableSub; it returns a string instead

 

[Erel]

You can add a Show sub to the second page which returns a ResumableSub. In most cases it will be simpler to raise an event when the second page "completes" and wait for that event.

 

[Alessandro71]

Searching for examples of raising an event and wait for it elsewhere, in the forum, right now, with little success…

 

[Erel]

Check the attached B4A example.

Public Sub Show(Callback As Object)
    mCallback = Callback
    B4XPages.ShowPage(B4XPages.GetPageId(Me))
End Sub

Private Sub B4XFloatTextField1_EnterPressed
    RaiseEvent(B4XFloatTextField1.Text)
    B4XPages.ClosePage(Me)
End Sub

Private Sub B4XPage_CloseRequest As ResumableSub
    Log("CloseRequest")
    RaiseEvent("")
    Return True
End Sub

Private Sub RaiseEvent(Text As String)
    CallSubDelayed2(mCallback, "InputPage_Complete", Text)
End Sub

Usage:

Private Sub Button1_Click
    ip.Show(Me)
    Wait For InputPage_Complete (Text As String)
    B4XPages.SetTitle(Me, Text)
End Sub