B4J Question How to move a rotated node with mouse?

[xulihang]

Hi there,

Previously, I asked how to drag a node to move it: https://www.b4x.com/android/forum/t...ve-it-to-another-position.106875/#post-668735

Now, I am trying to drag a rotated node and I am having trouble using the previous code.

Here is the code I used to rotate a node:

    Dim jo As JavaObject = Button1
    jo.RunMethod("setRotate",Array(120.0))

 

[xulihang]

Here is a test project.

 

[Erel]

Correct code to rotate a view:

Button1.Rotation = 120 'Button1 type should be B4XView

I haven't tried your project. Have you tried to put the rotated view in a panel and move the panel?

 

[xulihang]

I did try to move a rotated node in a pane. This works. But I prefer to move it directly.

 

[xulihang]

Found this post: https://stackoverflow.com/questions/27080039/proper-way-to-move-a-javafx8-node-around

I modified my code, which works better. The node will not fly away. But still not perfect, I need to drag the center point so that the node will not shift.

Private Sub Pane1_MousePressed (EventData As MouseEvent)
    Dim jo As JavaObject = Sender
    pressedX = jo.RunMethod("getLayoutX",Null) + EventData.X
    pressedY = jo.RunMethod("getLayoutY",Null) + EventData.Y
End Sub

Private Sub Pane1_MouseDragged (EventData As MouseEvent)
    Dim event As JavaObject = EventData
    Dim jo As JavaObject = Sender
    
    Dim offsetX, offsetY As Double
    offsetX = event.RunMethod("getSceneX",Null) - pressedX
    offsetY =  event.RunMethod("getSceneY",Null)- pressedY
    jo.RunMethod("setTranslateX",Array(offsetX))
    jo.RunMethod("setTranslateY",Array(offsetY))
End Sub

 

[xulihang]

Here is the version that works perfectly (based on this: https://stackoverflow.com/questions/33043173/javafx-drag-rotated-node)

Private Sub Pane1_MouseDragged (EventData As MouseEvent)
    Dim event As JavaObject = EventData
    Dim jo As JavaObject = Sender
    
    Dim offsetX, offsetY As Double
    offsetX = event.RunMethod("getSceneX",Null) - pressedX
    offsetY =  event.RunMethod("getSceneY",Null)- pressedY
    jo.RunMethod("setTranslateX",Array(jo.RunMethod("getTranslateX",Null)+offsetX))
    jo.RunMethod("setTranslateY",Array(jo.RunMethod("getTranslateY",Null)+offsetY))
    pressedX = event.RunMethod("getSceneX",Null)
    pressedY = event.RunMethod("getSceneY",Null)
End Sub

Private Sub Pane1_MousePressed (EventData As MouseEvent)
    Dim event As JavaObject = EventData
    pressedX = event.RunMethod("getSceneX",Null)
    pressedY = event.RunMethod("getSceneY",Null)
End Sub

 

[xulihang]

Modified a bit to use the view's left and top instead of setTranslateX.

Private Sub Pane1_MouseDragged (EventData As MouseEvent)
    Dim event As JavaObject = EventData
    Dim n As Node = Sender
    Dim offsetX, offsetY As Double
    offsetX = event.RunMethod("getSceneX",Null) - pressedX
    offsetY =  event.RunMethod("getSceneY",Null)- pressedY
    n.Left = n.Left + offsetX
    n.Top = n.Top + offsetY
    pressedX = event.RunMethod("getSceneX",Null)
    pressedY = event.RunMethod("getSceneY",Null)
End Sub

Private Sub Pane1_MousePressed (EventData As MouseEvent)
    Dim event As JavaObject = EventData
    pressedX = event.RunMethod("getSceneX",Null)
    pressedY = event.RunMethod("getSceneY",Null)
End Sub