Android Question MultiPart SMS Sent Status

BarryW · Jan 6, 2017

B4X:

   Sub SendLargeSms(Destination As String, Message As String)
   Dim r As Reflector
   r.Target = r.RunStaticMethod("android.telephony.SmsManager", "getDefault", Null, Null)
   Dim parts As Object
   parts = r.RunMethod2("divideMessage", Message, "java.lang.String")
   r.RunMethod4("sendMultipartTextMessage", _
      Array As Object(Destination, Null, parts, Null, Null), _
      Array As String("java.lang.String", "java.lang.String", _
         "java.util.ArrayList", "java.util.ArrayList", "java.util.ArrayList"))
End Sub

I used this code to send large sms and it works fine.
My question is how to capture the sent status of this code whether it success or not.
Tnx.

Erel · Jan 6, 2017

Try this:

B4X:

Sub SendLargeSms(Destination As String, Message As String)
   Dim ctxt As JavaObject
   ctxt.InitializeContext
   Dim smsManager As JavaObject
   smsManager = smsManager.InitializeStatic("android.telephony.SmsManager").RunMethod("getDefault", Null)
   Dim parts As Object = smsManager.RunMethod("divideMessage", Array(Message))
   Dim i As Intent
   i.Initialize("b4a.smssent", "")
   Dim pi As JavaObject
   pi = pi.InitializeStatic("android.app.PendingIntent").RunMethod("getBroadcast", _
     Array(ctxt, 0, i, 134217728))
   Dim al As JavaObject
   al.InitializeNewInstance("java.util.ArrayList", Null)
   al.RunMethod("add", Array(pi))
   smsManager.RunMethod("sendMultipartTextMessage", Array(Destination, Null, parts, al, Null))
End Sub

Listen to the SmsSentStatus event with PhoneEvents.

It should be raised after the first part was sent.

BarryW · Jan 6, 2017

Erel said:

Try this:

B4X:

Sub SendLargeSms(Destination As String, Message As String)
   Dim ctxt As JavaObject
   ctxt.InitializeContext
   Dim smsManager As JavaObject
   smsManager = smsManager.InitializeStatic("android.telephony.SmsManager").RunMethod("getDefault", Null)
   Dim parts As Object = smsManager.RunMethod("divideMessage", Array(Message))
   Dim i As Intent
   i.Initialize("b4a.smssent", "")
   Dim pi As JavaObject
   pi = pi.InitializeStatic("android.app.PendingIntent").RunMethod("getBroadcast", _
     Array(ctxt, 0, i, 134217728))
   Dim al As JavaObject
   al.InitializeNewInstance("java.util.ArrayList", Null)
   al.RunMethod("add", Array(pi))
   smsManager.RunMethod("sendMultipartTextMessage", Array(Destination, Null, parts, al, Null))
End Sub

Listen to the SmsSentStatus event with PhoneEvents.

It should be raised after the first part was sent.

But how to captude tsaka last part

Erel · Jan 8, 2017

Did it you test it? Does it work?

BarryW · Jan 30, 2017

Hi sir any updates on how to capture the last message sent status?

DonManfred · Jan 30, 2017

BarryW said:
Hi sir any updates on how to capture the last message sent status?

Did you answered Erels questions? See the post before yours; you get some questions...

BarryW · Feb 13, 2017

Hi. I already tried Erel's code and it successfully get the first sent message event. Now how to adjust to code getting the last message event status. Tnx.

Erel · Feb 13, 2017

You need to add the PendingIntent as the last element instead of the first.

Try this:

B4X:

Sub SendLargeSms(Destination As String, Message As String)
    Dim ctxt As JavaObject
    ctxt.InitializeContext
    Dim smsManager As JavaObject
    smsManager = smsManager.InitializeStatic("android.telephony.SmsManager").RunMethod("getDefault", Null)
    Dim parts As JavaObject = smsManager.RunMethod("divideMessage", Array(Message))
    Dim i As Intent
    i.Initialize("b4a.smssent", "")
    Dim p As Phone 'Phone library
    Dim flags As Int = 134217728
    If p.SdkVersion >= 31 Then
        flags = Bit.Or(33554432, flags)
    End If
    Dim pi As JavaObject
    pi = pi.InitializeStatic("android.app.PendingIntent").RunMethod("getBroadcast", _
     Array(ctxt, 0, i, flags))
    Dim size As Int = parts.RunMethod("size", Null)
    Dim al As JavaObject
    al.InitializeNewInstance("java.util.ArrayList", Null)
    For ii = 0 To size - 2
        al.RunMethod("add", Array(Null))
    Next
    al.RunMethod("add", Array(pi))
    smsManager.RunMethod("sendMultipartTextMessage", Array(Destination, Null, parts, al, Null))
End Sub

BarryW · Feb 14, 2017

Hi. i check your code and you add function getSize then a loop adding a null? What is the difference between your first code that gets the event on first msg to send and that code? Tnx

Erel · Feb 14, 2017

The intent will be sent when the last part is sent instead of the first one.

Android Question MultiPart SMS Sent Status

BarryW

Active Member

Erel

B4X founder

BarryW

Active Member

Erel

B4X founder

BarryW

Active Member

DonManfred

Expert

BarryW

Active Member

Erel

B4X founder

BarryW

Active Member

Erel

B4X founder

Similar Threads

Android Question MultiPart SMS Sent Status

Active Member

B4X founder

Active Member

B4X founder

Active Member

Expert

Active Member

B4X founder

Active Member

B4X founder

Similar Threads

Privacy & Transparency

Privacy & Transparency