Android Question Get Y postition of cursor in edittext

[RB Smissaert]

I need this to position a custom keyboard.
This post suggest it can be done easily:

How to get EditText cursor position x,y?

Hi, I have found some Java code that will give the x,y coordinates of the cursor in an EditText view. int pos = editText.getSelectionStart(); Layout layout = editText.getLayout(); int line = layout.getLineForOffset(pos); int baseline = layout.getLineBaseline(line); int ascent =...

www.b4x.com

but it doesn't compile.

RBS

 

[Sagenut]

Do you mean the position of the cursor in a specific character of the text in the Edittext?

Edittext.SelectionStart

should return that position.

 

[RB Smissaert]

Do you mean the position of the cursor in a specific character of the text in the Edittext?

Edittext.SelectionStart

should return that position.

No, that won't be accurate enough, although it could be made to work.
I need the actual screen Y position of the cursor.

RBS

 

[klaus]

Here you are:
The y position is the text base line, the red cross.
The coordinate origin is the top left corner of the EditText.
The routine returns an Array of Int. xy(0) = X and xy(1) = Y

The cross is drawn onto Panel with same size as the EditText.

'gets the x and y coordinates of the cursor in an EditText view
Private Sub GetEditTextXYCursor(edt As EditText) As Int()
    Private joEditText, joLayout As JavaObject
    Private PaddingLeft, PaddingTop, ScrollY, Pos, Line, LineBaseline As Int
    Private xy(2) As Int

    joEditText = edt
    PaddingLeft = joEditText.RunMethod("getPaddingLeft", Null)
    PaddingTop = joEditText.RunMethod("getPaddingTop", Null)
    ScrollY = joEditText.RunMethod("getScrollY", Null)
'    pos = edt.SelectionStart
    Pos = joEditText.RunMethod("getSelectionStart", Null)
    joLayout = joEditText.RunMethod("getLayout", Null)
    Line = joLayout.RunMethod("getLineForOffset", Array As Object(Pos))    'line numbsr
    LineBaseline = joLayout.RunMethod("getLineBaseline", Array As Object(Line))

    xy(0) = joLayout.RunMethod("getPrimaryHorizontal", Array As Object(Pos)) + PaddingLeft
    xy(1) = LineBaseline + PaddingTop - ScrollY    'base line
    Return xy
End Sub

Attached my test project, it contains more properties.

 

[RB Smissaert]

Here you are:
The y position is the text base line, the red cross.
The coordinate origin is the top left corner of the EditText.
The routine returns an Array of Int. xy(0) = X and xy(1) = Y

View attachment 95403

The cross is drawn onto Panel with same size as the EditText.

'gets the x and y coordinates of the cursor in an EditText view
Private Sub GetEditTextXYCursor(edt As EditText) As Int()
    Private joEditText, joLayout As JavaObject
    Private PaddingLeft, PaddingTop, ScrollY, Pos, Line, LineBaseline As Int
    Private xy(2) As Int

    joEditText = edt
    PaddingLeft = joEditText.RunMethod("getPaddingLeft", Null)
    PaddingTop = joEditText.RunMethod("getPaddingTop", Null)
    ScrollY = joEditText.RunMethod("getScrollY", Null)
'    pos = edt.SelectionStart
    Pos = joEditText.RunMethod("getSelectionStart", Null)
    joLayout = joEditText.RunMethod("getLayout", Null)
    Line = joLayout.RunMethod("getLineForOffset", Array As Object(Pos))    'line numbsr
    LineBaseline = joLayout.RunMethod("getLineBaseline", Array As Object(Line))

    xy(0) = joLayout.RunMethod("getPrimaryHorizontal", Array As Object(Pos)) + PaddingLeft
    xy(1) = LineBaseline + PaddingTop - ScrollY    'base line
    Return xy
End Sub

Attached my test project, it contains more properties.

Thanks, that works very nicely indeed.

RBS