Android Question Wrong MaterialIcons ?

[Deleted member 103]

Hi,

Msgbox2("Die Datei wird gelöscht!", "Sind Sie sicher?", "Ja", "Nein","", TextToBitmap(Chr(0xE002), lblMaterialIcons, 26, Colors.White) )

The upper code should show this.

In my app but this is displayed, what can be wrong here?

 

[Erel]

Works fine here. Tested with this code:

Sub Activity_Click
   Msgbox2("asdasd", "asdasdasd", "ok", "", "", TextToBitmap(Chr(0xE002), 20))
End Sub

Sub TextToBitmap (s As String, FontSize As Float) As Bitmap
   Dim bmp As Bitmap
   bmp.InitializeMutable(32dip, 32dip)
   Dim cvs As Canvas
   cvs.Initialize2(bmp)
   Dim h As Double = cvs.MeasureStringHeight(s, Typeface.MATERIALICONS, FontSize)
   cvs.DrawText(s, bmp.Width / 2, bmp.Height / 2 + h / 2, Typeface.MATERIALICONS, FontSize, Colors.White, "CENTER")
   Return bmp
End Sub

 

[Deleted member 103]

Funny, in a different app works the code correctly, and not in this.

The SDK in the Manifest is the same.

<uses-sdk android:minSdkVersion="14" android:targetSdkVersion="22"/>

To this day I have had no problems with the code.

 

[Erel]

Test it with the code I posted.

 

[Deleted member 103]

Test it with the code I posted.

Ok, my mistake!
I had swapped MATERIALICONS with FONTAWESOME.
For this I have now improved the code.

Public Sub TextToBitmap (s As String, IsMaterialIcons As Boolean, FontSize As Float, color As Int) As Bitmap
    Dim bmp As Bitmap
    bmp.InitializeMutable(32dip, 32dip)
    Dim cvs As Canvas
    cvs.Initialize2(bmp)
    Dim h As Double
    If IsMaterialIcons Then
        h = cvs.MeasureStringHeight(s, Typeface.MATERIALICONS, FontSize)
        cvs.DrawText(s, bmp.Width / 2, bmp.Height / 2 + h / 2, Typeface.MATERIALICONS, FontSize, color, "CENTER")
    Else
        h = cvs.MeasureStringHeight(s, Typeface.FONTAWESOME, FontSize)
        cvs.DrawText(s, bmp.Width / 2, bmp.Height / 2 + h / 2, Typeface.FONTAWESOME, FontSize, color, "CENTER")
    End If
    Return bmp
End Sub

 

[Erel]

Slightly better:

Public Sub TextToBitmap (s As String, IsMaterialIcons As Boolean, FontSize As Float, color As Int) As Bitmap
   Dim bmp As Bitmap
   bmp.InitializeMutable(32dip, 32dip)
   Dim cvs As Canvas
   cvs.Initialize2(bmp)
   Dim h As Double
   Dim t As Typeface
   If IsMaterialIcons Then t = Typeface.MATERIALICONS Else t = Typeface.FONTAWESOME
   h = cvs.MeasureStringHeight(s, t, FontSize)
   cvs.DrawText(s, bmp.Width / 2, bmp.Height / 2 + h / 2, t, FontSize, color, "CENTER")
   Return bmp
End Sub