Android Question [SOLVED]Implementing Timer in LibGdx

[abhishek007p]

Hi! Anyone can help me on how will i implement a timer in LibGdx?..

Im creating a countdown timer that i will use on the game im creating.

Sub Globals
Dim COUNTDOWN_TIMER As Int = 60 'equiv. to 60 seconds
End Sub

Then on every timer tick (per second), subtract 1 to COUNTDOWN_TIMER

thanks,
---------------------------------------
EDIT: Found the Solution
---------------------------------------

Spoiler: Heres my libgdx timer class

#Event: Tick()

'Class module
Private Sub Class_Globals
    Public Interval As Float = 1            'Interval in seconds
    Private DELTA_TIME_COUNTER As Float = 0
    Private ParentActivity As Object
    Private EventHandle As String
End Sub

'Initializes the object. You can add parameters to this method if needed.
'Example: Initialize(Me, "Timer", 1)
Public Sub Initialize(mParent As Object, mEventHandle As String, mInterval As Float)
    ParentActivity = mParent
    Interval = mInterval
    EventHandle = mEventHandle
End Sub

Sub UpdateTimer(DeltaTime As Float)
    DELTA_TIME_COUNTER = DELTA_TIME_COUNTER + DeltaTime
    If DELTA_TIME_COUNTER >= Interval Then
        DELTA_TIME_COUNTER = 0
        If SubExists(ParentActivity, EventHandle & "_Tick") Then
            CallSub(ParentActivity, EventHandle & "_Tick")
        End If
    End If
End Sub

Sub FormatToTime(TimeInSeconds As Float) As String
    Dim s1 As String = NumberFormat(Floor(TimeInSeconds / 60), 2, 0)
    Dim s2 As String = NumberFormat(TimeInSeconds Mod 60, 2, 0)
    Return s1 & ":" & s2
End Sub

 

[Informatix]

In the render event, subtract lGdx.Graphics.DeltaTime from your timer (in milliseconds).

 

[abhishek007p]

In the render event, subtract lGdx.Graphics.DeltaTime from your timer (in milliseconds).

thanks, btw, is it possible if you can implement this class on libgdx? http://libgdx.badlogicgames.com/nightlies/docs/api/com/badlogic/gdx/utils/TimeUtils.html

or maybe just tell me on how i can extend the b4a gdx library? haha..

 

[Informatix]

thanks, btw, is it possible if you can implement this class on libgdx? http://libgdx.badlogicgames.com/nightlies/docs/api/com/badlogic/gdx/utils/TimeUtils.html

or maybe just tell me on how i can extend the b4a gdx library? haha..

You dont' need this class. You have already the B4A DateTime class.

 

[abhishek007p]

You dont' need this class. You have already the B4A DateTime class.

ohh.. right.. haha.. thanks..