Android Tutorial Introduction to the libGDX library

Introduction to the libGDX library

What is libGDX ?

libGDX is a game engine. As we saw in the first tutorial, a game engine provides a framework to create games and covers all aspects (rendering, animation, input, music, networking, physics, ...) of various kinds of games.

libGDX is considered as one of the best and fastest engine for the Android world. It is free, rich-featured, reliable, and proved its efficiency in a lot of well-known games (Ingress, Zombie Smasher, Apparatus, Monsterama Park, Clash of the Olympians, Bumbledore, etc.)

It’s a layered framework: it goes from low-level classes for OpenGL experts to high-level classes, easy to use by beginners. It includes a scene graph (Scene2D classes), a physics engine (Box2D classes), a particle system, a map renderer, a sprite batcher, an extensive set of mathematics classes… more than 200 classes in total.

For technical reasons, the version for Basic4Android cannot be multi-platform, and by choice, the current release doesn't include the 3D classes (except the ones for the perspective camera and for the decals) and the Daydream class.

libGDX was created in 2010 by Mario Zechner (badlogicgames.com) and is maintained by M. Zechner, Nathan Sweet (esotericsoftware.com) and a community of developers.

Minimum requirements

OpenGL ES 2.0
Android Froyo (API 8)

Hardware acceleration

libGDX does not require that you enable hardware acceleration on your device because it is based on OpenGL, which interacts directly with the GPU.

Debugging

You cannot use the debugger of B4A with libGDX because most of the code of the library runs in a different thread. You have to use the Log() function to debug your game.

The library provides a debug renderer for Box2D (lgBox2DDebugRenderer), a debug renderer for Scene2D (lgScn2DDebugRenderer) and a profiler for OpenGL (lgGLProfiler).

A word about the classes

The main class is LibGDX. All other classes are prefixed by lg.
All Box2D classes are prefixed by lgBox2D. All Scene2D classes are prefixed by lgScn2D. All Map classes are prefixed by lgMap. All Math classes are prefixed by lgMath.

The LibGDX class gives access to five interfaces: Audio (lgAudio), Files (lgFiles), Graphics (lgGraphics), Input (lgInput), and Net (lgNet). You will use the Input interface, for example, to get the input from the accelerometer.

With some classes (e.g. the five interfaces), you cannot create a new instance with Dim. You have to use an instance returned by the library. For example, you cannot write:
B4X:
Dim Graphics As lgGraphics
Graphics = lGdx.Graphics
but you can write:
B4X:
Dim Graphics As lgGraphics = lGdx.Graphics

Some classes cannot be instantiated at all because they are generic classes (e.g. com.badlogic.gdx.scenes.scene2d.utils.Drawable or com.badlogic.gdx.maps.tiled.TiledMapTile). In this case, either you store their instance as an Object or you use a subclass, e.g.:
B4X:
Dim objTile As Object = CurrentLayer.GetCell(X, Y).Tile
Dim staticTile As lgMapStaticTiledMapTile = CurrentLayer.GetCell(X, Y).Tile

OpenGL ES

I explained what OpenGL is in the previous tutorial and I won't discuss it further here because the main advantage to use a game engine like libGDX is to benefit from the abstraction layer above OpenGL. However, if you need (or want) to call directly OpenGL, here's how to get access to the classes and functions:
B4X:
Dim lGdx_GL20 As lgGL20 = lGdx.Graphics.GL20
or better (includes also the constants):
B4X:
Dim GL As lgGL

Note: libGDX uses the 2D coordinate system and the color encoding of OpenGL ES, so the Y-axis is pointing upwards and each color value ranges from 0 to 1.

The libGDX life-cycle

An important thing to keep in mind about libGDX is that it runs in its own thread. Your Basic4Android application runs most of the time in a different thread called the UI thread, or main thread. That means you cannot access the other views of your activity and change their properties from the libGDX thread. Fortunately, there's a function in the LibGDX class that passes the runnable (the piece of code to execute) from a thread to the other: CallSubUI. So if you want to change the activity title, set a label text or show a MsgBox from the libGDX thread, don't forget to use this function to avoid a crash!

Since libGDX runs in a different thread, you have to inform its library of the events of your activity : Create, Pause and Resume. First, create an instance of libGDX in Globals :
B4X:
Dim lGdx As libGDX
In Activity_Create (and nowhere else), add the Initialize function :
B4X:
lGdx.Initialize(False, "LG") 'fills the activity with the libGDX surface, uses OpenGL 1 for compatibility and prefixes the events with LG
In Activity_Resume, add the following line :
B4X:
If lGdx.IsInitialized Then lGdx.Resume
In Activity_Pause, add the following line :
B4X:
If lGdx.IsInitialized Then lGdx.Pause

You could initialize libGDX differently. For example, it could be limited to a view with InitializeView. You could also define a configuration (lgConfiguration class) and pass it to libGDX. Example:
B4X:
Dim Config As lgConfiguration

'Disables the accelerometer and the compass
Config.useAccelerometer = False
Config.useCompass = False

'Uses a WakeLock (the device will stay on)
Config.useWakelock = True

'Creates the libGDX surface
lGdx.Initialize2(Config, "LG")

Once done, your library is ready to raise the events of its life-cycle : Create, Resize, Render, Pause, Resume, Dispose. These events are the place to put all the code of your game. Don't put anything in the usual activity events. They are reserved for your other views and are raised by the UI thread.

Create :

Create is the first raised event. It is raised soon after the initialization of the library and the creation of the OpenGL surface.
In this event, initialize your renderer and your input processors, load your resources (we'll see that in detail later) and initialize your game data.

Resize :

Resize is raised when the size of the libGDX surface changes. Under Android, that should only happen when you start the application and when it is restarted after a rotation or resumed.
It is raised at least once, after Create, and, when the application is resumed, just before Resume.
In this event, initialize the camera viewport. It's probably the only use you will find for it.
This event returns the new width and height in pixels.

Render :

Render is raised as soon as possible after Create and Resize.
It's where things are drawn. It's also where you have to put the logic of your game, but I would not recommend putting hundreds of lines of code here. Instead, create new subs and new modules and call them from this event.
The first lines in Render should be to clear the screen. Example:
B4X:
lGdx_GL.glClearColor(0, 0, 1, 1) 'Blue background
lGdx_GL.glClear(lGdx_GL.GL10_COLOR_BUFFER_BIT)

Pause :

Pause is raised when the activity is sent in the background, rotated or exited.
It's the right place to save your game data.
Note that the OpenGL context is destroyed when the app goes in the background, so all your unmanaged textures and pixmaps have to be reloaded or recreated in the Resume event when the app returns to the foreground.

Resume :

Contrary to the Resume event of your activity, this one is not raised after Create, only when the application returns from a pause.
As the OpenGL context is destroyed when the app goes in the background, all your unmanaged* textures and pixmaps have to be reloaded or recreated when this event is raised. More info here. *Not loaded by an asset manager.

Dispose :

Dispose is called when the activity is exited, after Pause, or when the device is rotated.
In this event, release all the used resources by calling the Dispose function of objects (if they have one).

The life-cycle :
application_lifecycle_diagram.png


Multiple screens

A game is made of many screens. You could create an activity for each one, but that would not be very convenient because you'd have to reinitialize the library in each activity and reload some resources. Moreover, that would not ease any graphical transition between screens. In fact, most games are made with a very small number of activities and make use of a screen manager instead. The screen manager stores the reference of the different screens and allows switching between them. Each screen has its own life-cycle.
To create a screen manager with two screens, for example, declare them in Globals:
B4X:
Dim lGdx_ScrMgr As lgScreenManager
Dim lGdx_Screen(2) As lgScreen
Then add these lines in the Create event handler:
B4X:
'Creates two screens
lGdx_ScrMgr.Initialize(lGdx)
lGdx_Screen(0) = lGdx_ScrMgr.AddScreen("LGS1")
lGdx_Screen(1) = lGdx_ScrMgr.AddScreen("LGS2")
Show the first screen:
B4X:
lGdx_ScrMgr.CurrentScreen = lGdx_Screen(0)

When you want to change the current screen, just change the value of the CurrentScreen property. That will raise the Hide event of the previous screen and the Show event of the new one.

The screens have the same life-cycle as the library, and thus the same events except that Create is named Show and Dispose is named Hide.

Input processor and gesture detector

To get the input events raised by your players, you have to declare input processors. libGDX has an input processor for keyboard and touch events (lgInputProcessor) and a specialized input processor for gestures (lgGestureDetector).
Start by declaring them in Globals:
B4X:
Dim lGdx_IP As lgInputProcessor
Dim lGdx_GD As lgGestureDetector
Initialize them in the Create event (or the Show event of a screen if you want different processors for different screens):
B4X:
lGdx_IP.Initialize("IP")
lGdx_GD.Initialize("GD")
And add the event handlers that you need:
B4X:
Sub IP_KeyDown(KeyCode As Int) As Boolean
   Return False
End Sub

Sub IP_KeyUp(KeyCode As Int) As Boolean
   Return False
End Sub

Sub IP_KeyTyped(Character As Char) As Boolean
   Return False
End Sub

Sub IP_TouchDown(ScreenX As Int, ScreenY As Int, Pointer As Int) As Boolean
   Return False
End Sub

Sub IP_TouchDragged(ScreenX As Int, ScreenY As Int, Pointer As Int) As Boolean
   Return False
End Sub

Sub IP_TouchUp(ScreenX As Int, ScreenY As Int, Pointer As Int) As Boolean
   Return False
End Sub

Sub GD_TouchDown(X As Float, Y As Float, Pointer As Int) As Boolean
   Return False
End Sub

Sub GD_Fling(VelocityX As Float, VelocityY As Float) As Boolean
   Return False
End Sub

Sub GD_LongPress(X As Float, Y As Float) As Boolean
   Return False
End Sub

Sub GD_Pan(X As Float, Y As Float, DeltaX As Float, DeltaY As Float) As Boolean
   Return False
End Sub

Sub GD_Pinch(InitialPointer1 As lgMathVector2, InitialPointer2 As lgMathVector2, Pointer1 As lgMathVector2, Pointer2 As lgMathVector2) As Boolean
   Return False
End Sub

Sub GD_Tap(X As Float, Y As Float, Count As Int) As Boolean
   Return False
End Sub

Sub GD_Zoom(InitialDistance As Float, Distance As Float) As Boolean
    Return False
End Sub

Description of events :

Fling: The user quickly dragged a finger across the screen, then lifted it. Useful to implement swipe gestures.
Pan: The user is dragging a finger across the screen. The detector reports the current touch coordinates as well as the delta between the current and previous touch positions. Useful to implement camera panning in 2D.
Pinch: Similar to zoom. The detector reports the initial and current finger positions instead of the distance. Useful to implement camera zooming and more sophisticated gestures such as rotation.
Tap: The user touched the screen and lifted the finger. The finger must not move outside a specified square area around the initial touch position for a tap to be registered. Multiple consecutive taps will be detected if the user performs taps within a specified time interval.
Zoom: The user has placed two fingers on the screen and is moving them together/apart. The detector reports both the initial and current distance between fingers in pixels. Useful to implement camera zooming.

The other events are self-explanatory.

.....
 
Last edited:

Informatix

Expert
Licensed User
Longtime User
Hi again Informatix, sorry to bother you again. Has anything else changed in the new version I am unaware of?

I now get this error:-
java.lng.NullPointer Exception
at com.badlogic.gdx.graphics.g2d.SpriteBatch.flush(SourceFile:958)
with this line of code
Batch.DrawTex2(pandaFrontTexture,mypanda.x,mypanda.y,ScreenW*0.08,ScreenH*0.2)

I had all this working before I thought about trying the gestures instead of buttons.
The complete changelog is in the first post of the libGDX thread.
 

Carcas

Member
Licensed User
Longtime User
Hello everyone,

how can I add an event to a cell in a hexagonal map?
I want that the hexagons are clickable.

There is no event on the cell !!! (I read the documentation)
You can not add buttons ...
There are no references to the position (X, Y) of the cell on the screen

How did you solve?

Thx Yu
 

JEG

Member
Licensed User
Longtime User
The following works for polygons
1 Get the x/y values from GD_Tap
2 Find the bounding rectangle containing the x/y value
3 If x/y falls in more than one bounding rectangle then
4 For each bounding rectangle get the vertices (v) for the polygon then

Dim comtri As lgMathEarClippingTriangulator
Dim PnP As lgMathIntersector
Dim LSA As lgShortArray

LSA=comtri.computeTriangles(v)
For k = 0 To (LSA.Size-3) Step 3
p1 = LSA.get(k)*2
p2 = LSA.get(k + 1)*2
p3 = LSA.get(k + 2)*2
If PnP.isPointInTriangle(Tx1,Ty1,v(p1),v(p1+1),v(p2),v(p2+1),v(p3),v(p3+1))Then

this is the required polygon
 

Informatix

Expert
Licensed User
Longtime User
The following works for polygons
1 Get the x/y values from GD_Tap
2 Find the bounding rectangle containing the x/y value
3 If x/y falls in more than one bounding rectangle then
4 For each bounding rectangle get the vertices (v) for the polygon then

Dim comtri As lgMathEarClippingTriangulator
Dim PnP As lgMathIntersector
Dim LSA As lgShortArray
LSA=comtri.computeTriangles(v)
For k = 0 To (LSA.Size-3) Step 3
p1 = LSA.get(k)*2
p2 = LSA.get(k + 1)*2
p3 = LSA.get(k + 2)*2
If PnP.isPointInTriangle(Tx1,Ty1,v(p1),v(p1+1),v(p2),v(p2+1),v(p3),v(p3+1))Then

this is the required polygon
You can do something simpler because you don't really need accuracy for a touch. You can use a grid with rectangular cells to detect the touched hexagon:
grid.jpg

And the code has to take into account the camera position and zoom factor. Here's the solution that I use in my game:
B4X:
Sub GD_TouchDown(X As Float, Y As Float, Pointer As Int) As Boolean
    'Gets the hex coordinates
Log(" --- ")
Log("Screen: " & X & " , " & Y)
    Dim invY As Float = lGdx.Graphics.Height - Y
    Dim OffsetCameraX As Float = (Camera.ViewportWidth / 2) - (Camera.Position.X / Camera.Zoom)
    Dim OffsetCameraY As Float = (Camera.ViewportHeight / 2) - (Camera.Position.Y / Camera.Zoom)
    Dim relX As Float = X - OffsetCameraX
    Dim relY As Float = invY - OffsetCameraY
Log("Relative to camera: " & relX & " , " & relY)
    Dim HexCoordX As Float = Floor((relX - (OffsetX / Camera.Zoom)) / (HexW / Camera.Zoom))
    Dim ScaledHexH As Float = HexHeight / Camera.Zoom
    Dim HexCoordY As Float = Floor(relY / ScaledHexH)
    If HexCoordX Mod 2 = 0 Then
        HexCoordY = Floor((relY - (ScaledHexH / 2)) / ScaledHexH)
    End If
Log("Hex: " & HexCoordX & " , " & HexCoordY)
    Return False
End Sub
 

Attachments

  • Hexagon.zip
    13.9 KB · Views: 283
Last edited:

eurojam

Well-Known Member
Licensed User
Longtime User
I want to create a transparent "surface" so that the Activity's background will show (perhaps showing the REAL world thru the camera)
I tried adjusting the 4th parameter (alpha?) to get a transparent background, but even setting to 0 did not work.

In essence, is there a way that the "background" of libgdx will show the REAL world thru the device camera?

are there any solutions on that problem? I 'am trying the same thing, bringing a rendered shape with libgdx on a panel with a camera preview.
 

wonder

Expert
Licensed User
Longtime User
Hello again,

As you know, I'm starting to take my first steps in Box2D.
There are many excellent tutorials about Box2D on Internet (those of iforce2d for example), so I don’t think it’s useful to cover again this topic. The differences with the original version in C++ are not fundamentals.

Regarding iforce2d, just quick question, is it possible in LibGDX, to import the files generated with their R.U.B.E. Box2D world editor?
 

wonder

Expert
Licensed User
Longtime User
With some classes (e.g. the five interfaces), you cannot create a new instance with Dim. You have to use an instance returned by the library. For example, you cannot write:
B4X:
Dim Graphics As lgGraphics
Graphics = lGdx.Graphics
but you can write:
B4X:
Dim Graphics As lgGraphics = lGdx.Graphics

Good morning, Fred.

If you have time, could you elaborate on this matter?
What's the difference between the two?

I'm just curious, if you're having a busy day, leave it for another time. :)
 

Informatix

Expert
Licensed User
Longtime User
Good morning, Fred.

If you have time, could you elaborate on this matter?
What's the difference between the two?

I'm just curious, if you're having a busy day, leave it. :)
In Java, there are classes with a constructor without arguments and classes without this constructor (i.e. all constructors require arguments). B4A cannot "dim" the second type to create a new instance. So if you try to create an instance of lgGraphics, you will fail. It's not an object that has to be created by the user. The instance of lgGraphics is created by the library when you call Initialize. To use this object, you have to do Dim Graphics As lgGraphics = lGdx.Graphics. You store in Graphics the reference of the created instance returned by lGdx.Graphics (you could also use directly lGdx.Graphics).
 

Informatix

Expert
Licensed User
Longtime User

ilan

Expert
Licensed User
Longtime User
this is not simple at all :(
try already for 3 hours to simulate the buoyancy effect but can't get it to work.
the body is just bouncing up and down, it never stop and float on the water.
 

ilan

Expert
Licensed User
Longtime User
this is what i managed to accomplish: (i could not get the part how to calculate the intersection of the two bodies :()


the circles are jumping above the water, i could fix that by drawing the water sprite with circle.radius above the water top.
but this is not the real solution.
 
Last edited:
Top