Android Question DDD.CreateToolbar - recognize Label Properties

[Mark Stuart]

I've noticed on other Android apps that the bottom Toolbar/Navigation "buttons" when touched show the button with round ends - the left and right ends.
Even animation to the button when pressed.
So any chance when setting the Label Properties / Color and Corner Radius, that they be recognized when the "button" is pressed?

I read in Erel's comments introducing the DDD, that the Text Properties are only recognized.
It would be nice to have these other properties be used.

Thanx,
Mark Stuart

 

[Erel]

Create a class and put this code:

Private Sub CreateToolbar (DesignerArgs As DesignerArgs)
    Dim pnl As B4XView = DesignerArgs.GetViewFromArgs(0)
    If DesignerArgs.FirstRun Then
        Dim StubLabel As B4XView = pnl.GetView(0)
        StubLabel.RemoveViewFromParent
        Dim EventName As String = DesignerArgs.Arguments.Get(1)
        Dim fnt As B4XFont = StubLabel.Font
        For i = 2 To DesignerArgs.Arguments.Size - 1 Step 2
            Dim text As String = DesignerArgs.Arguments.Get(i)
            Dim tag As String = DesignerArgs.Arguments.Get(i + 1)
            Dim lbl As B4XView = CreateLabel
            lbl.Font = fnt
            lbl.Text = text
            lbl.TextColor = StubLabel.TextColor
            lbl.SetTextAlignment("CENTER", "CENTER")
            lbl.Tag = Array(DesignerArgs.LayoutModule, EventName, tag)
            pnl.AddView(lbl, 0, 0, 40dip, pnl.Height)
        Next
    Else
        For i = 0 To pnl.NumberOfViews - 1
            pnl.GetView(i).Height = pnl.Height
        Next
    End If
End Sub

Private Sub CreateLabel As B4XView
    Dim lbl As Label
    lbl.Initialize("lbl")
    Return lbl
End Sub

#if B4J
Private Sub lbl_MouseClicked (EventData As MouseEvent)
    RaiseToolbarEvent(Sender, Sender.As(B4XView).Tag)
    EventData.Consume
End Sub
#else
Private Sub lbl_Click
    RaiseToolbarEvent(Sender, Sender.As(B4XView).Tag)
End Sub
#End If

Private Sub RaiseToolbarEvent (lbl As B4XView, Data() As Object)
    CallSubDelayed2(Data(0), Data(1) & "_click", Data(2))
    If ToolbarPressedColor <> 0 Then
        lbl.SetColorAnimated(100, xui.Color_Transparent, ToolbarPressedColor)
        Sleep(100)
        lbl.SetColorAnimated(100, ToolbarPressedColor, xui.Color_Transparent)
    End If
End Sub

You can now modify it as you need.

 

[Mark Stuart]

I copied that script into a new B4A Standard Class named DDD. All sorts of issues in it.
I don't know what I'm doing. Where do I start?

Maybe you can help.

Thanx,
Mark Stuart

 

[TILogistic]

Example.
One of the options is to unpack the DesignerUtils.b4xlib library and add or modify the functionality.

 

[LucaMs]

One of the options is to unpack the DesignerUtils.b4xlib library and add or modify the functionality.

Another one is to wait for Erel to do it ?

 

[TILogistic]

another option is to create your own functionality,

See an example.

Designer Script Extensions with buttons in panel

Hi, I like the new Designer Script Extensions feature. It will make things easier to use. What would be the best way to re-size the buttons like shown below if the buttons was in a panel using this new feature ? I want to put the buttons in a panel and then re-size the buttons based on the...

www.b4x.com

 

[TILogistic]

Another one is to wait for Erel to do it ?

this reminds me of a similar situation, an image of a @LucaMs roulette. ???

but now @Erel recommend.

A new internal library is available named DesignerUtils. It includes a class named DDD with all kinds of useful method. I recommend developers to check it source code (inside the b4xlib = zip).

[B4X] [DSE] Designer Script Extensions

The soon to be released versions of B4A, B4i and B4J include a new feature named: designer script extensions. The new feature allows calling B4X code from the visual designer scripts. Note that the B4X code is not executed at design time. I believe that over time this new feature, with a...

www.b4x.com

 

[LucaMs]

but now @Erel recommend.

Yes, but in this case, maybe you could ask Erel to put that part in the official B4XLib (open a new "Wish" thread?).

 

[Erel]

I copied that script into a new B4A Standard Class named DDD. All sorts of issues in it.
I don't know what I'm doing. Where do I start?

Don't name it DDD. This will clash with the class in DesignerUtils. Give it a different name.

 

[Mark Stuart]

Renamed the Class module but the logger is complaining with the following handler.
Something about it needs to be in an Activity.

Private Sub CreateLabel As B4XView
    Dim lbl As Label
    lbl.Initialize("lbl")
    Return lbl
End Sub

 

[TILogistic]

Post an example to help you.

 

[Erel]

Something about it needs to be in an Activity.

Add this line to the Class_Globals:

Private stub As B4XView 'ignore

This will cause the compiler to treat it as a class with an activity context.