Size of label to fit a string

Erel said:

Check AutoTextSizeLabel class: http://www.b4x.com/android/forum/posts/177986/

It sets the maximum text size that fits. Check the code. You should probably be able to change its implementation and instead of modifying the text size, modify the label width.

Click to expand...

Erel said:

You do not need an ImageView. Have you tried AutoTextSizeLabel? You just need to modify the CheckSize sub and increase the width instead of the font size.

Click to expand...

RJB said:

I'll take another look. I can vary the width, as long as I know what it has been set to and the offset of the text from the left. Ideally I don't want to vary the height. The height and the font size should be fixed, so I need to be able to put the text right at the top of the label so that the descenders fit in.

Click to expand...

ImageView1.Initialize("")
ImageView1.Color = Colors.lightgray
Activity.AddView(ImageView1,0,0,1dip,1dip)
Dim textsize As Float = 24
Dim text As String = "The quick brown fox jumps over the lazy dogs back"       
Canvas.Initialize(Activity)
Dim Height As Int = Canvas.MeasureStringheight(text, Typeface.DEFAULT, textsize)' * 1dip
Dim width As Int = Canvas.MeasureStringwidth(text, Typeface.DEFAULT, textsize)' * 1dip
ImageView1.SetLayout(0,0,width,Height)
Canvas.Initialize(ImageView1)
Canvas.DrawText(text, 0, Height * 0.8, Typeface.DEFAULT, textsize, Colors.Red, "LEFT")
ImageView1.Bitmap = Canvas.Bitmap

klaus said:

The code below will do it.

B4X:

Sub Globals
    Dim lblTest As Label
    Dim btnTextLong, btnTextShort As Button
 
    Dim bmpTest As Bitmap
    Dim cvsTest As Canvas
    Dim stu As StringUtils
End Sub
 
Sub Activity_Create(FirstTime As Boolean)
    Activity.LoadLayout("main")
 
    bmpTest.InitializeMutable(1dip, 1dip)
    cvsTest.Initialize2(bmpTest)
 
    btnTextLong_Click
End Sub
 
Sub btnTextLong_Click
    lblTest.TextSize = 16
    SetTextAndWidth(lblTest, "Long long long long long long text")
End Sub
 
Sub btnTextShort_Click
    lblTest.TextSize = 24
    SetTextAndWidth(lblTest, "Short text")
End Sub
 
Sub SetTextAndWidth(lbl As Label, txt As String)
    lbl.Width = cvsTest.MeasureStringWidth(txt, lbl.Typeface, lbl.TextSize)
    lbl.Height = stu.MeasureMultilineTextHeight(lbl, txt)
    lbl.Text = txt
End Sub

Best regards.

Click to expand...

Dim Canvas1 As Canvas
 
    Dim lbl1 As Label
    Dim character As Float = 0
    Dim runningtotal As Float = 0
    Dim width As Float = 0
    Dim text1 As String = "TTTtttt T t f fffffffo o oooo The quick brown fox jumps over the lazy dogs back"
    Dim text2 As String = ""
    Dim textsize As Int = 16
    Dim difference As Float = 0
   
    Canvas1.Initialize(Activity)
    lbl1.Initialize("")
    Activity.AddView(lbl1,0dip,0dip,1dip,24dip)
    lbl1.Color = Colors.blue
    lbl1.text = ""
    lbl1.Typeface = Typeface.DEFAULT
    lbl1.textsize = textsize
 
    For i = 0 To text1.Length - 1
        text2 = text2 & text1.SubString2(i, i + 1)
        character = Canvas1.MeasureStringWidth(text1.SubString2(i, i + 1), Typeface.DEFAULT_BOLD, textsize)
        runningtotal = runningtotal + character
        width = Canvas1.MeasureStringWidth(text2, Typeface.DEFAULT_BOLD, textsize)
        difference = runningtotal - width
        Log(text1.SubString2(i, i + 1) & " : " & character & " : " & runningtotal & " : " & width & " : " & difference)
        lbl1.text = text2
        lbl1.width = width
    Next

RJB said:

Thanks Erel and Klaus.

............
The difference figure increases and there is a blank space at the end of the displayed text.
When run on the 7inch device the difference is always zero and there is no space at the end.
Any thoughts?
Thanks

Click to expand...