Android Code Snippet Check Internet connection + Know connection type (WiFi/Cell)

SOLUTION HERE

[B4X] Check if Internet interfaces are enabled and internet status + type (WiFi/Cell/LAN)

This project combines two libraries, [B4X] SP Ping and [B4X] IFStatus. The following code shows how to use both libraries. https://www.b4x.com/android/forum/threads/b4x-sp-ping-run-the-ping-command-from-b4a-b4j-and-b4i.161861/...

www.b4x.com

Please do not use the following code in your projects.

Below I share a function that returns if the Internet connection exists and what type of connection is available.

Warning: @drgottjr wrote to me: The classes and methods used for b4a have all been deprecated for some time (since sdk 28/29)

Sub Process_Globals
  Type tpeCheckInternet(blnIsOnline As Boolean, strType As String)
End Sub

Public Sub CheckInternet() As tpeCheckInternet
  Dim ci As tpeCheckInternet
  ci.Initialize
  ci.strType = "NONE"
  ci.blnIsOnline = False
  Dim jo As JavaObject
  jo.InitializeContext
  Dim cm As JavaObject = jo.RunMethod("getSystemService", Array("connectivity"))
  Dim activeNetwork As JavaObject = cm.RunMethod("getActiveNetworkInfo", Null)
  If activeNetwork.IsInitialized Then
    If activeNetwork.RunMethod("isConnected", Null).As (Boolean) = True Then
      ci.blnIsOnline = True
      If activeNetwork.RunMethod("getType", Null).As (Int) = 1 Then
        ci.strType = "WIFI"
      Else
        ci.strType = "CELL"
      End If
    End If
  End If
  Return ci
End Sub

Sub Class_Globals
  Dim tpeInet As tpeCheckInternet
End Sub

Public Sub Initialize
  tpeInet.Initialize
End Sub

Private Sub B4XPage_Appear
  'Check if the connection is active
  If tpeInet.blnIsOnline Then
    If tpeInet.strType = "WIFI" Then
      'Download the large file automatically
    Else
      'Wait for user approval to use cellular network data
    End If
  Else
    'No internet connection available
  End If
End Sub

 

[enrfortin]

I could somehow "force" to use a type of connection in case both are connected, currently I have a problem with an application that if the cellular connection is active takes the ip of this network and not the wifi network that is the ip I need to take.

 

[Sergio Haurat]

I could somehow "force" to use a type of connection in case both are connected, currently I have a problem with an application that if the cellular connection is active takes the ip of this network and not the wifi network that is the ip I need to take.

Hello @enrfortin, if you want to activate WiFi or those types of functions, I believe I have read in the forum that Android is becoming more and more restrictive and does not allow it.
See this post:

WiFi On Off

Hi All Is there a way to switch the WiFi On or Off programmable in Android 11.. Thx

www.b4x.com

My function just tries to find out if there is a connection and what type. I use it BEFORE to send GET or POST queries to an API, I leave you the example.

Public Sub GetJSONData(strLink As String) As ResumableSub
    Dim Result As String
    If mdlFunctions.CheckInternet.blnIsOnline Then
        Dim j As HttpJob
        Try
            j.Initialize("", Me)
            j.Download(strLink)
            j.GetRequest.SetHeader("Content-Type","application/json")
            If mdlFunctions.mapToken.IsInitialized And mdlFunctions.mapToken.Size > 0 Then
                j.GetRequest.SetHeader("UserId", mdlFunctions.mapToken.Get("id"))
                j.GetRequest.SetHeader("UniqueKey", mdlFunctions.mapToken.Get("key"))
                j.GetRequest.SetHeader("Authorization", mdlFunctions.mapToken.Get("token"))
            End If
            If mdlFunctions.mapHeaders.IsInitialized And mdlFunctions.mapHeaders.Size > 0 Then
                For Each strKey As String In mdlFunctions.mapHeaders.Keys
                    j.GetRequest.SetHeader(strKey, mdlFunctions.mapHeaders.Get(strKey))
                Next
            End If
            j.GetRequest.Timeout = 60000
            Wait For (j) JobDone(j As HttpJob)
            If j.Success Then
                Result = j.GetString
            Else
                Result = j.ErrorMessage
            End If
        Catch
            Result = LastException.Message
            Log(LastException)
        End Try
        j.Release
    End If
    Return Result
End Sub

Public Sub PostJSONData(strRun As String, mapData As Map) As ResumableSub
    Dim Result As String
    If mdlFunctions.CheckInternet.blnIsOnline  Then
        Dim JSONGenerator As JSONGenerator
        Dim JSONString As String
        JSONGenerator.Initialize(mapData)
        Try
            Dim j As HttpJob
            j.Initialize("", Me)
            JSONString = JSONGenerator.ToString
            j.PostString(mdlFunctions.strRemoteHost & strRun, JSONString)
            j.GetRequest.SetContentType("application/json")
            If mdlFunctions.mapToken.IsInitialized And mdlFunctions.mapToken.Size > 0 Then
                j.GetRequest.SetHeader("UserId", mdlFunctions.mapToken.Get("id"))
                j.GetRequest.SetHeader("UniqueKey", mdlFunctions.mapToken.Get("key"))
                j.GetRequest.SetHeader("Authorization", mdlFunctions.mapToken.Get("token"))
            End If
            If mdlFunctions.mapHeaders.IsInitialized And mdlFunctions.mapHeaders.Size > 0 Then
                For Each strKey As String In mdlFunctions.mapHeaders.Keys
                    j.GetRequest.SetHeader(strKey, mdlFunctions.mapHeaders.Get(strKey))
                Next
            End If
            Wait For (j) JobDone(j As HttpJob)
            If j.Success Then
                Result = j.GetString
            Else
                Result = j.ErrorMessage
            End If
        Catch
            Result = LastException.Message
            Log(LastException)
        End Try
        j.Release
    End If
    Return Result
End Sub

I have some variables of type Map (mapToken and mapHeaders), which I fill with the information that is required, both in the GET and in POST.

As you can see on line 3 in both cases, check beforehand, is there internet?

In the following example code, I query for the current version of the database

Public Sub LoadDB(strTable As String) As ResumableSub
    Dim strURL As String = ""
    Select Case strTable
        Case "get_db_info"
            strURL = mdlFunctions.strRemoteHost & "db_info"
    End Select
    Wait For(clsFunct.GetJSONData(strURL)) Complete (strResult As String)
    Return strResult
End Sub

I made the code prior to paying the $99 from Apple and @Erel's service to be able to remotely compile the application. Now I find myself with these issues that should be simple but in reality, they are not.

 

[Sergio Haurat]

I could somehow "force" to use a type of connection in case both are connected, currently I have a problem with an application that if the cellular connection is active takes the ip of this network and not the wifi network that is the ip I need to take.

Try this library @enrfortin

MLwifi Library Updated to v4.00

Attached Java Source Code MLWifi.zip - couldn't attach the entire Android Studio project as even zipped it was too big (900 KB) for the forum limits. If you want the entire project, private message me with your email address & I'll send it to you. Library updated to v4.40 Added @Events so the...

www.b4x.com