Sub Process_Globals
Public Serial1 As Serial
Private wifi As ESP8266WiFi
Private server As WiFiServerSocket
Private astream As AsyncStreams
Private timer1 As Timer
Private ser As B4RSerializator
End Sub
Private Sub AppStart
Serial1.Initialize(115200)
Log("AppStart")
'ScanNetworks
If wifi.Connect("dlink") Then 'change to your network SSID (use Connect2 if a password is required).
Log("Connected to wireless network.")
Log("My ip: ", wifi.LocalIp)
Else
Log("Failed to connect.")
Return
End If
timer1.Initialize("timer1_Tick", 1000)
timer1.Enabled = True
server.Initialize(51042, "server_NewConnection")
server.Listen
End Sub
Sub Server_NewConnection (NewSocket As WiFiSocket)
Log("Client connected")
astream.Initialize(NewSocket.Stream, "astream_NewData", "astream_Error")
End Sub
Sub Timer1_Tick
If server.Socket.Connected Then
astream.Write(ser.ConvertArrayToBytes(Array("Time here is: ", Millis)))
End If
End Sub
Sub AStream_NewData (Buffer() As Byte)
Dim be(10) As Object
Dim data() As Object = ser.ConvertBytesToArray(Buffer, be)
Log("Received:")
For Each o As Object In data
Log(o)
Next
End Sub
Sub AStream_Error
Log("Error")
server.Listen
End Sub
Private Sub ScanNetworks 'ignore
Dim numberOfNetworks As Byte = wifi.Scan
Log("Found: ", numberOfNetworks, " networks.")
For i = 0 To numberOfNetworks - 1
Log(wifi.ScannedSSID(i))
Next
End Sub
