Android Question How to change a certain value in a list containing "Type elements"?

[Andie]

I have the feeling I should know this. However, I don't. So here is my question:

I defined a Type person and filled the list person_list with elements based on this structure person:

    Type person(name As String, profession As String)
    Dim person_data As person
    
    Dim person_list As List
    
    person_data.name = "Mick"
    person_data.profession = "singer"
    person_list.Add(person_data)
    '
    person_data.name = "Keith"
    person_data.profession = "bass guitarist"
    person_list.Add(person_data)
    '
    person_data.name = "Charlie"
    person_data.profession = "drummer"
    person_list.Add(person_data)

How can I change the profession of Keith from "bass guitarist" to "guitarist"?

 

[Daestrum]

    Type person(name As String, profession As String)

...
    
    Dim person_list As List
    
    person_list.Initialize
    
    Dim person_data As person
    person_data.Initialize
    person_data.name = "Mick"
    person_data.profession = "singer"
    person_list.Add(person_data)
    '
    Dim person_data As person
    person_data.Initialize
    person_data.name = "Keith"
    person_data.profession = "bass guitarist"
    person_list.Add(person_data)
    '
    Dim person_data As person
    person_data.Initialize
    person_data.name = "Charlie"
    person_data.profession = "drummer"
    person_list.Add(person_data)
    
    Log(person_list)
    
    For Each p As person In person_list
        If p.name = "Keith" Then
            p.profession = "guitarist"
        End If
    Next
    Log(person_list)

 

[Daestrum]

Or cleaner way (using the auto generated sub for the type)

    Type person(name As String, profession As String)
...
    Dim person_list As List
  
    person_list.Initialize

    person_list.Add(Createperson("Mick","singer"))
    '
    person_list.Add(Createperson("Keith","bass guitarist"))
    '
    person_list.Add(Createperson("Charlie","drummer"))
  
    Log(person_list) ' before change
  
    For Each p As person In person_list
        If p.name = "Keith" Then
            p.profession = "guitarist"
        End If
    Next
    Log(person_list) ' after change
...


Public Sub Createperson (name As String, profession As String) As person
    Dim t1 As person
    t1.Initialize
    t1.name = name
    t1.profession = profession
    Return t1
End Sub

You could add an Exit after the line p.profession = "guitarist" to save reading any more of the list.

 

[emexes]

Another way of loading the list:

Type Person(name As String, profession As String) 
...
Dim InitData() As Object = Array("Mick", "singer", "Keith", "bass guitarist", "Charlie", "drummer")
  
Dim person_list As List
person_list.Initialize
  
For I = 0 To InitData.Length - 2 Step 2
    Dim person_data As Person
    person_data.initialize
    person_data.name = InitData(I + 0)
    person_data.profession = InitData(I + 1)
    person_list.Add(person_data)
Next

Log(person_list)

 

[William Lancee]

I always like the Type approach.
I would make it a map of types.

    Dim person_Map As Map
    person_Map.Initialize
    person_Map.Put("Mick", Createperson("Mick","singer"))
    person_Map.Put("Keith", Createperson("Keith","bass guitarist"))
    person_Map.Put("Charlie", Createperson("Charlie","drummer"))
    
    Log(person_Map.Get("Keith").As(person).profession)    'bass guitarist
    person_Map.Get("Keith").As(person).profession = "guitarist"
    Log(person_Map.Get("Keith").As(person).profession)    'guitarist

 

[William Lancee]

Putting the map loading in the type creator is better.

    Dim persons As Map
    persons.Initialize
    NewPerson(persons, "Mick","singer")
    NewPerson(persons, "Keith","bass guitarist")
    NewPerson(persons, "Charlie","drummer")
    
    Log(persons.Get("Keith").As(person).profession)    'bass guitarist
    persons.Get("Keith").As(person).profession = "guitarist"
    Log(persons.Get("Keith").As(person).profession)    'guitarist

Public Sub NewPerson (db As Map, name As String, profession As String) As person
    Dim t1 As person
    t1.Initialize
    t1.name = name
    t1.profession = profession
    db.Put(name, t1)
    Return t1
End Sub

 

[LucaMs]

If you only have two fields, KeyValueStore comes in handy.

Dim KVS As KeyValueStore
KVS.Initialize("...", "...")
'Fill KVS here

'Change (overwrite)
Dim IndexOf As Int
IndexOf = KVS.ListKeys.IndexOf("Keith")
KVS.Put(IndexOf, "guitarist")

'Horrible version:

'Change (overwrite)
KVS.Put(KVS.ListKeys.IndexOf("Keith"), "guitarist")

If there are more than two fields, it is better to use a DB (SQLite).