B4J Question ping an ip

[bogdanc]

I working on my app.
I need to check that network location (networks devices) is reachable.
I saw similar thread here and I know that I can run the shell command.
I would like to have it in the background and have respond that is reachable or not.

 

[Erel]

You need to use jShell and run ping. It will run in the background.

 

[bogdanc]

You need to use jShell and run ping. It will run in the background.

Will give me a respond means : reachable or not?

 

[giga]

You could use this:
https://www.b4x.com/android/forum/threads/b4j-how-to-ping.37755/#post-223020

 

[eurojam]

see this example, you can play around with it....

Sub AppStart (Args() As String)
   
   Dim shl As Shell
   shl.Initialize("shl", "ping", Array As String("localhost"))
   shl.WorkingDirectory = "C:"
   shl.Run(60000) 'set a timeout of 60 seconds
   StartMessageLoop
End Sub

Sub shl_ProcessCompleted (Success As Boolean, ExitCode As Int, StdOut As String, StdErr As String)
   If Success And ExitCode = 0 Then
     Log("Success")
     Log(StdOut)
   Else
     Log("Error: " & StdErr & ExitCode)
   End If
   ExitApplication
End Sub

 

[rwblinn]

Small enhancement covering Ping Count = 1 with Windows and Linux/Mac

Sub Ping(ipaddress As String)
    Dim shl As Shell
    Dim lstParams As List: lstParams.Initialize
    Try
        Dim os As String = GetSystemProperty("os.name", "").ToLowerCase
        If os.Contains("win") Then
            'Windows
            lstParams.Add("-n")
        Else
            'Linux and Mac
            lstParams.Add("-c")
        End If
        lstParams.Add("1")
        lstParams.Add(ipaddress)
        shl.Initialize("shl", "ping", lstParams)
        shl.WorkingDirectory = File.DirApp
        shl.Run(-1)
    Catch
        Log(LastException.Message)
    End Try
End Sub

Sub shl_ProcessCompleted (Success As Boolean, ExitCode As Int, StdOut As String, StdErr As String)
   If Success And ExitCode = 0 Then
     Log("Success: Host is reachable.")
  Else
       Log("Error: Host is NOT reachable.")
  End If
  ExitApplication
End Sub

 

[jmon]

You can try jShellQueue : https://www.b4x.com/android/forum/threads/jshellqueue.58315/
The example provided pings some IPs