Android Tutorial Android Network Tutorial

Status
Not open for further replies.

Erel

Administrator
Staff member
Licensed User
This is an old tutorial. All new implementations of network solutions should be based on AsyncStreams.

The Network library allows you to communicate over TCP/IP with other computers or devices.
The Network library contains two objects. Socket and ServerSocket.
The Socket object is the communication endpoint. Reading and writing are done with Socket.InputStream and Socket.OutputStream.

ServerSocket is an object that listens for incoming connections. Once a connection is established an event is raised and a socket object is passed to the event sub. This socket will be used to handle the new client.

Client application
Steps required:
- Create and initialize a Socket object.
- Call Socket.Connect with the server address.
- Connection is done in the background. The Connected event is raised when the connection is ready or if it failed.
- Communicate with the other machine using Socket.InputStream to read data and Socket.OutputStream to write data.

Server application
Steps required:
- Create and initialize a ServerSocket object.
- Call ServerSocket.Listen to listen for incoming connections. This happens in the background.
- Once a connection is established the NewConnection event is raised and a Socket object is passes.
- Call ServerSocket.Listen if you want to accept more connections.
- Using the Socket object received, communicate with the client.

We will see two examples.
The first example connects to a time server and displays the current date and time as received from the server.

B4X:
Sub Process_Globals
    Dim Socket1 As Socket
End Sub

Sub Globals

End Sub

Sub Activity_Create(FirstTime As Boolean)
    Socket1.Initialize("Socket1")
    Socket1.Connect("nist1-ny.ustiming.org" , 13, 20000)
End Sub

Sub Socket1_Connected (Successful As Boolean)
    If Successful = False Then
        Msgbox(LastException.Message, "Error connecting")
        Return
    End If
    Dim tr As TextReader
    tr.Initialize(Socket1.InputStream)
    Dim sb As StringBuilder
    sb.Initialize
    sb.Append(tr.ReadLine) 'read at least one line
    Do While tr.Ready
        sb.Append(CRLF).Append(tr.ReadLine)
    Loop
    Msgbox("Time received: " & CRLF & sb.ToString, "")
    Socket1.Close
End Sub
We are creating a new socket and trying to connect to the server which is listening on port 13.
The next step is to wait for the Connected event.
If the connection is successful we create a TextReader object and initialize it with Socket1.InputStream. In this case we want to read characters and not bytes so a TextReader is used.
Calling tr.ReadLine may block. However we want to read at least a single line so it is fine.
Then we read all the other available lines (tr.Ready means that there is data in the buffer).



In the second application we will create a file transfer application, that will copy files from the desktop to the device.
The device will use a ServerSocket to listen to incoming connections.
Once a connection has been made, we will enable a timer. This timer checks every 200ms whether there is any data waiting to be read.

The file is sent in a specific protocol. First the file name is sent and then the actual file.
We are using a RandomAccessFile object to convert the bytes read to numeric values. RandomAccessFile can work with files or arrays of bytes, we are using the later in this case.
RandomAccessFile can be set to use little endian byte order. This is important here as the desktop uses this byte order as well.

The desktop example application was written with Basic4ppc.
Once connected the user selects a file and the file is sent to the device which saves it under /sdcard/android.
Both applications are attached.

Some notes about the code:
- The server is set to listen on port 2222.
The server displays its IP when it starts. The desktop client should use this IP address when connecting to a real device (this IP will not work with the emulator).
However if you work with the emulator or if your device is connected to the computer in debug mode you can use 'adb' to forward a desktop localhost port to the device.
This is done by issuing "adb forward tcp:5007 tcp:2222"
Now in the client code we should connect to the localhost ip with port 5007.
B4X:
Client.Connect("127.0.0.1", 5007)
Again if you are testing this application in the emulator you must first run this adb command. Adb is part of the Android SDK.

- Listening to connections:
B4X:
Sub Activity_Resume
        ServerSocket1.Listen
End Sub

Sub Activity_Pause (UserClosed As Boolean)
    If UserClosed Then
        Timer1.Enabled = False
        Socket1.Close
        ServerSocket1.Close 'stop listening
    End If
End Sub

Sub ServerSocket1_NewConnection (Successful As Boolean, NewSocket As Socket)
    If Successful Then
        Socket1 = NewSocket
        Timer1.Enabled = True
        InputStream1 = Socket1.InputStream
        OutputStream1 = Socket1.OutputStream
        ToastMessageShow("Connected", True)
    Else
        Msgbox(LastException.Message, "Error connecting")
    End If
    ServerSocket1.Listen 'Continue listening to new incoming connections
End Sub
In Sub Activity_Resume (which also called right after Activity_Create) we call ServerSocket.Listen and start listening to connections. Note that you can call this method multiple times safely.
In Sub Activity_Pause we close the active connection (if there is such a connection) and also stop listening. This only happens if the user pressed on the back key (UserClosed = True).
The ServerSocket will later be initialized in Activity_Create.

The server side application can handle new connections. It will just replace the previous connection with the new one.
The desktop client example application doesn't handle broken connections. You will need to restart it to reconnect.

Edit: It is recommended to use the new AsnycStreams object instead of polling the available bytes parameter with a timer. Using AsyncStreams is simpler and more reliable.
 

Attachments

Last edited:

schimanski

Well-Known Member
Licensed User
Hello Erel,

thanks for this network-lib. Together with agrahams threading-lib, my network-apps are running as good as under basic4ppc. :icon_clap: Respect!!

But I have two questions:

-I checked if the connection is successful with the following code, but when the connection isn't successful, I get an error, that the socket is not connected. It seems, that 'Successful' always is true:confused: I never get the msgbox 'not connected'.

-Is there a way to jump to the android-settings to switch the network on, like jumping to the GPS-settings as
StartActivity(GPS1.LocationSettingsIntent)?


B4X:
Sub Socket1_Connected (Successful As Boolean)
  If Successful Then
       main.filestreamRead=Socket1.InputStream 
       main.filestreamWrite=Socket1.OutputStream 
       ToastMessageShow("Connected!", True)
  Else
      Msgbox("Not Connected!","")
  End If
End Sub
 

Erel

Administrator
Staff member
Licensed User
There is a bug in Network 1.00 regarding the successful flag. Fixed now: http://www.basic4ppc.com/forum/addi...002-new-network-tcp-ip-library.html#post40303

Using the Phone library you can create this Intent:
B4X:
    Dim i As Intent
    i.Initialize("android.settings.WIFI_SETTINGS", "")
    StartActivity(i)
BTW, Socket.Connect and ServerSocket.Listen are handled internally in the background and will not block your program.
 

James Moxham

Member
Licensed User
After exploring many options, I wonder if this might be the key to interfacing an Android with the real world?

(For those of us with the cheaper pads that don't have bluetooth).

After much searching, I think this might be the cheapest way to convert cat5 to serial WIZnet Serial-to-Ethernet Gateway - WIZ110SR - SparkFun Electronics (well, not quite as the cheapest probably involves buying a W5100 chip and soldering it, but the pins are 0.2mm apart!).

If you can get data to serial, there are many devices that can convert real world data into serial eg picaxe, arduino, propeller.

I do like the simple software interface for these sockets. Sure is a lot easier than trying to write a TCP stack.
 

MFX

Member
Licensed User
Thanks although I've recently seen references that suggest that Ad hoc is available from 2.2 onwards. Not sure what's involved in getting it working though?
 

MFX

Member
Licensed User
Does anyone know of any example code for setting up Telnet connection between two devices? Basically I simply want to send text between two devices.

Martin.
 

MFX

Member
Licensed User
Thanks, I've been a bit busy so it's been a while before I could try this. I've looked at the examples and am still confused. It looks like the Asyncstreams example is for when the device acts as a server is this correct? And the network examples seem to be both server and client? To simplify what I want to do :-

Android device is the Client
Android device connects to IP address (e.g. 192.168.216.32) Port 23 (telnet)
Telnet software on PC (in this case Realterm set o server:telnet) is the server.
If connection is successful then I send text between the two devices.

I've managed to successfully connect to the PC but unfortunately because there's only a few examples around I'm having trouble getting my head round what I need to do next. What I think I need is an Asyncstreams client example?

Cheers.
Martin.
 
Status
Not open for further replies.
Top