Android Tutorial MediaPlayer tutorial

Erel · Nov 14, 2010

The MediaPlayer is used to play audio files.
MediaPlayer supports formats like: mp3, midi, wave and ogg. The full list is available here: Android Supported Media Formats | Android Developers

In order to play an audio file we first need to load the file:

B4X:

MediaPlayer1.Load(File.DirAssets, "IsawHerStandingThere.mid")

In this case the file was added with the file manager and therefore File.DirAssets is used.

Now we can start playing the file with:

B4X:

MediaPlayer1.Play

and pause the playback with:

B4X:

MediaPlayer.Pause

Calling Play will resume from the same position.
Note that you can only call Pause while MediaPlayer is playing.

You can call MediaPlayer.Load at any point (after initialization), and load a new file.
MediaPlayer should be declared in Process_Globals otherwise a new instance will be created each time the activity is recreated.

The program attached is a small program that allows the user to see the playback progress and to change the position.

This is the code:

B4X:

Sub Process_Globals
    Dim MediaPlayer1 As MediaPlayer
    Dim timer1 As Timer
End Sub

Sub Globals
    Dim barPosition As SeekBar
    Dim barVolume As SeekBar
    Dim lblPosition As Label
    Dim Looping As ToggleButton
End Sub

Sub Activity_Create(FirstTime As Boolean) 
    If FirstTime Then
        MediaPlayer1.Initialize( )
        MediaPlayer1.Load(File.DirAssets, "IsawHerStandingThere.mid")
        Timer1.Initialize("timer1", 1000)
    End If
    Activity.LoadLayout("1")
    Looping_CheckedChange(Looping.Checked) 'set the default value
End Sub

Sub Activity_Resume
    MediaPlayer1.Play
    timer1.Enabled = True
    timer1_Tick 'don't wait one second for the UI to update.
End Sub

Sub Activity_Pause (UserClosed As Boolean)
    If MediaPlayer1.IsPlaying Then MediaPlayer1.Pause
    timer1.Enabled = False
End Sub

Sub timer1_Tick
    If MediaPlayer1.IsPlaying Then
        barPosition.Value = MediaPlayer1.Position / MediaPlayer1.Duration * 100
        lblPosition.Text = "Position: " & ConvertToTimeFormat(MediaPlayer1.Position) & _
            " (" & ConvertToTimeFormat(MediaPlayer1.Duration) & ")"
    End If
End Sub
'converts milliseconds to m:ss format.
Sub ConvertToTimeFormat(ms As Int) As String
    Dim seconds, minutes As Int
    seconds = Round(ms / 1000)
    minutes = Floor(seconds / 60)
    seconds = seconds Mod 60
    Return NumberFormat(minutes, 1, 0) & ":" & NumberFormat(seconds, 2, 0) 'ex: 3:05
End Sub

Sub barVolume_ValueChanged (Value As Int, UserChanged As Boolean)
    MediaPlayer1.SetVolume(barVolume.Value / 100, barVolume.Value / 100)
End Sub

Sub barPosition_ValueChanged (Value As Int, UserChanged As Boolean)
    If UserChanged = False Then Return 'the value was changed programmatically
    MediaPlayer1.Position = Value / 100 * MediaPlayer1.Duration
    If MediaPlayer1.IsPlaying = False Then 'this can happen when the playback reached the end and the user changes the position
        MediaPlayer1.Play
    End If
    timer1_Tick 'immediately update the progress label
End Sub

Sub Looping_CheckedChange(Checked As Boolean)
    MediaPlayer1.Looping = Checked
End Sub

We are initializing MediaPlayer only once when the application starts.
Playing starts when the activity resumes, which happens right after the Create event.

A timer is used to check the playback position every second and update the label and seek bar.
Note that the seekbar ValueChanged position includes a boolean value named UserChanged which you can use to differentiate between changes done by the user (by dragging the thumb) and changes done programmatically.

The Looping property determines whether playback will restart automatically when it reaches the end.

Erel · Sep 12, 2012

@AscySoft the API you mentioned is only available in Android 4.1 devices. You can try to create the fading effect by changing the volume. Did you try to use two media player objects?

@nad, You can call it with reflection however the data is not available. It will return -1.

AscySoft · Sep 12, 2012

a little bit closer..

Erel said:
You can try to create the fading effect by changing the volume. Did you try to use two media player objects?

Thanks for the tip, I was thinking to go in this direction, but is good that you point it out for me, because I was AFRAID not to spend too much time in a direction that could bring nothing.
So, I should create another service module to start a separate song, or should I use another mediaplayer on the same service module?
My instinct say that I should go with the same service. Is it OK? What's your opinion? Which is better (programming/resources etc)?

Erel · Sep 12, 2012

It doesn't matter whether you put the two MediaPlayers in the same service or not. This means that you should use the same service to keep your code simpler.

AscySoft · Sep 12, 2012

Thanks for your answers. Thanks for everything.

Vabzboy · Sep 30, 2012

Hey Erel,

Is there any way to automatically update the Position Seekbar and Label according to audio file being played.

Erel · Oct 1, 2012

The seekbar and label should update automatically.

seniorbot · Nov 20, 2012

Media Player has no sound on AVD

When using Media Player why sometimes simulator has no sound? Real device connected like phone or tablet don't have the problem. Thanks.

Erel · Nov 21, 2012

Android emulator is far from being perfect. I recommend you to use a real device during development.

jeeradate · Jan 22, 2013

How to stop the MediaPlayer during the phone call?

If it is possible to stop MediaPlayer during the phone call and resume the play after the phone call is end.

Would you please be so kind and advise?

Thank you in advance.

Best regards,
Jeeradate K.

AscySoft · Jan 22, 2013

jeeradate said:
If it is possible to stop MediaPlayer during the phone call and resume the play after the phone call is end.

Yes, it is possible. I'm not at home, but I can recall that I was using Phone library, listening to a parameter (a flag)
I create this and test it with real phone/device, and yes is possible 100% sure.

jeeradate · Jan 22, 2013

AscySoft said:
Yes, it is possible. I'm not at home, but I can recall that I was using Phone library, listening to a parameter (a flag)
I create this and test it with real phone/device, and yes is possible 100% sure.

Thank you for the good news.

I try to look in Phone library but could not find it.
Would you please advise?

Best regards,
Jeeradate K.

AscySoft · Jan 23, 2013

jeeradate said:
I try to look in Phone library but could not find it.
Would you please advise?

Sure. Look at post http://www.b4x.com/forum/additional...9-phone-library-update-v1-34-a.html#post44329

Sub you need is:

B4X:

PhoneStateChanged (State As String, IncomingNumber As String, Intent As Intent)
'use parameters:OFFHOOK and RINGING
If State="OFFHOOK" OR State="RINGING" Then
Log("Phone ringing, pausing...")
End If

Furthermore pleas read documentation.

jeeradate · Jan 23, 2013

AscySoft said:
Sure. Look at post http://www.b4x.com/forum/additional...9-phone-library-update-v1-34-a.html#post44329

Sub you need is:

B4X:

PhoneStateChanged (State As String, IncomingNumber As String, Intent As Intent) 'use parameters:OFFHOOK and RINGING If State="OFFHOOK" OR State="RINGING" Then Log("Phone ringing, pausing...") End If

Furthermore pleas read documentation.

Thank you very much for your kind advice. :sign0142:

AscySoft · Jan 23, 2013

you're welcome

cramcha · Mar 17, 2013

continuous playback from list

:sign0013::BangHead:
Hi all. This is my first post.
I have a little problem with this code and I hope someone can have some solution:

This is a summary of the code...

For h = 0 To lstRepro.Size-1
MP.Load(fullpath, lstRepro.Get(h))
MP.Play
Log(h)
Next

I expected continuous playback of files from the list (lstRepro), but it's not.
Log prints the entire list, but mediaplayer only loads the first file.

I have not found anything about this issue yet. Thanks to all
:sign0085:

klaus · Mar 17, 2013

You should use something like this:

B4X:

Index = 0
MP.Load(fullpath, lstRepro.Get(Index))
MP.Play



Sub MP_Complete
    Index = Index + 1
    If Index = lstRepro.Size Then
        Index = 0
    End If
    MP.Load(fullpath, lstRepro.Get(Index))
    MP.Play
End Sub

MiguelAlvarez · Mar 22, 2013

Why? When I test this MediaPlayer tutorial and play it, I can hear nothing? No error but not sound

Erel · Mar 22, 2013

I guess that you checked the volume. Do you hear sounds when playing other apps?

Pelican104 · Apr 25, 2013

MediaPlayer GetAudioSessionID

Anyone know how I can retrieve a media players session ID?

Thanks

Erel · Apr 26, 2013

What is this id?

Android Tutorial MediaPlayer tutorial

Attachments

B4X founder

Active Member

B4X founder

Active Member

Member

B4X founder

New Member

B4X founder

Member

Active Member

Member

Active Member

Member

Active Member

Member

Expert

Member

B4X founder

New Member

B4X founder

Similar Threads

Privacy & Transparency

Privacy & Transparency