B4J Question GetSystemProperty & GetEnvironmentVariable

[LucaMs]

I can't remember (nor find) which library allows you to get the B4J application name at runtime (I would need it to set xui.SetDataFolder dynamically).

Is there a way to get all possible keys of GetSystemProperty and GetEnvironmentVariable, i.e. get two Maps?

I found Java code for the environment, so I could with Inline Java, but I would have to study how to get the Map in B4J and I don't think it's worth spending a whole day on a single instruction (SetDataFolder).

 

[LucaMs]

With:

GetSystemProperty("sun.java.command", "")

I get the package name (I think); it is already useful, even if it is not the name of the application.
P.S. No, it's not the package name, it gives me this but also "Main".

Still searching ...

 

[LucaMs]

The following function is certainly not ideal but it works a little, for jar files or in debug mode.
I'll use that one for now, but my question still stands.

Private Sub GetAppName As String
    Dim appName As String

    appName = GetSystemProperty("sun.java.command", "")
    If appName.EndsWith("jar") Then
        appName = appName.SubString2(0, appName.Length - 4)
        Dim FileSeparatorChar As String = GetSystemProperty("file.separator", ".")
        appName = appName.SubString(appName.LastIndexOf(FileSeparatorChar) + 1)
    Else
        If appName.EndsWith(".main") Then
            appName = appName.SubString2(0, appName.Length - 5) ' Removes ".main"
            appName = appName.SubString(appName.LastIndexOf(".") + 1)
        End If
    End If
    
    Return appName
End Sub

 

[DonManfred]

GetEnvironmentVariable("COMPUTERNAME", "") issue on Mac

I'm trying to get the GetEnvironmentVariable("COMPUTERNAME", "") to work in vmWare v15.1.0 on my PC. I'm running MacOS El capitan. JavaFX seems to work fine with RNE v8 and v9, went back to v8 but this command still returns an empty string. My virtual Mac's name is Macstation in system...

www.b4x.com

 

[LucaMs]

GetEnvironmentVariable("COMPUTERNAME", "") issue on Mac

I'm trying to get the GetEnvironmentVariable("COMPUTERNAME", "") to work in vmWare v15.1.0 on my PC. I'm running MacOS El capitan. JavaFX seems to work fine with RNE v8 and v9, went back to v8 but this command still returns an empty string. My virtual Mac's name is Macstation in system...

www.b4x.com

Did you want to tell me how to receive the value of a java function in B4J, @DonManfred?
Otherwise it's not what I need (the name of the app, not of the "system" (PC)).

 

[aeric]

To get the package name, you can use JavaObject:

Dim joBA As JavaObject
joBA.InitializeStatic("anywheresoftware.b4a.BA")
Log("Packagename: " & joBA.GetField("packageName"))

How to get Package Name?

How does one get the b4j package name in code?

www.b4x.com

or if you try to use Me,

Log(Me)

you will get something like this:

class b4j.example.main

So, remove the "class " and ".main", you can get the package name.

Sub PackageName As String
    Return Me.As(String).SubString2("class ".Length, Me.As(String).Length - ".main".Length)
End Sub

Log(PackageName)

 

[LucaMs]

To get the package name, you can use JavaObject:

Dim joBA As JavaObject
joBA.InitializeStatic("anywheresoftware.b4a.BA")
Log("Packagename: " & joBA.GetField("packageName"))

How to get Package Name?

How does one get the b4j package name in code?

www.b4x.com

or if you try to use Me,

Log(Me)

you will get something like this:

class b4j.example.main

So, remove the "class " and ".main", you can get the package name.

Sub PackageName As String
    Return Me.As(String).SubString2("class ".Length, Me.As(String).Length - ".main".Length)
End Sub

Log(PackageName)

https://www.b4x.com/android/forum/t...rty-getenvironmentvariable.157640/post-967631

With that code I get the name of the application, whether with the IDE open, debug or release, from the jar or from the exe.
It seems ok to me.

My question remains whether a library already exists, whether there is a direct way for the name, without having to eliminate the "main" or "jar" and, above all at this point, how the keys to the maps of Environment and System properties can be obtained .

 

[aeric]

I found Java code for the environment, so I could with Inline Java, but I would have to study how to get the Map in B4J

I am not sure I get you correctly.

Sub getSystemEnvironment As Map
    Dim jo As JavaObject
    jo.InitializeStatic("java.lang.System")
    Dim Env As Map = jo.RunMethod("getenv", Null)
    Return Env
End Sub

Dim SystemEnvironment As Map = getSystemEnvironment
For Each Key As String In SystemEnvironment.Keys
    Log($"${Key} = ${SystemEnvironment.Get(Key)}"$)
Next

 

[aeric]

For SystemProperty,

Sub GetSystemProp As Map
    Dim jo As JavaObject
    jo.InitializeStatic("java.lang.System")
    Dim Prop As Map = jo.RunMethod("getProperties", Null)
    Return Prop
End Sub

Dim SystemProperty As Map = GetSystemProp
For Each Key As String In SystemProperty.Keys
    Log($"${Key} = ${SystemProperty.Get(Key)}"$)
Next

 

[LucaMs]

Thanks so much, @aeric, I'll try them (although I'm sure they'll work). They will be very useful.