iOS Question UserNotificationCenter - set interruptionLevel for time sensitive notifications

[Alexander Stolte]

In my app, I need a notification that is displayed on the lock screen and is not immediately pushed to the notification center. You can do this by declaring a notification as “time critical”. Now I don't know how to integrate the whole thing correctly with Native Object. My following code returns an Object was not initialized (NSObject) error.

UNNotificationInterruptionLevel | Apple Developer Documentation

Constants that indicate the importance and delivery timing of a notification.

developer.apple.com

UNNotificationInterruptionLevel.timeSensitive | Apple Developer Documentation

The system presents the notification immediately, lights up the screen, can play a sound, and breaks through system notification controls.

developer.apple.com

Public Sub CreateNotificationWithContent(Title As String, Body As String, Identifier As String, Category As String, MillisecondsFromNow As Long)
    Dim ln As NativeObject
    ln = ln.Initialize("UNMutableNotificationContent").RunMethod("new", Null)
    ln.SetField("title", Title)
    ln.SetField("body", Body)
    Dim n As NativeObject
    ln.SetField("sound", n.Initialize("UNNotificationSound").RunMethod("defaultSound", Null))
    Dim n2 As NativeObject
    ln.SetField("interruptionLevel", n2.Initialize("UNNotificationInterruptionLevel").RunMethod("UNNotificationInterruptionLevelTimeSensitive", Null)) 'Error - Object was not initialized (NSObject)
    If Category <> "" Then ln.SetField("categoryIdentifier", Category)
    Dim trigger As NativeObject
    trigger = trigger.Initialize("UNTimeIntervalNotificationTrigger").RunMethod("triggerWithTimeInterval:repeats:", Array(MillisecondsFromNow / 1000, False))
    Dim request As NativeObject
    request = request.Initialize("UNNotificationRequest").RunMethod("requestWithIdentifier:content:trigger:", _
       Array(Identifier, ln, trigger))
    Dim NotificationCenter As NativeObject
    NotificationCenter = NotificationCenter.Initialize("UNUserNotificationCenter").RunMethod("currentNotificationCenter", Null)
    NotificationCenter.RunMethod("addNotificationRequest:", Array(request))
End Sub

Thanks

 

[Erel]

Enums are constants and you need to do some work to get their actual value:

#if OBJC
 #import <UserNotifications/UserNotifications.h>
-(void) test {
    NSLog(@"%@", @(UNNotificationInterruptionLevelTimeSensitive));
}
#End If

Using OBJC to find the values of native constants

Apple documentation doesn't list the actual values of the various constants. These values are needed when calling native methods with NativeObject. You can use OBJC code to log these values: #if OBJC -(void) test { NSLog(@"%@", NSForegroundColorAttributeName); NSLog(@"%@"...

www.b4x.com

 ln.SetField("interruptionLevel", 2) 'UNNotificationInterruptionLevelTimeSensitive

 

[Alexander Stolte]

Thank you very much!
It works, the following still needs to be added to the project attributes:

#Entitlement: <key>com.apple.developer.usernotifications.time-sensitive</key><true/>

 

[Alexander Stolte]

All steps summarized in a separate thread:

UserNotificationCenter class - Time sensitive notifications

https://www.b4x.com/android/forum/threads/usernotificationcenter-class.117925/#content This is an addition to the UserNotificationCenter class. I need a notification that is displayed on the lock screen and is not immediately pushed to the notification center. You can do this by declaring a...

www.b4x.com