B4J Question HttpUtils - Cookie Store?

[JMB_Downlaod]

Hello,

I have a question regarding the HttpUtils library: How does OKHttp handle cookies? Are they deleted after each request or is there a local CookieStore? I have seen this thread: https://www.b4x.com/android/forum/threads/httputills2-clear-cookies.20053/post-116138 Is there an equivalent solution for B4J?

Thanks.

 

[Erel]

Cookies are managed internally and are kept by default.

Clear cookies:
1.

Sub ClearCookies
    If HttpUtils2Service.hc.IsInitialized = False Then
        HttpUtils2Service.Service_Create
    End If
    Log(HttpUtils2Service.hc.IsInitialized)
    Dim jo As JavaObject = HttpUtils2Service.hc
    Dim client As JavaObject = jo.GetField("client")
    Dim r As Reflector
    r.Target = client.RunMethod("cookieJar", Null)
    Dim CookieManager As JavaObject = r.GetField("cookieHandler")
    CookieManager.RunMethodJO("getCookieStore", Null).RunMethod("removeAll", Null)
End Sub

2. Add symbol to build configuration (ctrl + b): HU2_PUBLIC

 

[JMB_Downlaod]

Hi,

thank you very much. I tried your code snippet, but I go the following error:

java.lang.RuntimeException: java.lang.RuntimeException: java.lang.RuntimeException: java.lang.NoClassDefFoundError: javafx/beans/value/ChangeListener

Please note, that I use HttpUtils on a non UI app.

 

[Erel]

jReflection depends on several UI classes, which are not used in this case.

Try to add a reference to jFX library.

 

[JMB_Downlaod]

Try to add a reference to jFX library.

Unfortunately it doesn't work,I still get the same error.

 

[Erel]

You are correct. The behavior depends on the Java version.

Solution without jReflection:

Sub ClearCookies
    If HttpUtils2Service.hc.IsInitialized = False Then
        HttpUtils2Service.Service_Create
    End If
    Log(HttpUtils2Service.hc.IsInitialized)
    Dim jo As JavaObject = HttpUtils2Service.hc
    Dim client As JavaObject = jo.GetField("client")
    Dim jme As JavaObject = Me
    Dim handler As Object = jme.RunMethod("getCookieHandler", Array(client.RunMethod("cookieJar", Null)))
    Dim CookieManager As JavaObject = handler
    CookieManager.RunMethodJO("getCookieStore", Null).RunMethod("removeAll", Null)
End Sub


#if JAVA
import java.lang.reflect.*;
public static Object getCookieHandler(Object o) throws Exception {
    Field f = o.getClass().getDeclaredField("cookieHandler");
    f.setAccessible(true);
    return f.get(o);
}
#End If