B4J Code Snippet [B4J] Text Input Dialog with JavaObject

For use JavaFx TextInput Dialog

TextInputDialog (JavaFX 8)

        Dim jo As JavaObject
        jo.InitializeNewInstance("javafx.scene.control.TextInputDialog", Null)
        jo.RunMethodJO("setTitle", Array As String("Sample Title"))
        jo.RunMethod("setHeaderText", Array As String("Sample Text"))
        

        If jo.RunMethodjo("showAndWait", Null).RunMethod("isPresent", Null)=True Then
            'ok button pressed
            Dim txt As String=jo.RunMethodJO("getEditor", Null).RunMethod("getText", Null)
            Log(txt)
        End If

 

[peacemaker]

Good example, thanks !
The default value:

jo.InitializeNewInstance("javafx.scene.control.TextInputDialog", Array As String(DefaultValue_or_Variable))

 

[aeric]

Label on the left of the Text Input (Content Text):

jo.RunMethod("setContentText", Array As String("Value:"))

JavaFX TextInputDialog | o7planning.org

o7planning.org

 

[Star-Dust]

It is possible to insert more fields, but also ComboBox etc ..

Get more than two inputs in a JavaFX Dialog

I trying to build the text dialog where the user enter the event name, event size, and the selected the venue. My problem is in how can I gather the inputs; here what I did so far: eventName = new

stackoverflow.com

How would you do it in B4J?

Dim dialog As JavaObject
dialog.InitializeNewInstance("javafx.scene.control.TextInputDialog", Null)
dialog.RunMethodJO("setTitle", Array As String("Sample Title"))
dialog.RunMethod("setHeaderText", Array As String("Sample Text"))

Dim dialogPane As JavaObject = dialog.RunMethod("getDialogPane",Null)
Dim BasePane As Pane = dialogPane.RunMethod("getContent",Null)
Dim T2 As TextField
T2.Initialize("T2")
T2.Text="Hallo"
BasePane.AddNode(T2,0,0,-1,-1)

If dialog.RunMethodjo("showAndWait", Null).RunMethod("isPresent", Null)=True Then
        'ok button pressed
        Dim txt As String=dialog.RunMethodJO("getEditor", Null).RunMethod("getText", Null)
        Log(T2.Text & " " & txt)
End If

 

[Star-Dust]

Items in Hidden panel

Dim dialog As JavaObject
dialog.InitializeNewInstance("javafx.scene.control.TextInputDialog", Null)
dialog.RunMethodJO("setTitle", Array As String("Sample Title"))
dialog.RunMethod("setHeaderText", Array As String("Sample Text"))

Dim dialogPane As JavaObject = dialog.RunMethod("getDialogPane",Null)
Dim BasePane As Pane = dialogPane.RunMethod("getContent",Null)

Dim L1 As Label
L1.Initialize("")
L1.Text = " First row"
BasePane.AddNode(L1,0,0,-1,-1)

Dim T2 As TextField
T2.Initialize("T2")
T2.Text="Hallo"
'BasePane.AddNode(T2,0,0,-1,-1)

Dim L2 As Label
L2.Initialize("")
L2.Text = " Second row"

Dim PaneNew As Pane
PaneNew.Initialize("")
PaneNew.AddNode(L2,12,0,90,-1)
PaneNew.AddNode(T2,120,0,-1,-1)
PaneNew.prefHeight=50

dialogPane.RunMethod("setExpanded",Array(True))
dialogPane.RunMethod("setExpandableContent",Array(PaneNew))

PS.: If you want to customize the main panel and not the extendable one, just assign the panel like this

dialogPane.RunMethod("setContent",Array(PaneNew))

 

[Star-Dust]

Another solution

Obviously, the creation of the panel and the TextView can be done more easily from Design than from code.
ATTENTION: Using the XUI VIEW dialogs you will do before, this is just an example

Private Sub PanelTwoField
            Dim dialog As JavaObject
            dialog.InitializeNewInstance("javafx.scene.control.TextInputDialog", Null)
            dialog.RunMethodJO("setTitle", Array As String("Ttile"))
            dialog.RunMethod("setHeaderText", Array As String("HEADER"))
    
            Dim dialogPane As JavaObject = dialog.RunMethod("getDialogPane",Null)

            Dim PaneNew As B4XView = xui.CreatePanel("")  ' Create New Panel
            Dim txt1 As B4XView =CreateTextField("txt1",row(1)) ' Add Text Filed 1
            Dim txt2 As B4XView =CreateTextField("txt2",row(2)) ' Add Text Filed 2
            PaneNew.AddView(CreateLabel("Field 1"),10,10,80,30) ' Add Laleb 1
            PaneNew.AddView(txtModello,100,10,220,30) 
            PaneNew.AddView(CreateLabel("Field 2"),10,50,80,30) ' Add Laleb 1
            PaneNew.AddView(txtDescrizione,100,50,220,30)
            PaneNew.Height=90
            dialogPane.RunMethod("setContent",Array(PaneNew)) ' Add Panel with 2 field
            
            If dialog.RunMethodjo("showAndWait", Null).RunMethod("isPresent", Null)=True Then
                log(txt1.Text)
                Log(txt2.Text)
            End If
End Sub

Private Sub CreateLabel(Text As String) As B4XView
    Dim L As Label 
    L.Initialize("")
    L.Text=Text
    Return L
End Sub

Private Sub CreateTextField(EventN As String, Text As String) As B4XView
    Dim T As TextField
    T.Initialize(EventN)
    T.Text=Text
    Return t
End Sub

 

[Star-Dust]

Dialog with password

Dim dialog As JavaObject
    dialog.InitializeNewInstance("javafx.scene.control.TextInputDialog", Null)
    
    'Dim F As Form =  dialog.RunMethodJO("getDialogPane",Null).RunMethodJO("getScene",Null).RunMethodJO("getWindow",Null).
    dialog.RunMethodJO("getDialogPane",Null).RunMethodJO("getScene",Null).RunMethodJO("getWindow",Null).RunMethodJO("setAlwaysOnTop",Array(True))
    dialog.RunMethodJO("setTitle", Array As String("Security"))
    dialog.RunMethod("setHeaderText", Array As String("Insert Password"))
    
    Dim dialogPane As JavaObject = dialog.RunMethod("getDialogPane",Null)
    Dim BasePane As Pane = dialogPane.RunMethod("getContent",Null)
    Dim Pss As TextField
    BasePane.RemoveAllNodes
    Pss.InitializePassword("Pss")
    BasePane.AddNode(Pss,0,0,-1,-1)

    If dialog.RunMethodjo("showAndWait", Null).RunMethod("isPresent", Null)=True Then
        log(Pss.Text)
    End If

 

[Johan Hormaza]

Dialog with password

Dim dialog As JavaObject
    dialog.InitializeNewInstance("javafx.scene.control.TextInputDialog", Null)
   
    'Dim F As Form =  dialog.RunMethodJO("getDialogPane",Null).RunMethodJO("getScene",Null).RunMethodJO("getWindow",Null).
    dialog.RunMethodJO("getDialogPane",Null).RunMethodJO("getScene",Null).RunMethodJO("getWindow",Null).RunMethodJO("setAlwaysOnTop",Array(True))
    dialog.RunMethodJO("setTitle", Array As String("Security"))
    dialog.RunMethod("setHeaderText", Array As String("Insert Password"))
   
    Dim dialogPane As JavaObject = dialog.RunMethod("getDialogPane",Null)
    Dim BasePane As Pane = dialogPane.RunMethod("getContent",Null)
    Dim Pss As TextField
    BasePane.RemoveAllNodes
    Pss.InitializePassword("Pss")
    BasePane.AddNode(Pss,0,0,-1,-1)

    If dialog.RunMethodjo("showAndWait", Null).RunMethod("isPresent", Null)=True Then
        log(Pss.Text)
    End If

How can I place the logo in the Dialog window