Android Code Snippet NB6 class - additional functions

wes58 · Mar 31, 2019

I wrote in my previous post that the method Colorize to change background color of the notification doesn't work. I have tested it today and it seems that it works fine, see attached picture.
I used the code like this:

B4X:

n.Color(Colors.Blue)
n.Colorized(True)

wes58 · Apr 3, 2019

Users can modify some settings for notification channels, including behaviors such as importance, vibration and alert sound. So If you'd like to know the settings a user has applied to your notification channels, you can get the settings for a specific channel (you have to provide a channelID) or get settings for all notification channels.
If you detect a channel setting that you believe inhibits the intended behavior for your app, you can suggest the user change it and provide an action to open the Channel settings (functions in post #1)
You can also show on the screen (icons/text) what the settings are when you create a channel and after the user changes any of the settings.

Here are 2 functions that may be useful if you want to check if the user has changed the Notification Channel settings.

B4X:

Sub GetNotifChannel(channelID As String)   
    Dim Channel As JavaObject
    Dim m As Map
    m.Initialize
    Channel.InitializeContext
    m = Channel.RunMethod("mGetNotifChannel", Array(channelID))
    If Not(m.IsInitialized) Then        'return from call = Null
        ToastMessageShow("Invalid Channel Id "  & channelID, True)
        Return
    End If
    Dim Id As String  = m.Get("Id")
    Dim importance As Int = m.Get("Importance")
    Dim lightcolor As Int = m.Get("Lightcolor")
    Dim shouldVibrate As Boolean = m.Get("Vibrate")
    Dim shouldShowLight As Boolean = m.Get("ShowLight")
    Dim sound As Uri = m.Get("Sound")
    Dim canShowBadge As Boolean = m.Get("ShowBadge")
    Dim canBypassDnd As Boolean = m.Get("BypassDnd")

    Log("Channel Id = " & Id)
    Log("Importance = " & importance)
    Log("Light color = " & lightcolor)
    Log("Vibrate = " & shouldVibrate)
    Log("Show Light " & shouldShowLight)
    Log("Show Badge = " & canShowBadge)
    Log("Bypass the 'Do Not Disturb' = " & canBypassDnd)
    Log("Sound URI = " & sound)
End Sub

Public Sub GetAllNotifChannells
    Dim l As List
    Dim i As Int
    Dim Channel As JavaObject
    Channel.InitializeContext
    l.Initialize
    l = Channel.RunMethod("mGetNotifChannels", Null)
    If Not(l.IsInitialized) Then        'list wac set to Null because couldn't get notidication channels
        ToastMessageShow("Error getting Notification Channels", True)
        Return
    End If
    For i = 0 To l.Size-1
        Dim m As Map
        m.Initialize
        m = l.Get(i)
        Dim Id As String  = m.Get("Id")
        Dim importance As Int = m.Get("Importance")
        Dim lightcolor As Int = m.Get("Lightcolor")
        Dim shouldVibrate As Boolean = m.Get("Vibrate")
        Dim shouldShowLight As Boolean = m.Get("ShowLight")
        Dim sound As Uri = m.Get("Sound")
        Dim canShowBadge As Boolean = m.Get("ShowBadge")
        Dim canBypassDnd As Boolean = m.Get("BypassDnd")

        Log("item " & i )
        Log("Channel Id = " & Id)
        Log("Importance = " & importance)
        Log("Light color = " & lightcolor)
        Log("Vibrate = " & shouldVibrate)
        Log("Show Light " & shouldShowLight)
        Log("Show Badge = " & canShowBadge)
        Log("Bypass the 'Do Not Disturb' = " & canBypassDnd)
        Log("Sound URI = " & sound)
    Next
End Sub

#if JAVA
import java.util.ArrayList;
import android.content.Context;
import android.app.NotificationManager;
import android.app.NotificationChannel;
import android.os.Build;
import java.util.List;
import android.net.Uri;
import anywheresoftware.b4a.objects.collections.Map;

public  List<Object> mGetNotifChannels() {
    if (Build.VERSION.SDK_INT >= Build.VERSION_CODES.O) {
        Context context = BA.applicationContext;  
        NotificationManager notificationManager = (NotificationManager) context.getSystemService(Context.NOTIFICATION_SERVICE);
        if (notificationManager == null) {
             return null;
        }
        List<NotificationChannel> l = notificationManager.getNotificationChannels();
        List<Object> lMap = new ArrayList();
        int i;
        for(i = 0; i < l.size()-1; ++i){
            NotificationChannel channel = l.get(i);
            Object o = getMap(channel);
               lMap.add(o);
        }
        return lMap;  
    }
    return null;
}  

public Object mGetNotifChannel(String channelId){
    if (Build.VERSION.SDK_INT >= Build.VERSION_CODES.O) {
        Context context = BA.applicationContext;  
        NotificationManager notificationManager = (NotificationManager) context.getSystemService(Context.NOTIFICATION_SERVICE);
        if (notificationManager == null) {
             return null;
        }
        NotificationChannel channel =  notificationManager.getNotificationChannel(channelId);
        if(channel == null){
            return null;
        }
        return getMap(channel);
    }
    return null;
}

public Object getMap(NotificationChannel channel){
    String Id = channel.getId();
    int importance = channel.getImportance();
    int lightcolor = channel.getLightColor();
    Boolean shVibrate = channel.shouldVibrate();
    Boolean shShowLight = channel.shouldShowLights();
    Boolean canShowBadge = channel.canShowBadge();
    Boolean canBypassDnd = channel.canBypassDnd();
    Uri sound = channel.getSound();
    anywheresoftware.b4a.objects.collections.Map map = new anywheresoftware.b4a.objects.collections.Map();
    map.Initialize();
    map.Put("Id", Id);
    map.Put("Sound", sound);
    map.Put("Importance", importance);
    map.Put("Lightcolor", lightcolor);
    map.Put("Vibrate", shVibrate);
    map.Put("ShowLight", shShowLight);
    map.Put("ShowBadge", canShowBadge);
    map.Put("BypassDnd", canBypassDnd);
    return map.getObject();
}
#End If

wes58 · Apr 7, 2019

Maybe it is not directly related to NB6, but that's when I found the need for this function.
I had the following situation: I selected a notification sound via ringtone picker and stored the name and the uri of the selected sound.
After firmware update of the phone, or using different phone, I found out that the uri I stored doesn't correspond to the name of the notification sound.
That's why, I needed a function where I can find the uri of the notification sound if I know the name, and without using again the ringtone picker.

Here is a example of the sub and java function:

B4X:

Sub getURI(title As String)
    Dim jo As JavaObject

    jo.InitializeContext 
    uri = jo.RunMethod("getSoundUri", Array(title))
    If Not(uri.IsInitialized) Then                    'not found
        ToastMessageShow("Notification sound " & title & " not found", True)
    Else
        'do something with the uri
    End If
End Sub

#if JAVA
import android.content.Context;
import android.database.Cursor;
import android.media.RingtoneManager;
import android.net.Uri;
import android.provider.MediaStore;

//Note that the list of ringtones/notification sounds available will differ depending on whether
//you have in the Manifest.permission.READ_EXTERNAL_STORAGE permission.

public Uri getSoundUri(String ringtoneTitle) {
    Uri foundUri;
    Context context = BA.applicationContext;
    RingtoneManager rm = new RingtoneManager(context);
    rm.setType(RingtoneManager.TYPE_NOTIFICATION);        //notification sounds
//    rm.setType(RingtoneManager.TYPE_RINGTONE);            //ringtone sounds
    Cursor cursor = rm.getCursor();
    cursor.moveToFirst();

    while (cursor.moveToNext()) {
          if(ringtoneTitle.compareToIgnoreCase(cursor.getString(RingtoneManager.TITLE_COLUMN_INDEX)) == 0) {
            int ringtoneID = cursor.getInt(RingtoneManager.ID_COLUMN_INDEX);
            foundUri = rm.getRingtoneUri(cursor.getPosition());   
//            String name = cursor.getString(RingtoneManager.TITLE_COLUMN_INDEX);
//            BA.Log(name);
//            BA.Log(foundUri.toString());
            return foundUri;
        }   
    }
    return null;
}
#End If

Note that the list of ringtone/notification sounds available will differ depending on whether you have the Manifest.permission.READ_EXTERNAL_STORAGE permission.

wes58 · Apr 26, 2019

Create a Group of Notifications
Starting from Android 7.0 you can display related notifications in a group. You can read more about it on https://developer.android.com/training/notify-user/group.html and https://blog.danlew.net/2017/02/07/correctly-handling-bundled-android-notifications/
Android Grouped Notifications are handy when you have too many notifications stacked vertically. Groupped Notifications collapse them all into a single notification with a group summary set on the group notification. This saves us from scrolling through all the notifications. Also, if you receive many single notifications at once, instead of getting multiple noisy notification sounds, group notifications would give a single notification sound.

To build a grouped notification you have to create a Summary Notification and a number of Single Notifications. Whenever you send a Single notification you have to send a Summary notification as well.
Every notification will have the same group key.
When a new notification is added, it gets merged in the group with the matching group key.

Here is an example code to do it:
Run sub Send_Group_Notification a couple of times to create a number of notifications. They will be grouped in one notification which, when expanded, shows all notifications.

The sub Cancel_Notification cancels one notification at a time.
The problem (Google's design) with canceling notifications by code is, that when you remove the last notification, the Summary notification stay on. That's why you need to keep track of the number of notifications issued and removed. When there is only one left, and it is cleared you have to clear the Summary notification.
This issue, is only when you clear notification by code.
When you swipe the notification to clear it, all of them (including Summary) will be cleared.

B4X:

Sub Process_Globals

  
    Public const grpNotifyID As Int = 101
    Public const sumNotifyID As Int = 100
    Public const groupID As String = "test_group"
    Public const groupName As String = "Test Group"
    Public const grpChnId As String = "chnTest"
    Public const grpChnName As String = "Test Channel"
    Public const sumChnId As String = "chnSummary"
    Public const sumChnName As String = "Summary Channel"
    Public curNotifyID As Int = grpNotifyID
  
    Public remNotifyID As Int = 0
  
End Sub

'Each time you send a notification you have to send a Group Summary notification as well.
Sub Send_Group_Notification
    Dim n As NB6
    n.Initialize(grpChnId, grpChnName, "DEFAULT").AutoCancel(True).SmallIcon(smiley)
    n.SetDefaults(True, True, True)
    'create notification channel group
    n.NotificationChannelGroup(groupID, groupName)
  
    n.GroupSet(groupID)
    n.GroupSummary(False)
    Dim contentText As String = "Message with ID " & curNotifyID
    Dim contentTitle As String = "New Group Message"
    n.Build(contentTitle, contentText, "Tag", Me).Notify(curNotifyID)
'you have to send notification with different ID each time
    curNotifyID = curNotifyID + 1
  
    Dim nSum As NB6
    nSum.Initialize(sumChnId, sumChnName, "LOW").AutoCancel(True).SmallIcon(smiley)
    'we don't need any notification sound/vibration
    nSum.SetDefaults(False, False, False)
    'create notification channel group
    nSum.NotificationChannelGroup(groupID, groupName)
  
    nSum.GroupSet(groupID)
    nSum.GroupSummary(True)
  
    Dim contentText As String = "Summary Notification"
    Dim contentTitle As String = "Group " & grpChnName
    nSum.Build(contentTitle, contentText, "Tag", Me).Notify(sumNotifyID)
End Sub

Sub Cancel_Notification
    If remNotifyID = 0 Then
        remNotifyID = curNotifyID
    End If
    If remNotifyID = grpNotifyID Then
        Return
    End If
  
    'clear notification
    Dim ctx As JavaObject
    ctx.InitializeContext
    ToastMessageShow("cancelled notification with ID " & remNotifyID, False)
    Dim manager As JavaObject = ctx.RunMethod("getSystemService", Array("notification"))
    manager.RunMethod("cancel", Array(remNotifyID))
  
    remNotifyID = remNotifyID - 1
    'you need to clear the Summary Notification when you clear the last one.
    If remNotifyID = grpNotifyID Then
        ToastMessageShow("cancelled group summary notification", False)
        manager.RunMethod("cancel", Array(sumNotifyID))
        curNotifyID = grpNotifyID
        remNotifyID = 0
    End If
End Sub

And here are the changes to the NB6 class module:
Add to Class_Globals:

B4X:

Sub Class_Globals

    Private NotifChannelGroup As JavaObject    
    Private groupID As String
End Sub

Add in NB6 class, to Sub Build, the marked lines:

B4X:

Public Sub Build (ContentTitle As Object, ContentText As Object, Tag As String, Activity As Object) As Notification

...
...
        If IsChannel Then
            Dim manager As JavaObject = ctxt.RunMethod("getSystemService", Array("notification"))

'*** add lines below
            'create notification Channel Group
            If NotifChannelGroup.IsInitialized Then
                 manager.RunMethod("createNotificationChannelGroup", Array(NotifChannelGroup))
                 Channel.RunMethod("setGroup", Array(groupID))
            End If
'*** end changes

           manager.RunMethod("createNotificationChannel", Array(Channel))      
        End If
        Return NotificationBuilder.RunMethod("build", Null)
    End If
End Sub

Add the following subs in NB6 class

B4X:

'Create Group for Notification Channel
'grpID - id of the group created with sub NotificationChannelGroup
'grpName - Name of the Group displayed on the App. Notification Setting screen
Public Sub NotificationChannelGroup(grpID As String, grpName As String)
    If IsChannel Then
        groupID = grpID
        NotifChannelGroup.InitializeNewInstance("android.app.NotificationChannelGroup", Array(grpID, grpName))
    End If
End Sub

'Set the group for the Notification
'groupID - id of the group created the same as created with sub NotificationChannelGroup
Public Sub GroupSet(grpID As String) As NB6
    If IsBuilder Then
        NotificationBuilder.RunMethod("setGroup", Array(grpID))
    End If
    Return Me
End Sub

'Set group summary
True - only for Summary Notifications
'False - false for other notifications in a group
Public Sub GroupSummary(isGroupSummary As Boolean) As NB6
    If IsBuilder Then
        NotificationBuilder.RunMethod("setGroupSummary", Array(isGroupSummary))
    End If
    Return Me
End Sub

Mike1970 · Nov 21, 2019

wes58 said:
Dim nSum As NB6
nSum.Initialize(sumChnId, sumChnName, "LOW").AutoCancel(True).SmallIcon(smiley)
'we don't need any notification sound/vibration
nSum.SetDefaults(False, False, False)
'create notification channel group
nSum.NotificationChannelGroup(groupID, groupName)

nSum.GroupSet(groupID)
nSum.GroupSummary(True)

Dim contentText As String = "Summary Notification"
Dim contentTitle As String = "Group " & grpChnName
nSum.Build(contentTitle, contentText, "Tag", Me).Notify(sumNotifyID)

Awesome work.
But i didn’t understand what is supposed to do this part.
I tried to delete it to figure out what it does but there are no changes.

wes58 · Nov 22, 2019

You can read more about it on https://developer.android.com/training/notify-user/group.html
Here are two pictures attached showing what it does:
It creates summary notifications (bundled notification)- see pic01.png - small number '2" indicates that there are two notifications. When you click on the text at the top of the notification, it will expand showing details of the two notifications - see pic02.png.

Mike1970 · Nov 22, 2019

wes58 said:
When you click on the text at the top of the notification, it will expand showing details of the two notifications

Yeah, but those notification are created by using this part

Dim n As NB6
n.Initialize(grpChnId, grpChnName, "DEFAULT").AutoCancel(True).SmallIcon(smiley)
n.SetDefaults(True, True, True)
'create notification channel group
n.NotificationChannelGroup(groupID, groupName)

n.GroupSet(groupID)
n.GroupSummary(False)
Dim contentText As String = "Message with ID " & curNotifyID
Dim contentTitle As String = "New Group Message"
n.Build(contentTitle, contentText, "Tag", Me).Notify(curNotifyID)
'you have to send notification with different ID each time
curNotifyID = curNotifyID + 1

My doubt is with the Summary (the only thing i noticed is this: pic1)
But in notification center i have only this (pic2) nothing regarding summary

wes58 · Nov 22, 2019

You have explanation in the comments in the code "create notification channel group
The attached picture shows what I have in my application. When you click on it it will show the channel settings for group notifications (on the right of the photo).

For you application, you can see it when you go to Settings-App. And find you application, and in "App Info" click on "Notifications". You should see the channel for group notification with the name that you have defined.

Mike1970 · Nov 23, 2019

wes58 said:
You have explanation in the comments in the code "create notification channel group
The attached picture shows what I have in my application. When you click on it it will show the channel settings for group notifications (on the right of the photo).

For you application, you can see it when you go to Settings-App. And find you application, and in "App Info" click on "Notifications". You should see the channel for group notification with the name that you have defined.

Ok.. it's slightly different for me. Thanks anyway

blikkk · Dec 21, 2020

Dear Dev!

3. Delete Channel with specified channelID - unfortunately, this only removes the channel from the App. Notification Settings. When you re-initialise it, it will show up with the settings
that the channel was created with before.

For 2 and 3 you have to be careful, because that ChannelId that you supply to the NB6 Initialize Sub is not the ChannelId that is used when the Channel is created.
There is a line of code in this sub that changes it.
ChannelId = ChannelId & "_" & ImportanceLevel
I think that this line should be removed.
Here is the code:

B4X:

Sub deleteChannel(chID As String)
Dim jo As JavaObject
If chID = "" Then
ToastMessageShow("Invalid channel ID", False)
Return
End If
jo.InitializeContext ' = Me
jo.RunMethod("DelNotifChannel", Array(chID))
End Sub

Sub OpenAppNotifSet
Dim jo As JavaObject
jo.InitializeContext
jo.RunMethod("openAppSettings", Null)
End Sub

Sub OpenNotifChannelSet(chID As String)
Dim jo As JavaObject
If chID = "" Then
ToastMessageShow("Invalid channel ID", False)
Return
End If
jo.InitializeContext
jo.RunMethod("openChannelSettings", Array(chID))
End Sub

#if JAVA
import android.content.Context;
import android.app.NotificationManager;
import android.content.Intent;
import static android.provider.Settings.ACTION_CHANNEL_NOTIFICATION_SETTINGS;
import static android.provider.Settings.ACTION_APP_NOTIFICATION_SETTINGS;
import static android.provider.Settings.EXTRA_APP_PACKAGE;
import static android.provider.Settings.EXTRA_CHANNEL_ID;

public void DelNotifChannel(String id){
Context context = BA.applicationContext;
NotificationManager notificationManager = (NotificationManager) context.getSystemService(Context.NOTIFICATION_SERVICE);
notificationManager.deleteNotificationChannel(id);
}

public void openAppSettings(){
Context context = BA.applicationContext;
Intent intent = new Intent(ACTION_APP_NOTIFICATION_SETTINGS);
intent.putExtra(EXTRA_APP_PACKAGE, context.getPackageName());
startActivity(intent);
}

public void openChannelSettings(String id){
Context context = BA.applicationContext;
Intent intent = new Intent(ACTION_CHANNEL_NOTIFICATION_SETTINGS);
intent.putExtra(EXTRA_APP_PACKAGE, context.getPackageName());
intent.putExtra(EXTRA_CHANNEL_ID, id);
startActivity(intent);
}
#End If

Because the only way to change some channel settings (like notificaion light on/off, color, vibration pattern) it is to unistall the app, or clear app data.
The workaround (if necessary), to modify all channel settings and give the user option to modify them in your app seetings page could be like this:
1. User opens Notification Settings page in your app and makes changes.
2. If the changes are made. Delete the channel.
3. Initialize new channel with new ID and old name and description. A channel ID can be changed for example like this "sms1", "sms2", "sms3" etc.
The only drawback is, that the size of app data increases with every addition of the new channel.

Compiling generated Java code. Error
javac 1.8.0_271
src\b4a\example3\nb6.java:782: error: cannot find symbol
startActivity(intent);
^
symbol: method startActivity(Intent)
location: class nb6
1 error

What's the mistake?

wes58 · Dec 8, 2021

blikkk said:
Dear Dev!

Compiling generated Java code. Error
javac 1.8.0_271
src\b4a\example3\nb6.java:782: error: cannot find symbol
startActivity(intent);
^
symbol: method startActivity(Intent)
location: class nb6
1 error

What's the mistake?

I know it is very late, but if someone else has this error you should replace:
startActivity(intent);
with
context.startActivity(intent);

Android Code Snippet NB6 class - additional functions

wes58

Active Member

Attachments

wes58

Active Member

wes58

Active Member

wes58

Active Member

Mike1970

Well-Known Member

wes58

Active Member

Attachments

Mike1970

Well-Known Member

Attachments

wes58

Active Member

Attachments

Mike1970

Well-Known Member

blikkk

New Member

wes58

Active Member