Android Tutorial Android Serial tutorial

The code in this tutorial should not be used for new projects.
New tutorial:
https://www.b4x.com/android/forum/threads/android-bluetooth-bluetoothadmin-tutorial.14768/#content

This tutorial covers the Serial library. This library allows you to connect with other Bluetooth devices using virtual serial ports (RFCOMM).

The Serial library requires Android OS 2.0 or above (API level 5 or above).

We will build a simple chat example which allows two connected devices to send text messages.


serial_chat2.png


We created a process global object named Serial1 of type Serial.
Usually it is a good idea to initialize process objects in Sub Activity_Create when FirstTime is True. This way the objects will be initialized exactly once.

B4X:
Sub Activity_Create(FirstTime As Boolean)
    If FirstTime Then
        Serial1.Initialize("Serial1")
        Timer1.Initialize("Timer1", 200)
    End If
    Activity.LoadLayout("1")
    Activity.AddMenuItem("Connect", "mnuConnect")
    Activity.AddMenuItem("Disconnect", "mnuDisconnect")
End Sub
The next Sub running is Activity_Resume:
B4X:
Sub Activity_Resume
    If Serial1.IsEnabled = False Then
        Msgbox("Please enable Bluetooth.", "")
    Else
        Serial1.Listen 'listen for incoming connections
    End If
End Sub
Here we are checking if the Bluetooth device is enabled. If it is not enabled we ask the user to enable it. Note that by putting this code in Activity_Resume (and not Activity_Create) this test will happen every time the activity is resumed. So if the user goes to the settings screen, enables the device and then returns to our application we will now know that the Bluetooth is enabled.

If the Bluetooth is enabled we start listening for incoming connections. This allows other devices to connect with our device. This is not required if you connect to a device that listens for connections (like external GPS for example).
Note that calling Listen more than once doesn't do anything. So we are safe calling it this way.

When the user presses on the Connect menu item we show the user the list of known paired devices. When the user clicks on a device name we fetch its MAC address from the map and connect to it:

serial_chat_1.png


B4X:
Sub mnuConnect_Click
    Dim PairedDevices As Map
    PairedDevices = Serial1.GetPairedDevices
    Dim l As List
    l.Initialize
    For i = 0 To PairedDevices.Size - 1
        l.Add(PairedDevices.GetKeyAt(i)) 'add the friendly name to the list
    Next
    Dim res As Int
    res = InputList(l, "Choose device", -1) 'show list with paired devices
    If res <> DialogResponse.CANCEL Then
        Serial1.Connect(PairedDevices.Get(l.Get(res))) 'convert the name to mac address
    End If
End Sub
The connection is not established immediately. It will happen in the background. When the connection is established, the Connected event will be raised. A 'Success' parameter tells us if the connection is successful.
The Connected event can also be raised if an incoming connection is established.

B4X:
Sub Serial1_Connected (Success As Boolean)
    If Success Then
        ToastMessageShow("Connected successfully", False)
        TextReader1.Initialize(Serial1.InputStream)
        TextWriter1.Initialize(Serial1.OutputStream)
        timer1.Enabled = True
        connected = True
    Else
        connected = False
        Timer1.Enabled = False
        Msgbox(LastException.Message, "Error connecting.")
    End If
End Sub
If the connection was established successfully we can start the data transfer.
TextReader1 and TextWriter1 are process global object. We now initialize them using the serial stream. This will allow us to send and receive text over our newly created connection.
Timer1 is used to test whether there is incoming data (and read this data). Now we enable it and start listening.

If the connection is not successful we retrieve the exception and show it.

Sending messages - When the user presses on btnSend we send the text:
B4X:
Sub btnSend_Click
    If connected Then
        TextWriter1.WriteLine(txtSend.Text)
        TextWriter1.Flush
        txtSend.Text = ""
    End If
End Sub
'connected' is a variable that we use to know if we are currently connected.
Note that we call Flush after writing the text. This way we make sure that TextWriter doesn't buffer the text and sends it right away.

Receiving messages - Whenever the timer ticks we check if there is any data waiting to be read. If there is, we read it and add it to the large EditText:
B4X:
Sub Timer1_Tick
    If connected Then
        If TextReader1.Ready Then 'check if there is any data waiting to be read
            txtLog.Text = txtLog.Text & TextReader1.ReadLine & CRLF
            txtLog.SelectionStart = txtLog.Text.Length
        End If
    End If
End Sub
TextReader.ReadLine is a blocking call. It waits till there is at least a single character to be read. Therefore we need to test TextReader.Ready if we don't want to block our application.

This application can also be used to connect with non-Android devices.
An external GPS for example:
serial_3.png


The external GPS continuously sends its data as text.
I actually had quite an interesting conversation with the external GPS...

The program is attached.

Edit: It is recommended to use the new AsnycStreams object instead of polling the available bytes parameter with a timer. Using AsyncStreams is simpler and more reliable.
 

Attachments

  • SerialExample.zip
    6.3 KB · Views: 10,527
Last edited:

BluSky76

Member
Licensed User
Longtime User
Erel,

does not work. If between a write command and the subsequent enter even a simple log ("x") does not match the consequence that it is impossible to read the answers.

You can create an example of sending two strings based on the response?
 

Felix Maria

Member
Licensed User
Longtime User
Thanks Erel, It did work with AsyncStreams.
And Agraham's lovely Byteconvertor lib also came in handy to convert the bytes to hex as needed.

Your Forum is excellent.
Think of the Doubt and the Solution is already on the forum.

Love B4A!
 

BluSky76

Member
Licensed User
Longtime User
Erel,
sorry but I do not understand.

You can try to send 10 strings of type

1) send
reply

how to stop the program here to read the response and then send.

2) send
reply

etc.
 

BluSky76

Member
Licensed User
Longtime User
Erel,
I have to send a binary file into blocks of 48byte you have a solution?

With FileTrasfer did not succeed.

Thanks
 

BluSky76

Member
Licensed User
Longtime User
Erel,
use

Dim As InputStream in = File.OpenInput (dir, fileName)
countingStream.Initialize (In)

now I can not go on. How to send byte blocks at a constant length using astreams.Write
 

Tommy Green

New Member
Hi,

I am trying to send a 2 digit number to my bluetooth device and it not working properly.

Sub btnSend_Click
If connected Then
TextWriter1.WriteLine(12)
TextWriter1.Flush
End If
End Sub


Its is sending 1 and then 2 instead of 12

Can anyone help me?
 

agus mulyana

Member
Licensed User
Longtime User
Hi Erel,

I still got an error, when I try to read serial data from arduino uno via Bluetooth, my device is freeze, i use LG Mobile Phone, what should i do ? ( I use an arduino Uno, Bluetooth HC-05/HC-06 )



How can I solve it?

thanks you
 

StillLearning

Member
Licensed User
Longtime User
Is there a way to make the choose list only be populated with HID or SPP devices?

Like a list of serial or keyboard devices?

I would prefer just SPP devices if possible, but I think I read that that is not possible

Thank You
 

luciano deri

Active Member
Licensed User
Longtime User
Hy, with this method can i connect a barcode scanner bluetooth? Can i read the flow of chars on port by scanner before view in a edit text?
Thanks
 

luciano deri

Active Member
Licensed User
Longtime User
It depends on the scanner. If it supports the SPP profile then you can connect to it and read the data.
Yes, Motorola CS3070 support it, could give me an example for understand right? In the test that i have done with Serial Example i had finded some difficult.
The problem is here
B4X:
Sub Timer1_Tick
    If connected Then
        If TextReader1.Ready Then 'check if there is any data waiting to be read
' the Up is blocked in this line after scanned barcode!
            txtLog.Text = TextReader1.ReadLine
          
        End If
    End If
End Sub
 
Last edited:

Similar Threads

  • Locked
  • Article
Android Tutorial Android JSON tutorial
Replies
90
Views
158K
  • Locked
  • Article
Android Tutorial SQL tutorial
Replies
161
Views
276K
  • Locked
  • Article
Android Tutorial GPS tutorial
Replies
310
Views
253K
Top