Android Question Generate sound frequency

[Sub7]

Hello, is possible generate sounds frequency on the fly with b4a?
something this (is dog whistle)
https://play.google.com/store/apps/details?id=proffesionals.dog.whistle.cat.repelent

Thanks

 

[Erel]

Yes. You can use AudioStreamer from the Audio library:

Sub Process_Globals
   Dim streamer As AudioStreamer
   Dim timer1 As Timer
   Dim freq As Int = 500
End Sub

Sub Globals
   
End Sub

Sub Activity_Create(FirstTime As Boolean)
   If FirstTime Then
     streamer.Initialize("streamer", 11025, True, 16, streamer.VOLUME_MUSIC)
     streamer.StartPlaying
     timer1.Initialize("timer1", 1000)
   End If
   timer1.Enabled = True
End Sub

Sub Timer1_Tick
   Log(freq)
   Beep(1000, freq)
   freq = freq + 500
End Sub

Sub Beep(Duration As Int, Frequency As Int)
   Dim dur As Double = Duration / 10000
   Dim sampleRate As Int = 11025
   Dim numSamples As Int = sampleRate * dur
   Dim snd(2 * numSamples) As Byte
   For i = 0 To numSamples - 1
     Dim d As Double = Sin(2 * cPI * i / (sampleRate / Frequency))
     Dim val As Short = d * 32767
     snd(i * 2) = Bit.AND(0xff, val)
     snd(i * 2 + 1) = Bit.ShiftRight(Bit.AND(0xff00, val), 8)
   Next
   streamer.Write(snd)
End Sub

Sub Activity_Pause (UserClosed As Boolean)
   timer1.Enabled = False
End Sub

 

[Sub7]

Wow! Thank you! it's possible to record and save the generated sound in real time?
or better store the informations somewhere like an array so the sound can be reproduced in any device which has the same library (app)?

 

[Erel]

You can write the bytes to a file and then read them from a file.

 

[Sub7]

Great thank you again.

 

[giacomo-italy]

Hi,
I would like to know if there is a way to change the frequency (and volume) of the sound while the sound is generated? (To get an effect like theremin).
In the example I can change the frequency only after it has passed the duration of the sound, so that the frequency can not change continuously ..
thank you.

 

[Beja]

Change Frequency before each Duration.

 

[giacomo-italy]

Change Frequency before each Duration.

thanks for the reply,
but is exactly what I wrote that i can do but i do not want to do:
I need that frequency and amplitude can be changed while the sound is generated.

I tried to reduce the duration of the sound and insert the frequency change in a loop of the same duration,
but the resulting sound is choppy and full of disturbs as 'click' and noise...

There is an alternative way to change frequency and amplitude while the sound is generated?

 

[Beja]

In this case, you may need two passes.. one to generate, record and concatenate the frequencies, and the other to play or save it.

 

[giacomo-italy]

I created a new thread for this question:

https://www.b4x.com/android/forum/t...ency-in-a-continuos-manner.51428/#post-322063

If someone wants to contribute ideas or comments are welcome, and thank him.