B4J Question [Solved] Join images side by side

[jroriz]

Hi.

I captured 2 portions of the screen, now I want to put them together in one image, side by side.

After that I want to write that image to HD as a png file.

This is what I have so far ...

Dim Bitmap1 As B4XBitmap = Capture(x, y, width, height)
Dim Bitmap2 As B4XBitmap = Capture(x, y, width, height)

' join images side by side

' write png file.

Sub Capture(x As Int, y As Int, width As Int, height As Int) As B4XBitmap
    c3po.ScreenCurrentRectangleSetAsArbitrary(x, y, width, height)
    Return BytesToImage(c3po.ScreenCaptureAsByteArray)
End Sub

Public Sub BytesToImage(bytes() As Byte) As B4XBitmap
    Dim In As InputStream
    In.InitializeFromBytesArray(bytes, 0, bytes.Length)

    Dim bmp As Image
    bmp.Initialize2(In)

    Return bmp
End Sub

Image 1:

Image 2:

Final Image:

 

[jroriz]

Any help?

 

[DonManfred]

Create a canvas of the same height of the images and a width of img1.width+img2.width
Draw the two images on the canvas.
Save the canvas as a new bitmap.

 

[jroriz]

I dont know how to save a canvas as bitmap.

I did it with BitmapCreator.

Any better idea?

Dim Bitmap1 As B4XBitmap = Capture(0, 0, 50, 50)
Dim Bitmap2 As B4XBitmap = Capture(50, 0, 50, 50)

Dim bc1, bc2, bc3 As BitmapCreator

bc1.Initialize(50,50)
bc1.CopyPixelsFromBitmap(Bitmap1)

bc2.Initialize(50,50)
bc2.CopyPixelsFromBitmap(Bitmap2)

bc3.Initialize(100,50)

For x = 0 To 49
    For y = 0 To 49
        bc3.CopyPixel(bc1, x, y, x, y)
        bc3.CopyPixel(bc2, x, y, x+50, y)
    Next
Next

Dim out As OutputStream
out = File.OpenOutput(dirapp, "join.png", False)
bc3.Bitmap.WriteToStream(out, 100, "PNG")
out.Close

 

[Erel]

Untested code:

Sub MergeTwoBitmapsSideBySide(bmp1 As B4XBitmap, bmp2 As B4XBitmap) As B4XBitmap
   Dim bc As BitmapCreator
   bc.Initialize(bmp1.Width + bmp2.Width, Max(bmp1.Height, bmp2.Height))
   Dim r As B4XRect
   r.Initialize(0, 0, bmp1.Width, bmp1.Height)
   bc.DrawBitmap(bmp1, r, True)
   r.Initialize(bmp1.Width, 0, bc.mWidth, bmp2.Height)
   bc.DrawBitmap(bmp2, r, True)
   Return bc.Bitmap
End Sub

 

[jroriz]

Untested code:

Sub MergeTwoBitmapsSideBySide(bmp1 As B4XBitmap, bmp2 As B4XBitmap) As B4XBitmap
   Dim bc As BitmapCreator
   bc.Initialize(bmp1.Width + bmp2.Width, Max(bmp1.Height, bmp2.Height))
   Dim r As B4XRect
   r.Initialize(0, 0, bmp1.Width, bmp1.Height)
   bc.DrawBitmap(bmp1, r, True)
   r.Initialize(bmp1.Width, 0, bc.mWidth, bmp2.Height)
   bc.DrawBitmap(bmp2, r, True)
   Return bc.Bitmap
End Sub

Perfect!