Android Question I can't use JSONParser correctly

[ema01]

Hello,
i'm receiving a json string;

{"data":[{"id":"my-id","name":"my-name","status":"ACTIVE","createdAt":"some-time","updatedAt":"some-time"}],"meta":{"page":1,"limit":20,"total":1,"totalPages":1}}

prettified:

{
  "data":[
    {
      "id":"my-id",
      "name":"my-name",
      "status":"ACTIVE",
      "createdAt":"some-time",
      "updatedAt":"some-time"
    }
  ],
  "meta":{
    "page":1,
    "limit":20,
    "total":1,
    "totalPages":1
  }
}

I'm interested in the "data" field, which contains and array of objects. However i've resorted to parsing the data manually.
I initialized a JsonParser on the raw string, and read a map using NextObject.

Now i get a map that has a single "data" key, and the content of "data" as a value. However, the string is not Json Anymore.
This is what i get:

[{id=my-id, name=my-name, status=ACTIVE, createdAt=some-time, updatedAt=some-time}]

and that can't be read with JsonParser anymore.
As i said, i've already written a parser function, but i want to see what i'm doing wrong.

Thanks for helping

 

[aeric]

You mean you write your own Json Parser function?
Why you want to do that? B4X has Json library you can use.
It is also very easy to cast the child items as Map or List straight away.

Private Sub TestJsonParser
    Dim s As String = $"{"data":[{"id":"my-id","name":"my-name","status":"ACTIVE","createdAt":"some-time","updatedAt":"some-time"}],"meta":{"page":1,"limit":20,"total":1,"totalPages":1}}"$
    Dim m As Map = s.As(JSON).ToMap
    For Each k As String In m.Keys
        Log(k)
    Next
    Log(" ")
    Dim data As List = m.Get("data")
    For Each m2 As Map In data
        For Each k2 As String In m2.Keys
            Log($"${k2} -> ${m2.Get(k2)}"$)
        Next
    Next
End Sub

Output:

data
meta
 
id -> my-id
name -> my-name
status -> ACTIVE
createdAt -> some-time
updatedAt -> some-time

 

[William Lancee]

https://www.b4x.com/android/forum/threads/convert-collections-to-json-and-vice-versa.132678/

 

[ema01]

Dim m As Map = s.As(JSON).ToMap

I didn't realize i could just cast the string as JSON!
Nor that every JSON Object was then interpreted as a Map
Thanks

 

[aeric]

I didn't realize i could just cast the string as JSON!
Nor that every JSON Object was then interpreted as a Map
Thanks

It also works with Lists.

 

[aeric]

that can't be read with JsonParser anymore.

Let say you assigned the value as String, you can still parse it but use parser.NextArray instead of parser.NextObject

Dim data As String = m.Get("data")
Dim parser As JSONParser
parser.Initialize(data)
Dim list1 As List = parser.NextArray
Log(list1)
Dim map1 As Map = list1.Get(0)
Log(map1)

Output:

(ArrayList) [{id=my-id, name=my-name, status=ACTIVE, createdAt=some-time, updatedAt=some-time}]
(MyMap) {id=my-id, name=my-name, status=ACTIVE, createdAt=some-time, updatedAt=some-time}

 

[DonManfred]

Nor that every JSON Object was then interpreted as a Map

No. If it starts with a { it is a MAP. If it starts with a [ it is a LIST.