Android Example Auto starting your app

Hi all!

Here is what you need to auto start your app at boot up.
Create a service module and paste in the code below:

#Region  Service Attributes
    #StartAtBoot: True
#End Region

Sub Process_Globals
    '--- These global variables will be declared once when the application starts.
    '--- These variables can be accessed from all modules.
 
    Private tmrStart As Timer
 
End Sub
Sub Service_Create
    '--- set timer to start app after 1 seconds
    '--- this gives time for system to init other stuff
    tmrStart.Initialize("tmrStart",1000)
End Sub

Sub Service_Start (StartingIntent As Intent)
    '--- enabled timer
    tmrStart.Enabled = True
End Sub

Private Sub Service_Destroy
End Sub


Sub tmrStart_Tick
    tmrStart.Enabled = False
    '--- if we find the file 'autoStart.dat' in the folder 'File.DirInternal'
    '--- then auto start the app.
    Dim checkFile As String = "autoStart.dat"
    If File.Exists(File.DirInternal,checkFile) Then
        Log("Auto Start is enabled")
        StartActivity(Main) 
    Else
        Log("Auto Start is disabled")
    End If
 
End Sub

This service module will now auto start at boot up. if it finds a file 'autoStart.dat' in the 'File.DirInternal' folder it will activate the main activity and auto start your app.

Here is a helper function to create the file that will auto-start or not auto-start your app.

Sub SetAutoStartAppOn(turnON As Boolean) 
    Dim checkFile As String = "autoStart.dat"
    If turnON Then
        If Not (File.Exists(File.DirInternal,checkFile)) Then
            File.WriteString(File.DirInternal,checkFile,"on")
        End If
    Else
        If File.Exists(File.DirInternal,checkFile) Then
            File.Delete(File.DirInternal,checkFile)
        End If
    End If
End Sub

Public Sub GetAutoStartAppOn() As Boolean
    Dim checkFile As String = "autoStart.dat"
    If File.Exists(File.DirInternal,checkFile) Then 
        Return True
    Else
        Return False
    End If
End Sub

Have fun!!!

 

[Shadow&Max]

Jake, this is pretty cool... Out of curiosity (I actually want to do this), is there a way to start your app up at a given time rather than at boot? If someone starts up the app, but doesn't turn their phone off, I'd want the app to automatically run at say &:45am or 6:15pm...

 

[barx]

Jake, this is pretty cool... Out of curiosity (I actually want to do this), is there a way to start your app up at a given time rather than at boot? If someone starts up the app, but doesn't turn their phone off, I'd want the app to automatically run at say &:45am or 6:15pm...

look up StartServiceAt

 

[Shadow&Max]

Thanks!

 

[vecino]

Nice. Thank you.

 

[sorex]

@JakeBullet70 : what's the secret in this routine?

Is the OS scanning the apps for that autostart file?

 

[Erel]

Edit: better to implement with receiver: Receivers and Services in 2023+

The #StartAtBoot: True attribute adds an item to the manifest file which tells the OS that this service should be started after boot completes.

 

[sorex]

If I have 3 services (network, server, client) do I need to set those all 3 to StartAtBoot or just 1 that opens the activity where the other 2 are started?

 

[Erel]

Only one. Don't start an activity at that point, only services.

 

[trueboss323]

It is good, but only 1 problem, is there a way I can start the app minimized? That way it is already loaded in memory?

 

[Erel]

The process will start and the service will run.

 

[trueboss323]

The process will start and the service will run.

But how do I do it minimized? I do not want the app to show in the foreground when it auto boots up.

 

[Erel]

Not sure what you mean with minimized. Services do not show any UI.

 

[trueboss323]

Not sure what you mean with minimized. Services do not show any UI.

Well I don't know why, but for me, when I try to restart the device, after the lock screen, my app comes into foreview.

 

[Erel]

Can you post your service code?

 

[trueboss323]

Here is what I have:

#Region  Service Attributes
    #StartAtBoot: True
#End Region

Sub Process_Globals
    '--- These global variables will be declared once when the application starts.
    '--- These variables can be accessed from all modules.
    Private tmrStart As Timer
End Sub
Sub Service_Create
    '--- set timer to start app after 1 seconds
    '--- this gives time for system to init other stuff
    tmrStart.Initialize("tmrStart",1000)
End Sub

Sub Service_Start (StartingIntent As Intent)
    '--- enabled timer
    tmrStart.Enabled = True
End Sub

Private Sub Service_Destroy
End Sub


Sub tmrStart_Tick
    tmrStart.Enabled = False
    '--- if we find the file 'autoStart.dat' in the folder 'File.DirInternal'
    '--- then auto start the app.
    Dim checkFile As String = "autoStart.dat"
    If File.Exists(File.DirInternal,checkFile) Then
        Log("Auto Start is enabled")
        StartActivity(Main)
    Else
        Log("Auto Start is disabled")
    End If
End Sub

 

[Erel]

Don't call StartActivity if you don't want to show any UI.

 

[KMatle]

What is the timer good for? Some sort of delay?

 

[raphael75]

What is the timer good for? Some sort of delay?

The reason is written in the comments

Sub Service_Create
    '--- set timer to start app after 1 seconds
    '--- this gives time for system to init other stuff
    tmrStart.Initialize("tmrStart",1000)
End Sub

 

[KMatle]

DIM MyAgenda as Agenda
MyAgenda.Initialize("Me")
MyAgenda.add("MUST get new glasses ")