Load image from web

[NetStorm]

Is there a way I can load an image directly in to a imageView via a http link?

 

[Erel]

You will need to use the Http library.
See the example in the manual:
Basic4android - HTTP

Instead of getting the response as string with Response.GetString you should call Response.GetInputStream and pass it to Bitmap.Initialize2:
Basic4android - Drawing (Core)

 

[NetStorm]

Im not sure exactly how to do this, could you help me out with an example please?

 

[ZJP]

One of my favorite examples : The Flickr Viewer : http://www.b4x.com/forum/basic4android-getting-started-tutorials/6646-flickr-viewer.html

JP

 

[Erel]

The FlickrViewer is a very good example.
Here is a simple code that downloads a single image:

Sub Process_Globals
    Dim hc As HttpClient
End Sub

Sub Globals

End Sub

Sub Activity_Create(FirstTime As Boolean)
    If FirstTime Then
        hc.Initialize("hc")
    End If
    Dim req As HttpRequest
    req.InitializeGet("http://www.b4x.com/android/images/logo.png")
    hc.Execute(req, 1)
End Sub

Sub hc_ResponseSuccess (Response As HttpResponse, TaskId As Int)
    Dim b As Bitmap
    b.Initialize2(Response.GetInputStream)
    Activity.SetBackgroundImage(b)
    Response.Release
End Sub

Sub hc_ResponseError (Response As HttpResponse, Reason As String, StatusCode As Int, TaskId As Int)
    Log("Error connecting: " & Reason & " " & StatusCode)
    If Response <> Null Then
        Log(Response.GetString("UTF8"))
        Response.Release
    End If
End Sub

Don't forget to add a reference to the Http library. The Http library version should be 1.10 or above.

 

[ZJP]

Hi,

FlickrViewer is the perfect example to find one (or more) picture in the html jungle (In French "Chercher une aiguille dans une botte de foin" / "Finding a needle in a haystack").
This current example is complementary. Ideal if the url of the picture is known

Tx.

JP

 

[NetStorm]

Works perfect, thankyou!!!