B4J Question treeView parent background color

[atiaust]

Hi All,

Is it possible to change the background color of each parent line in a treeView?

Thanks

 

[Erel]

Which lines are you asking about?

 

[atiaust]

Hi Erel,

Parent (change this line color)
Child
Grandchild
Parent (change line color) etc
Child
Parent (change line color)

Change the Parent line color?

Possible?

Thanks

 

[Erel]

I don't see any line.

 

[atiaust]

Change background color of Item #1, Item #2 & Item #3 lines

 

[Cableguy]

Yes, using CSS!

 

[atiaust]

Thanks Cableguy

Do you have an example to apply it just to the parent Items?

 

[Cableguy]

I know it's possible, but i don't have examples with me as i am browsing from my phone, at my day job, but you can search for JavaFx Treeview node css, and surely a lot of examples will show up....
Like this one

http://stackoverflow.com/questions/...nge-javafx-treeview-background-and-text-color

 

[Erel]

Code to change the text color of specific items:

Sub AppStart (Form1 As Form, Args() As String)
   MainForm = Form1
   MainForm.RootPane.LoadLayout("1")
   For i = 1 To 10
     Dim parent As TreeItem = CreateTreeItem("Parent " & i, fx.Colors.Red, fx.DefaultFont(20))
     Dim child As TreeItem = CreateTreeItem("Child", fx.Colors.Blue, fx.DefaultFont(14))
     parent.Children.Add(child)
     TreeView1.Root.Children.Add(parent)
   Next
   MainForm.Show
End Sub

Sub CreateTreeItem(Text As String, Color As Paint, Font As Font) As TreeItem
   Dim ti As TreeItem
   ti.Initialize("", "")
   Dim tf As TextFlow
   tf.Initialize
   tf.AddText(Text)
   tf.SetColor(Color)
   tf.SetFont(Font)
   Dim jo As JavaObject = ti
   Dim p As Pane = tf.CreateTextFlow
   jo.RunMethod("setGraphic", Array(p))
   Return ti
End Sub

TextFlow: https://www.b4x.com/android/forum/t...-similar-to-b4a-b4i-richstring.61237/#content

I'm not sure that it is possible to change the background color of specific items.

 

[atiaust]

Thanks Erel,

That will work for me.

 

[atiaust]

Hi Erel,

I have just discovered that using the code above creates the treeItems OK but if you use treeView1_SelectedItemChanged and try to get the text for the item, selectedItem.text returns "" (empty string).

Can you suggest how to get around this?

Have attached an example app.

Thanks

 

[Erel]

See this post: https://www.b4x.com/android/forum/threads/textflow-adding-images-other-fonts.79384/#post-502948 (and a few above it).

 

[atiaust]

Thanks.

Fixed by adding p.Tag = Text to the CreateTreeItem sub

And in the treeView1_SelectedItemChanged added Dim jo etc..

Sub CreateTreeItem(Text As String, Color As Paint, Font As Font) As TreeItem
    Dim ti As TreeItem
    ti.Initialize("", "")
    Dim tf As TextFlow
    tf.Initialize
    tf.AddText(Text)
    tf.SetColor(Color)
    tf.SetFont(Font)
    Dim jo As JavaObject = ti
    Dim p As Pane = tf.CreateTextFlow
    p.Tag = Text
    jo.RunMethod("setGraphic", Array(p))
    Return ti
End Sub

Sub TreeView1_SelectedItemChanged(SelectedItem As TreeItem)
    Log("SelectedItem text = "&SelectedItem.Text)
    Dim jo As JavaObject = SelectedItem
    Dim p As Pane = jo.RunMethod("getGraphic", Null)
    Log(p.Tag)
End Sub