B4J Question Tableview Set cell alignment

[tdocs2]

Greetings.

I have looked thru the documentation with great detail, and found to my surprise that there is no Tableview Set cell alignment.

I have seen this post, but it seems quite archaic. I added my tableview with the Open Designer (GREAT TOOL EREL ). I filled it with DBUtils (GREAT TOOL EREL ), but I cannot set cell alignment.

Have I missed something? Is there a simple way to do this?

Thank you in advance for your replies.

Sandy

 

[Erel]

You have two options to change a cell value:
1. Get the list of rows with TableView.Items. Modify the relevant cell and set the items again. The downsize is that the table position will be lost.
2. Instead of adding strings as items you can add Labels. Then you can get the relevant label and change its Text directly.

 

[tdocs2]

Thank you, Erel.

2. Instead of adding strings as items you can add Labels. Then you can get the relevant label and change its Text directly.

I added my tableview with the Open Designer. I filled the Tableview with DBUtils ExecuteTableView which adds strings. Truly EXCELLENT - RAD at its best.

I am sorry, but I am lost on your solution... Should there be an ExecuteTableView2 in DBUtils which adds labels instead of values so that I can set the alignment?

Thank you for your patience and tolerance...

Sandy

 

[rwblinn]

Hi,

adding a centered label to a TableView Row requires additional coding.
This sub can be used as one example on how to do so (will need JavaObject library).

Example adding two labels (included in a Pane) to the TableView Row - To note that the Label properties can be set (in this text color blue).

    TableView1.Items.Add(Array As Object(TableView_AddLabel("Label 1", "CENTER"), TableView_AddLabel("Label 2", "CENTER")))

Sub TableView_AddLabel(labeltext As String, Alignment As String) As Pane
    Dim lbl1 As Label
    lbl1.Initialize("")
    lbl1.text = labeltext
    lbl1.TextColor = fx.Colors.Blue
    Dim pn1 As AnchorPane
    pn1.Initialize("")
    pn1.AddNode(lbl1, 0, 0, -1, -1)
    pn1.FillHorizontally(lbl1, 0, 0)
    Dim jo1 = lbl1 As JavaObject
    jo1.RunMethod("setAlignment", Array As Object(Alignment))
    Return pn1
End Sub

To get the content of a cell, you will need following code - because each cell content is a Pane with a Label (or in other words, the Pane has one Node being a Label):

Sub TableView1_SelectedCellChanged (RowIndex As Int, ColIndex As Int, Cell As Object)
   Dim p As Pane = Cell
   Dim l As Label = p.GetNode(0)
   Log(l.Text)   
End Sub

 

[EnriqueGonzalez]

in DBUTILS there is not a executetableview2, i created one that center all columns, shouldnt be hard to specify more alignments.

Copy this code to the DBUTILS Class:

Public Sub ExecuteTableView2(SQL As SQL, Query As String, StringArgs() As String, Limit As Int, _
    TableView1 As TableView)
    TableView1.Items.Clear
    Dim cur As ResultSet
    If StringArgs = Null Then 
        Dim StringArgs(0) As String
    End If
    cur = SQL.ExecQuery2(Query, StringArgs)
    Dim cols As List
    cols.Initialize
    For i = 0 To cur.ColumnCount - 1
        cols.Add(cur.GetColumnName(i))
    Next
    TableView1.SetColumns(cols)
    Do While cur.NextRow
        Dim values(cur.ColumnCount) As Object
        For col = 0 To cur.ColumnCount - 1
            Dim Clabel As Label
            Clabel.Initialize("")
            Clabel.Text = cur.GetString2(col)
            values(col) = WrapLabel(Clabel,"CENTER")
        Next
        TableView1.Items.Add(values)
        If Limit > 0 And TableView1.Items.Size >= Limit Then Exit
    Loop
    cur.Close
End Sub

Sub WrapLabel(lbl As Label, Alignment As String) As Pane
   Dim pn1 As AnchorPane
   pn1.Initialize("")
   pn1.AddNode(lbl, 0, 0, -1, -1)
   pn1.FillHorizontally(lbl, 0, 0)
   Dim jo1 = lbl As JavaObject
   jo1.RunMethod("setAlignment", Array As Object(Alignment))
   Return pn1
End Sub

 

[tdocs2]

Enrique,

Thank you - . You are brilliant.

Development of the ExecuteTableView2 sub you developed is above my tech skills.

At the risk of prevailing on your generosity, may I make a WISH?

Could you add a parameter to the sub ExecuteTableView2 that indicates the alignment for each column?
For example, if there are four columns, an array is passed with 4 strings that would indicate LEFT, CENTER, OR RIGHT for each column.

Then, instead of defaulting to CENTER as it does now, the sub would set the alignment indicated for the column.

Thank you for your generosity.

Sandy

 

[EnriqueGonzalez]

of course Tdocs2

here it is the updated version:

Public Sub ExecuteTableView2(SQL As SQL, Query As String, StringArgs() As String, Limit As Int, _
    TableView1 As TableView, alignments() As String)
    TableView1.Items.Clear
    Dim cur As ResultSet
    If StringArgs = Null Then
        Dim StringArgs(0) As String
    End If
    cur = SQL.ExecQuery2(Query, StringArgs)
    Dim cols As List
    cols.Initialize
    For i = 0 To cur.ColumnCount - 1
        cols.Add(cur.GetColumnName(i))
    Next
    TableView1.SetColumns(cols)
    Do While cur.NextRow
        Dim values(cur.ColumnCount) As Object
        For col = 0 To cur.ColumnCount - 1
            Dim Clabel As Label
            Clabel.Initialize("")
            Clabel.Text = cur.GetString2(col)
            values(col) = WrapLabel(Clabel,alignments(col))
        Next
        TableView1.Items.Add(values)
        If Limit > 0 And TableView1.Items.Size >= Limit Then Exit
    Loop
    cur.Close
End Sub

and use it like this:

DBUtils.ExecuteTableView2(sqlite,"SELECT * FROM TABLE",Null,0,TableView1,Array As String("CENTER","CENTER_RIGHT"))

from the original executetableview i just changed like 5 words, the original creator is the one that blows minds.

 

[tdocs2]

Thank you, Enrique.

Best wishes.

Sandy

 

[tdocs2]

To get the content of a cell, you will need following code - because each cell content is a Pane with a Label (or in other words, the Pane has one Node being a Label):

Sub TableView1_SelectedCellChanged (RowIndex As Int, ColIndex As Int, Cell As Object)
   Dim p As Pane = Cell
   Dim l As Label = p.GetNode(0)
   Log(l.Text)  
End Sub

Thank you, Rob.

Your numerous contributions on your site are appreciated by all. Thank you for your generosity.

Sandy

 

[rboeck]

If you need the constants for alignment, her it is: https://docs.oracle.com/javafx/2/api/javafx/geometry/Pos.html

 

[tdocs2]

Thank you, rboeck.

To keep the documentation on this thread...

Enum Constants

 


Enum Constant and Description

BASELINE_CENTER
Represents positioning on the baseline vertically and on the center horizontally.
BASELINE_LEFT
Represents positioning on the baseline vertically and on the left horizontally.
BASELINE_RIGHT
Represents positioning on the baseline vertically and on the right horizontally.
BOTTOM_CENTER
Represents positioning on the bottom vertically and on the center horizontally.
BOTTOM_LEFT
Represents positioning on the bottom vertically and on the left horizontally.
BOTTOM_RIGHT
Represents positioning on the bottom vertically and on the right horizontally.
CENTER
Represents positioning on the center both vertically and horizontally.
CENTER_LEFT
Represents positioning on the center vertically and on the left horizontally.
CENTER_RIGHT
Represents positioning on the center vertically and on the right horizontally.
TOP_CENTER
Represents positioning on the top vertically and on the center horizontally.
TOP_LEFT
Represents positioning on the top vertically and on the left horizontally.
TOP_RIGHT
Represents positioning on the top vertically and on the right horizontally.

 

[Otto Tentacle]

Hi thanks for the ExecuteTableView2 code it works well, but, how do I get data from the selected row?

For instance I fill a 4 column tableview with data from an SQLite table, when I select a row in the tableview I would like to get the value in the first column (the ID field of the SQLite table) and use it as a parameter in a query.

For ExecuteTableView I can just use the SelectedRowChanged action and Row(0) gives me a string with the required value e.g 12

For ExecuteTableView2 Row(0) now gives a random value along the lines of AnchorPane@3bdae5bb

Thanks

 

[Erel]

Go over WrapLabel sub. You will see that it adds a pane and then adds the label to the pane. So each item is actually a pane.

Dim p As Pane = ..GetRow(0)
Dim lbl As Label = p.GetNode(0)
Log(lbl.Text)

 

[Otto Tentacle]

Thanks for the quick answer, the following works fine.

Sub TableView1_SelectedRowChanged(Index As Int, Row() As Object)
Dim p As Pane = Row(0)
Dim lbl As Label = p.GetNode(0)
Log(lbl.text)
End Sub