Android Question Dialog with B4X buttons only

Mark Stuart · 2025-09-20T03:31:42+0100

Hi all,

I'm wanting to display a dialog with a title and 2 buttons, one under the other.
I will not use the default "Yes", "No", "Cancel" dialog buttons. They will not be defined and therefore will not appear.

Each button will have its own _Click function.
When a button is clicked, the _Click function will run and then the dialog will close.
Preferably, the dialog will close first then the subsequent code will run.

I've looked thru the forum for this, but found nothing like I've mentioned here.
Any suggestions would be welcome on how to do this.

Thanx,
Mark Stuart

EDIT: Yes, I could define a panel and load the layout to it, but would rather use a B4X dialog.

LucaMs · 2025-09-20T05:33:17+0100

Mark Stuart said:
EDIT: Yes, I could define a panel and load the layout to it, but would rather use a B4X dialog.

You can assign any text to the three dialog buttons - "Yes," "No," and "Cancel" - and only use two of them.

If you really don't want to use a panel and two buttons, don't want to create your own custom dialog and absolutely want to try using the B4XDialog, you'll have to try moving its buttons. I don't know if this can be done without modifying the source code, but you can try.

LucaMs · 2025-09-20T06:05:47+0100

LucaMs said:
and absolutely want to try using the B4XDialog, you'll have to try moving its buttons. I don't know if this can be done without modifying the source code, but you can try.

An example of how you can modify B4XDialog at runtime (without modifying its source code), by accessing its Views:

B4X:

    Dim dlg As B4XDialog
    dlg.Initialize(Root)
   
    Dim rs As ResumableSub = dlg.Show("Message", "Do it", "Do other", "")
   
    Dim Base As B4XView = dlg.Base
   
    Dim lblText As B4XView = Base.GetView(2).GetView(0)
    lblText.SetLayoutAnimated(0, 10dip, 0dip, Base.Width - 20dip, 40dip)
   
    Dim FirstButton As B4XView = dlg.GetButton(xui.DialogResponse_Positive)
    FirstButton.SetColorAndBorder(xui.Color_Green, 1, xui.Color_White, 8dip)
    FirstButton.TextColor = xui.Color_White
    Dim FirstButtonTop As Int = lblText.Top + lblText.Height
    FirstButton.SetLayoutAnimated(0, 10dip, FirstButtonTop, Base.Width / 2, 40dip)
   
    Dim SecondButton As B4XView = dlg.GetButton(xui.DialogResponse_Negative)
    SecondButton.SetColorAndBorder(xui.Color_Red, 1, xui.Color_White, 8dip)
    SecondButton.TextColor = xui.Color_White
    Dim SecondButtonTop As Int = FirstButton.Top + FirstButton.Height + 10dip
    SecondButton.SetLayoutAnimated(0, 10dip, SecondButtonTop, Base.Width / 2, 40dip)
   
    Wait For (rs) Complete (Result As Int)
    Select Result
        Case xui.DialogResponse_Positive
            'Do it
            Log("Do it")
        Case xui.DialogResponse_Negative
            'Do other
            Log("Do other")
'        Case xui.DialogResponse_Cancel
'            Log("Don't do anything")
    End Select

It's not "pretty" but now you know how to do it.

aeric · 2025-09-20T06:46:30+0100

You can create your own custom layout.

[B4X] [XUI] B4XDialog - Custom dialogs

Edit: B4XDialogs is part of XUI Views library. Use that instead: [B4X] XUI Views - Cross platform views and dialogs B4XDialog class helps with creating cross platform custom dialogs. The dialog is made of a simple panel and it is therefore completely customizable. Simple usage (change...

www.b4x.com

LucaMs · 2025-09-20T06:55:16+0100

aeric said:
You can create your own custom layout.

[B4X] [XUI] B4XDialog - Custom dialogs

Edit: B4XDialogs is part of XUI Views library. Use that instead: [B4X] XUI Views - Cross platform views and dialogs B4XDialog class helps with creating cross platform custom dialogs. The dialog is made of a simple panel and it is therefore completely customizable. Simple usage (change...

www.b4x.com

Yes but then the 3 fundamental buttons must be there and in those positions (at least one of them for closing the dialog)

LucaMs · 2025-09-20T06:56:35+0100

LucaMs said:
Yes but then the 3 fundamental buttons must be there and in those positions (at least one of them for closing the dialog)

Mark Stuart said:
a dialog with a title and 2 buttons, one under the other.
I will not use the default "Yes", "No", "Cancel" dialog buttons. They will not be defined and therefore will not appear.

Mark Stuart · 2025-09-20T16:52:07+0100

This code line throws an error:
Dim rs As ResumableSub = dlg.Show("Message", "Do it", "Do other", "")

java.lang.ClassCastException: com.mfs.bx.birthdays.addeditperson cannot be cast to android.view.View

LucaMs · 2025-09-20T18:56:54+0100

Mark Stuart said:
This code line throws an error:
Dim rs As ResumableSub = dlg.Show("Message", "Do it", "Do other", "")

java.lang.ClassCastException: com.mfs.bx.birthdays.addeditperson cannot be cast to android.view.View

Are you sure that's the line generating the error? It's correct, unless you've misdeclared dlg. It must be of type B4XDialog ("Xui Views" library), preferably declared in Class_Globals or Process_Globals.

Also make sure you don't already have a variable named "rs" of a different type (I don't think that's the problem, but it's better to be sure).

Mark Stuart · 2025-09-20T19:02:07+0100

Here's my code. The Dim dlg as B4XDialog is the only place it is declared:

B4X:

Sub OpenDialog
    Dim dlg As B4XDialog
    dlg.Initialize(Me)
    
    Dim rs As ResumableSub = dlg.Show("Message", "Do it", "Do other", "")
    Dim base As B4XView = dlg.Base
    Dim lblText As B4XView = base.GetView(2).GetView(0)
    lblText.SetLayoutAnimated(0, 10dip, 0dip, base.Width - 20dip, 40dip)
    
    Dim FirstButton As B4XView = dlg.GetButton(xui.DialogResponse_Positive)
    FirstButton.SetColorAndBorder(xui.Color_Green,1dip,xui.Color_White,8dip)
    FirstButton.TextColor = xui.Color_White
    Dim FirstButtonTop As Int = lblText.Top + lblText.Height
    FirstButton.SetLayoutAnimated(0,10dip, FirstButtonTop, base.Width / 2, 40dip)
    
    Dim SecondButton As B4XView = dlg.GetButton(xui.DialogResponse_Negative)
    SecondButton.SetColorAndBorder(xui.Color_Red, 1dip, xui.Color_White, 8dip)
    SecondButton.TextColor = xui.Color_White
    Dim SecondButtonTop As Int = FirstButton.Top + FirstButton.Height + 10dip
    SecondButton.SetLayoutAnimated(0, 10dip, SecondButtonTop, base.Width / 2, 40dip)
    
    Wait For (rs) Complete (Result As Int)
    Select Result
        Case xui.DialogResponse_Positive
            'Do it
            Log("Do it - Yes")
        Case xui.DialogResponse_Negative
            'Do other
            Log("Do other - No")
            '        Case xui.DialogResponse_Cancel
            '            Log("Don't do anything")
    End Select
End Sub

LucaMs · 2025-09-20T19:13:52+0100

Mark Stuart said:
dlg.Initialize(Me)

The parameter must be of type B4XView - Root, if yours is a B4XPage.

Mark Stuart · 2025-09-20T19:16:14+0100

The project is a B4XPages type app.

B4X:

Private Sub B4XPage_Created (Root1 As B4XView)
    Root = Root1

LucaMs · 2025-09-20T19:20:22+0100

Mark Stuart said:
The project is a B4XPages type app.

B4X:

Private Sub B4XPage_Created (Root1 As B4XView) Root = Root1

... then...

B4X:

dlg.Initialize(Root)

Mark Stuart · 2025-09-20T19:26:04+0100

That change made it work - thank you!
Learning B4XPages - something new and trying to get this old dog to learn new tricks :{

Mark

LucaMs · 2025-09-20T19:31:57+0100

Mark Stuart said:
That change made it work - thank you!
Learning B4XPages - something new and trying to get this old dog to learn new tricks :{

Mark

You should carefully examine the context help; it tells you the parameter type:

This has nothing to do with B4XPages, since you could also use B4XDialog in a non-B4XPages project.

Mark Stuart · 2025-09-20T19:33:18+0100

Yes I see now.
Now how to get it to be Cancelable by touching outside the dialog?

LucaMs · 2025-09-20T19:34:53+0100

Mark Stuart said:
Yes I see now.
Now how to get it to be Cancelable by touching outside the dialog?

I think that is not possible without modifying the B4XDialog source code.

Mark Stuart · 2025-09-20T19:38:29+0100

LucaMs · 2025-09-20T21:51:12+0100

Mark Stuart said:

Please, don't cry

I've developed a custom class for you! (attached)
msB4XDialog.bas, which you can use just like B4XDialog (it's, of course, the B4XDialog with my modifications).

B4X:

Sub Class_Globals
    Private Root As B4XView
    Private xui As XUI
 
    Private msDlg As msB4XDialog
End Sub

B4X:

Private Sub B4XPage_Created (Root1 As B4XView)
    Root = Root1
    Root.LoadLayout("MainPage")
 
    msDlg.Initialize(Root)
    msDlg.AddCallbackAndEventName(Me, "msDlg")
    msDlg.BaseClickable = True
End Sub

B4X:

Private Sub Button1_Click
    Dim rs As ResumableSub = msDlg.Show("Message", "Yes", "No", "Cancel")
 
    Wait For (rs) Complete (Result As Int)
    Select Result
        Case xui.DialogResponse_Positive
            Log("Yes")
        Case xui.DialogResponse_Negative
            Log("No")
        Case xui.DialogResponse_Cancel
            Log("Cancel")
        Case Else
            Log("Closed clicking on base")
    End Select
 
End Sub

Private Sub msDlg_Click
    msDlg.Close(123) ' any number except: 0, 1, 2 which are xui.DialogResponse constants.
End Sub

[Requires the "Xui Views" library]

Mark Stuart · 2025-09-20T23:11:15+0100

I'll check it a little later. Got to go eat.

Android Question Dialog with B4X buttons only

Active Member

Expert

Expert

Expert

Expert

Expert

Active Member

Expert

Active Member

Expert

Active Member

Expert

Active Member

Expert

Active Member

Expert

Active Member

Expert

Attachments

Active Member

Similar Threads

Privacy & Transparency

Privacy & Transparency