Get a random String

[ilan]

you can use this to generate a random userid:

function:

Sub RandomString(length As Int) As String
    Dim abc As String = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz"
    Dim randomstr As String = ""
    For i = 0 To length - 1
        randomstr = randomstr & (abc.CharAt(Rnd(0,abc.Length)))
    Next
    Return randomstr
End Sub

use:

Log(RandomString(12))

 

[Widget]

Useful routine. It reminds me of the Youtube url that gets generated to identify each unique video.
If you use StringBuilder it will run considerably faster.

 

[Erel]

Sub AppStart (Args() As String)
   Dim n As Long = DateTime.Now
   RandomString(30000)
   Log(DateTime.Now - n) '583 milliseconds
   Dim n As Long = DateTime.Now
   RandomString2(30000)
   Log(DateTime.Now - n) '5 milliseconds
End Sub

Sub RandomString(length As Int) As String
   Dim abc As String = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz"
   Dim RandomStr As String = ""
   For i = 0 To length - 1
     RandomStr = RandomStr & (abc.CharAt(Rnd(0,abc.Length)))
   Next
   Return RandomStr
End Sub

Sub RandomString2(length As Int) As String
   Dim abc As String = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz"
   Dim RandomStr As StringBuilder
   RandomStr.Initialize
   For i = 0 To length - 1
     RandomStr.Append(abc.CharAt(Rnd(0,abc.Length)))
   Next
   Return RandomStr.ToString
End Sub

 

[ilan]

Log(DateTime.Now - n) '583 milliseconds
Log(DateTime.Now - n) '5 milliseconds

can you explain why? (5ms vs 583ms)

thank you

 

[Erel]

Strings are immutable objects. This means that for each modification a new string is created.
Consider this code:

Dim s As String = "1000 characters long string..."
s = s & "."

In the second line a new string is created with a size of 1001 characters. The 1000 characters from the previous string are copied to the new string and a dot is added as the last character.

This happens on each iteration. For short strings the overhead is negligible, however for longer strings it becomes huge.

StringBuilder on the other hand is a mutable string.

sb.Append(".")

It maintains an internal buffer and grows it as needed (with enough room for many more characters).
So appending a character is a very quick operation. It just copies the character to the internal buffer.

 

[ilan]

Thank you @Erel. Very clear answer.

 

[ilan]

Sub AppStart (Args() As String)

is this a new tool @Erel?

no b4x tool has such a line. (Appstart with Args array as string)

 

[Cableguy]

is this a new tool @Erel?

no b4x tool has such a line. (Appstart with Args array as string)

No-ui b4j??

 

[ilan]

No-ui b4j??

thanx @Cableguy, you are right. i just never use b4j non ui app but now i see it can be used as a console app where you can test code sample fast without any UI.
have never thought about using b4j non ui for that .

 

[Peter Simpson]

We are all always learning @ilan...

 

[Derek Johnson]

If users have to type in their userid you might want to consider whether it needs to have both upper case and lower case letters. Many systems use userids that are not case sensitive, although passwords are almost always case sensitive.

 

[ilan]

If users have to type in their userid you might want to consider whether it needs to have both upper case and lower case letters. Many systems use userids that are not case sensitive, although passwords are almost always case sensitive.

you could use:

Return randomstr.ToLowerCase

for username

 

[Derek Johnson]

you could use:

Return randomstr.ToLowerCase

for username

or just take the set of uppercase letters out of this string:

   Dim abc As String = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz"

   Dim abc As String = "0123456789abcdefghijklmnopqrstuvwxyz"

 

[ilan]

or just take the set of uppercase letters out of this string:

   Dim abc As String = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz"

   Dim abc As String = "0123456789abcdefghijklmnopqrstuvwxyz"

but like this you could use it not only for username you could use it also for passwords. so better leave it inside and just add .ToLowerCase from the returned string (not inside the function)

like:

dim str as string
str = RandomString(12).ToLowerCase