B4J Code Snippet Slider show value in thumb

Hi,

a neat little snippet showing the slider value while moving. Makes use of the JavaObject libary.

Private Slider1 As Slider

Set the track color and bind a label to the slider.

SliderTrackColorRGB(Slider1,0,0,255)
SliderBindLabel(Slider1, "%.0f")

Bind a label to a slider. The label displays the slider value.

Sub SliderBindLabel(sldr As Slider, fmt As String)
    Dim lblvalue As Label
    lblvalue.Initialize("lblvalue")
    Dim joSlider As JavaObject = sldr
    Dim joLabel As JavaObject = lblvalue
    ' Get the valueproperty of the slider as StringBinding
    Dim vp As JavaObject = joSlider.RunMethodJO("valueProperty", Null).RunMethod("asString", Array(fmt))
    ' Bind the slider stringbinding to the label
    joLabel.RunMethodjo("textProperty", Null).runmethodjo("bind", Array(vp))
    ' Add the label to the slider thumb
    joSlider.RunMethodJo("lookup", Array(".thumb")).RunMethodJo("getChildren", Null).RunMethod("add", Array(lblvalue))
End Sub

' Set the color of the slider track using RGB colors, e.g. red=255,0,0, green=0,255,0,blue=0,0,255.

Sub SliderTrackColorRGB(slr As Slider, r As Int, g As Int, b As Int)
    Dim joSldr As JavaObject = slr
    joSldr.RunMethodJo("lookup", Array(".track")).RunMethod("setStyle", Array($"-fx-background-color:rgb(${r},${g},${b});"$))
End Sub

 

[alienhunter]

Hi ,
thanks for sharing this
it does not display 1.5 how would i do this ?
thanks AH

 

[rwblinn]

Hi,

change the format parameter in SliderBindLabel to:

SliderBindLabel(Slider1, "%.1f")

 

[Mashiane]

Hi ,
thanks for sharing this
it does not display 1.5 how would i do this ?
thanks AH
View attachment 49780

How did you do the ruler for the slider? Thanks...

 

[rwblinn]

Hi,

set the properties - either in the designer or in the code.

Slider.ShowTickLabels = True
Slider.ShowTickMarks = True

 

[Mashiane]

Hi,

set the properties - either in the designer or in the code.

Slider.ShowTickLabels = True
Slider.ShowTickMarks = True

Sorry, the built in b4j slider does not have these properties.

 

[rwblinn]

OK - sorry = the answer was related to the CustomView library jRLViews.

For use with the standard B4J Slider, make use of a JavaObject to access additional properties.
Example:

Private Slider1 As Slider

'Assign a JavaObject as Slider
Dim joSlider As JavaObject = Slider1
'Set additional properties which are not provided by the B4J Visual Designer
joSlider.RunMethod("setBlockIncrement", Array(10.0))    ' Must be double
joSlider.RunMethod("setMajorTickUnit", Array(10.0))     ' Must be double             
joSlider.RunMethod("setMinorTickCount", Array(20))      ' Must be Int
joSlider.RunMethod("setShowTickLabels", Array(True))
joSlider.RunMethod("setShowTickMarks", Array(True))
joSlider.RunMethod("setValueChanging", Array(True))
joSlider.RunMethod("setSnapToTicks", Array(True))