iOS Tutorial FirebaseNotifications / Push Messages (server not required)

Updated tutorial: https://www.b4x.com/android/forum/threads/b4x-firebase-push-notifications-2023.148715/

Update: It is simpler to use the new and recommended APN authentication keys: https://www.b4x.com/android/forum/t...on-keys-vs-authentication-certificates.126402

View attachment 171393


The configuration steps are still relevant.


Firebase Notifications service makes it relatively easy to send push messages.

Integrating Firebase: https://www.b4x.com/android/forum/threads/firebase-integration.68623/

Push messages in iOS requires some configuration.


1. Create a new explicit (non-wildcard) App ID with the package name of the push app. For example anywheresoftware.b4i.push. Enable push notification service.
2. Create an Apple Push Notification SSL certificate. Use the same certSigningRequest.csr file that you previously created.
This can be done from App IDs - Choose the id - Edit.

I recommend using a Production SSL Certificate with a Distribution / Ad Hoc provision profile. This way you can use the same tokens during development and in production.

3. Create a provision file with the new App ID.



Old keys (works as well):
4. There should be a file named aps_*.cer in the keys folder. Now you should click on Tools - Build Server - Create Push Key - Firebase Service:

This will create a file named firebase_push.p12 in the keys folder. You need to upload it to Firebase console under Settings - CLOUD MESSAGING:

You only need to upload the production APN.

5. Download GoogleService-Info.plist and copy it to Files\Special folder.

Code

The code should be similar to:

#Entitlement: <key>aps-environment</key><string>production</string>
'use the distribution certificate
#CertificateFile: ios_distribution.cer
'use the provision profile that goes with the explicit App Id
#ProvisionFile: Firebase.mobileprovision
Sub Process_Globals
   Public App As Application
   Public NavControl As NavigationController
   Private Page1 As Page
   Private analytics As FirebaseAnalytics
   Private fm As FirebaseMessaging
End Sub

Private Sub Application_Start (Nav As NavigationController)
   analytics.Initialize
   NavControl = Nav
   Page1.Initialize("Page1")
   Page1.Title = "Page 1"
   Page1.RootPanel.Color = Colors.White
   NavControl.ShowPage(Page1)
   App.RegisterUserNotifications(True, True, True)
   App.RegisterForRemoteNotifications
   fm.Initialize("fm")
End Sub

Private Sub fm_FCMConnected
   Log("FCMConnected")
   'here we can subscribe and unsubscribe from topics
   fm.SubscribeToTopic("ios_general") 'add ios_ prefix to all topics
End Sub

Private Sub Application_RemoteNotification (Message As Map, CompletionHandler As CompletionHandler)
   Log($"Message arrived: ${Message}"$)
   Msgbox(Message, "Push message!")
   CompletionHandler.Complete
End Sub

Private Sub Application_Active
   fm.FCMConnect 'should be called from Application_Active
End Sub

Private Sub Application_Background
   fm.FCMDisconnect 'should be called from Application_Background
End Sub

Sub Application_PushToken (Success As Boolean, Token() As Byte)
   Log($"PushToken: ${Success}"$)
   Log(LastException)
End Sub

Use the attached B4J (non-ui) program to send messages. It handles ios messages a bit differently. There is an assumption that all iOS topics start with ios_.

 

[Erel]

Is this correct?

It is fine. You can change the file name if needed.

 

[cloner7801]

In ios 10 , we can send a media (image) near push and if 3d touch the notifcation that image show.
Is this support send media ?

 

[Erel]

It is currently not supported.

 

[cloner7801]

It is currently not supported.

I am using onesignal rest api to send push notification,
It work but the media doesn't send ! (sent by don't show on notification)
What should I do?

 

[Erel]

See my previous answer.

 

[JohnnyHamburg]

Why do we have to put "ios_" prefix to the topicname?
I have no problems sending and receiving messages between android and iphone without the "ios_"-prefix.

 

[Erel]

See the B4J code from the first post. It treats the topic differently if it starts with ios_.

 

[sergiones]

I'm unable to receive the push notification. I did all the steps (actually I revoked all certificates and created new ones from scratch), the Sub Application_RemoteNotification is not being called.

fm_FCMConnected works, I'm using fm.SubscribeToTopic("ios_mySubject") and I can see this topic on Firebase console.

I sent a few messages for this topic using firebase, firebase says the message was sent but no activity on RemoteNotification Sub with a message box.

I'm using B4i version 3.01 with iOs 10.0.

Am I missing something?

Thank you.

 

[JohnnyHamburg]

I sent a few messages for this topic using firebase

I'm a beginner too, but Erel mentioned quite often that we have to use the B4J-app from the first post to send messages. NOT firebase!
I send with my app from iphone or android. You can receive your own messages.

 

[sergiones]

I'm a beginner too, but Erel mentioned quite often that we have to use the B4J-app from the first post to send messages. NOT firebase!
I send with my app from iphone or android. You can receive your own messages.

You are right, thanks. I don't remember something so unproductive as iOs...

 

[JohnnyHamburg]

I have to ask again about the difference to use the "ios_" prefix in the topic. Is it just for the notification, that is handled another way than android?
I send only data between the devices and it works without prefix.

 

[Erel]

This is the code:

Dim Job As HttpJob
   Job.Initialize("fcm", Me)
   Dim m As Map = CreateMap("to": $"/topics/${Topic}"$)
   Dim data As Map = CreateMap("title": Title, "body": Body)
   If Topic.StartsWith("ios_") Then
     Dim iosalert As Map =  CreateMap("title": Title, "body": Body, "sound": "default")
     m.Put("notification", iosalert)
     m.Put("priority", 10)
     'm.Put("content_available", True)
   End If
   m.Put("data", data)

It is required for the notification on iOS.

 

[Alpandino]

This is the code:

Dim Job As HttpJob
   Job.Initialize("fcm", Me)
   Dim m As Map = CreateMap("to": $"/topics/${Topic}"$)
   Dim data As Map = CreateMap("title": Title, "body": Body)
   If Topic.StartsWith("ios_") Then
     Dim iosalert As Map =  CreateMap("title": Title, "body": Body, "sound": "default")
     m.Put("notification", iosalert)
     m.Put("priority", 10)
     'm.Put("content_available", True)
   End If
   m.Put("data", data)

It is required for the notification on iOS.

So, If I send a notification from an Android App I must insert the code

     m.Put("notification", iosalert)
     m.Put("priority", 10)

in my send message SubRoutine in order to create a notification in the iPhone App?
But in this case it's not needed the prefix "ios_" in the Topic, right?
Other question: what consequences has the field "notification" for an Android App receiveing this kind of message?

Thanks

 

[Erel]

in my send message SubRoutine in order to create a notification in the iPhone App?

Yes.

But in this case it's not needed the prefix "ios_" in the Topic, right?

No, assuming that the device was subscribed to a topic that doesn't start with ios_.

Other question: what consequences has the field "notification" for an Android App receiveing this kind of message?

I don't 100% remember. You will need to check it.

 

[Alpandino]

I don't 100% remember. You will need to check it.

I checked it: If I put the notification payload in the message, Android redirect this payload on the system tray if the App is in background, otherwise the app will consider only the data payload.
Reading this I noticed "on iOS 10 devices, you'll need to handle applicationReceivedRemoteMessage", but I can't see this Sub in the code of the first post. I can only see the code for notifications:

Sub Application_RemoteNotification

Someone can explain why? I think that without the "applicationReceivedRemoteMessage" Sub is not possible to receive any message....

 

[Erel]

This is already implemented in B4i. Follow the tutorial and it will work.

 

[Daniel Uribe]

Hi everyone!!

Good morning, If we want to show a specific module when the user click the notification, is possible?

Thanks a lot!!!

 

[Erel]

You can show a different page from Application_RemoteNotification event.

 

[fransvlaarhoven]

Hello,

I just started with Notifications using the example code in the first post and noticed something strange:

- when the app is active and I send a notification, the event Application_RemoteNotificationis triggered showing the details of the notification.

- when the app is in the background and I send a notification, the notification shows. When I select the notification, the app is started and the event Application_RemoteNotification is triggered.

- when the app is in the background and I send a notification, the notification shows. When I start the app by pushing the icon of the app, the event Application_RemoteNotification is NOT triggered. It is only after selecting the notification that the event is triggered.

Is this normal or am I doing something wrong?

 

[Erel]

This is the normal behavior.