B4J Question How? Correct crossplatform mouse object moving (dragging) by _Touch event

[peacemaker]

HI, All

Please, help to understand how to just make correct dragging the B4XView-object manually by a mouse.
The project is attached. It will be shared to any forummates when ready - it's the template of the vector objects editor.

How to make smooth dragging along the cursor ? And without going out the parent (screen).
Now coordinates during the dragging is sometimes changed back.

 

[Erel]

There are several libraries in the forum that handle dragging.

You will get smooth movement with this code:

Private Sub mRoot_Touch (Action As Int, X As Float, Y As Float)
    If Action = mRoot.TOUCH_ACTION_DOWN Then
        Dragging = True
        DownX = X
        DownY = Y
    Else If Action = mRoot.TOUCH_ACTION_UP Then
        Dragging = False
    Else If Dragging And Action = mRoot.TOUCH_ACTION_MOVE Then
        'If mRoot.Left + mRoot.Width <= mParent.Width Then
        mRoot.Left = mRoot.Left + X - DownX
        mRoot.Top = mRoot.Top + Y - DownY
    End If
End Sub

 

[peacemaker]

Thanks, Erel. But this code works only in B4J smoothly.
In B4A - it's strange circled dragging.

 

[Erel]

You need to add the event with reflection as done in this old example: https://www.b4x.com/android/forum/threads/classes-are-soon-coming.18395/#content

 

[peacemaker]

Hmm, so _Touch event is not cross-platform ? But it works, in whole...

I see that Android sub signature is different

Private Sub Panel1_Touch (o As Object, ACTION As Int, x As Float, y As Float, motion As Object) As Boolean

Or what the trouble here to make similar crossplatform working ?

 

[Erel]

Hmm, so _Touch event is not cross-platform ?

It is. The problem is that the "regular" Touch event is raised indirectly in B4A (historic reasons). This is why you need to add the slightly different touch event with reflection.

 

[Erel]

    #if B4A
    Dim r As Reflector
    r.Target = mRoot
    r.SetOnTouchListener("mRoot_Touch")
    #end if
End Sub


#if B4A
Private Sub mRoot_Touch (o As Object, ACTION As Int, x As Float, y As Float, motion As Object) As Boolean
#else
Private Sub mRoot_Touch (Action As Int, X As Float, Y As Float)
#end if
    If Action = mRoot.TOUCH_ACTION_DOWN Then
        Dragging = True
        DownX = X
        DownY = Y
    Else If Action = mRoot.TOUCH_ACTION_UP Then
        Dragging = False
    Else If Dragging And Action = mRoot.TOUCH_ACTION_MOVE Then
        'If mRoot.Left + mRoot.Width <= mParent.Width Then
        mRoot.Left = mRoot.Left + X - DownX
        mRoot.Top = mRoot.Top + Y - DownY
    End If
    #if B4A
    Return True
    #end if
End Sub

 

[peacemaker]

Thanks, Erel, now it's cross-platform

 

[Erel]

And now with grid and boundaries:

#if B4A
Private Sub mRoot_Touch (o As Object, ACTION As Int, x As Float, y As Float, motion As Object) As Boolean
#else
Private Sub mRoot_Touch (Action As Int, X As Float, Y As Float)
#end if
    If Action = mRoot.TOUCH_ACTION_DOWN Then
        Dragging = True
        DownX = X
        DownY = Y
    Else If Action = mRoot.TOUCH_ACTION_UP Then
        Dragging = False
    Else If Dragging And Action = mRoot.TOUCH_ACTION_MOVE Then
        mRoot.Left = Max(0, Min(mRoot.Parent.Width - mRoot.Width, ApplyGrid(mRoot.Left + X - DownX)))
        mRoot.Top = Max(0, Min(mRoot.Parent.Height - mRoot.Height, ApplyGrid(mRoot.Top + Y - DownY)))
    End If
    #if B4A
    Return True
    #end if
End Sub

Private Sub ApplyGrid (x As Int) As Int
    If GridSize > 0 Then
        Return x - (x Mod GridSize)
    End If
    Return x
End Sub

Private GridSize As Int = 10dip

 

[peacemaker]

So, draggin is solved.

p.s. but in B4A, it seems, mRoot_Click and mRoot_LongClick are broken now, solving

 

[peacemaker]

The final (for dragging, clicks) project v.0.13 is attached.

Sub Class_Globals
...
    Private DownX, DownY As Double, Dragging As Boolean, DraggingStart As Long
    Private GridSize As Int = 5dip
End Sub

#if B4A
Private Sub mRoot_Touch (o As Object, ACTION As Int, x As Float, y As Float, motion As Object) As Boolean
#else
Private Sub mRoot_Touch (Action As Int, X As Float, Y As Float)
#end if
    If Action = mRoot.TOUCH_ACTION_DOWN Then
        Dragging = True
        DraggingStart = DateTime.Now
        DownX = X
        DownY = Y
    Else If Action = mRoot.TOUCH_ACTION_UP Then
        Dragging = False
        #if B4A
            If (DateTime.Now - DraggingStart) > 500 Then
                mRoot_LongClick
            Else
                mRoot_Click
            End If
        #end if
    Else If Dragging And Action = mRoot.TOUCH_ACTION_MOVE Then
        mRoot.Left = Max(0, Min(mRoot.Parent.Width - mRoot.Width, ApplyGrid(mRoot.Left + X - DownX)))
        mRoot.Top = Max(0, Min(mRoot.Parent.Height - mRoot.Height, ApplyGrid(mRoot.Top + Y - DownY)))
    End If
    #if B4A
    Return True
    #end if
End Sub

Private Sub ApplyGrid (x As Int) As Int
    If GridSize > 0 Then
        Return x - (x Mod GridSize)
    End If
    Return x
End Sub