Android Tutorial SQL tutorial

Status
Not open for further replies.
Update 2018:

New video tutorial:


The source code is available here: https://www.b4x.com/android/forum/t...ming-video-tutorials.88787/page-2#post-577932

Async methods: [B4X] SQL with Wait For

The following tutorial is obsolete:

This tutorial covers the SQL library and its usage with Basic4android.
There are many general SQL tutorials that cover the actual SQL language. If you are not familiar with SQL it is recommended to start with such a tutorial.
SQL Introduction

A new code module is available named DBUtils. It contains methods for common tasks which you can use and also learn from the code.

Android uses SQLite which is an open source SQL implementation.
Each implementation has some nuances. The following two links cover important information regarding SQLite.
SQLite syntax: Query Language Understood by SQLite
SQLite data types: Datatypes In SQLite Version 3

SQL in Basic4android
The first step is to add a reference to the SQL library. This is done by going to the Libraries tab and checking SQL.
There are two types in this library.
An SQL object gives you access to the database.
The Cursor object allows you to process queries results.

Usually you will want to declare the SQL object as a process global object. This way it will be kept alive when the activity is recreated.

SQLite stores the database in a single file.
When we initialize the SQL object we pass the path to a database file (which can be created if needed).
B4X:
Sub Process_Globals
    Dim SQL1 As SQL
End Sub

Sub Globals

End Sub

Sub Activity_Create(FirstTime As Boolean)
    If FirstTime Then
        SQL1.Initialize(File.DirDefaultExternal, "test1.db", True)
    End If
    CreateTables
    FillSimpleData
    LogTable1
    InsertManyRows
    Log("Number of rows = " & SQL1.ExecQuerySingleResult("SELECT count(*) FROM table1"))
 
    InsertBlob 'stores an image in the database.
    ReadBlob 'load the image from the database and displays it.
End Sub
The SQL1 object will only be initialized once when the process starts.
In our case we are creating it in the sd card. The last parameter (CreateIfNecessary) is True so the file will be created if it doesn't exist.

There are three types of methods that execute SQL statements.
ExecNonQuery - Executes a "writing" statement and doesn't return any result. This can be for example: INSERT, UPDATE or CREATE TABLE.

ExecQuery - Executes a query statement and returns a Cursor object that is used to process the results.

ExecQuerySingleResult - Executes a query statement and returns the value of the first column in the first row in the result set. This method is a shorthand for using ExecQuery and reading the value with a Cursor.

We will analyze the example code:
B4X:
Sub CreateTables
    SQL1.ExecNonQuery("DROP TABLE IF EXISTS table1")
    SQL1.ExecNonQuery("DROP TABLE IF EXISTS table2")
    SQL1.ExecNonQuery("CREATE TABLE table1 (col1 TEXT , col2 INTEGER, col3 INTEGER)")
    SQL1.ExecNonQuery("CREATE TABLE table2 (name TEXT, image BLOB)")
End Sub
The above code first deletes the two tables if they exist and then creates them again.

B4X:
Sub FillSimpleData
    SQL1.ExecNonQuery("INSERT INTO table1 VALUES('abc', 1, 2)")
    SQL1.ExecNonQuery2("INSERT INTO table1 VALUES(?, ?, ?)", Array As Object("def", 3, 4))
End Sub
In this code we are adding two rows. SQL.ExecNonQuery2 receives two parameters. The first parameter is the statement which includes question marks. The question marks are then replaced with values from the second List parameter. The List can hold numbers, strings or arrays of bytes (blobs).
Arrays are implicitly converted to lists so instead of creating a list we are using the Array keyword to create an array of objects.

B4X:
Sub LogTable1
    Dim Cursor1 As Cursor
    Cursor1 = SQL1.ExecQuery("SELECT col1, col2, col3 FROM table1")
    For i = 0 To Cursor1.RowCount - 1
        Cursor1.Position = i
        Log("************************")
        Log(Cursor1.GetString("col1"))
        Log(Cursor1.GetInt("col2"))
        Log(Cursor1.GetInt("col3"))
    Next
    Cursor1.Close
End Sub
This code uses a Cursor to log the two rows that were previously added.
SQL.ExecQuery returns a Cursor object.
Then we are using the For loop to iterate over all the results.
Note that before reading values from the Cursor we are first setting its position (the current row).

B4X:
Sub InsertManyRows
    SQL1.BeginTransaction
    Try
        For i = 1 To 500
            SQL1.ExecNonQuery2("INSERT INTO table1 VALUES ('def', ?, ?)", Array As Object(i, i))
        Next
        SQL1.TransactionSuccessful
    Catch
        Log(LastException.Message)
    End Try
    SQL1.EndTransaction
End Sub
This code is an example of adding many rows. Internally a lock is acquired each time a "writing" operation is done.
By explicitly creating a transaction the lock is acquired once.
The above code took less than half a second to run on a real device.
Without the BeginTransaction / EndTransaction block it took about 70 seconds.
A transaction block can also be used to guarantee that a set of changes were successfully done. Either all changes are made or none are made.
By calling SQL.TransactionSuccessful we are marking this transaction as a successful transaction. If you omit this line, all the 500 INSERTS will be ignored.
It is very important to call EndTransaction eventually.
Therefore the transaction block should usually look like:
B4X:
SQL1.BeginTransaction
Try
  'Execute the sql statements.
SQL1.TransactionSuccessful
Catch
'the transaction will be cancelled
End Try
SQL1.EndTransaction
Note that using transactions is only relevant when doing "writing" operations.

Blobs
The last two methods write an image file to the database and then read it and set it as the activity background.
B4X:
Sub InsertBlob
    Dim Buffer() As Byte = File.ReadBytes(File.DirAssets, "smiley.gif")
    'write the image to the database
    SQL1.ExecNonQuery2("INSERT INTO table2 VALUES('smiley', ?)", Array As Object(Buffer))
End Sub
Here we are using a special type of OutputStream which writes to a dynamic bytes array.
File.Copy2 copies all available data from the input stream into the output stream.
Then the bytes array is written to the database.

B4X:
Sub ReadBlob
    Dim Cursor1 As Cursor = SQL1.ExecQuery2("SELECT image FROM table2 WHERE name = ?", Array As String("smiley"))
    Cursor1.Position = 0
    Dim Buffer() As Byte = Cursor1.GetBlob("image")
    Dim InputStream1 As InputStream
    InputStream1.InitializeFromBytesArray(Buffer, 0, Buffer.Length)
    Dim Bitmap1 As Bitmap
    Bitmap1.Initialize2(InputStream1)
    InputStream1.Close
    Activity.SetBackgroundImage(Bitmap1)
End Sub
Using a Cursor.GetBlob we fetch the previously stored image.
Now we are using an input stream that reads from this array and load the image.

Asynchronous queries
SQL library v1.20 supports asynchronous select queries and asynchronous batch inserts.

Asynchronous means that the task will be processed in the background and an event will be raised when the task completes. This is useful when you need to issue a slow query and keep your application responsive.

The usage is quite simple:
B4X:
sql1.ExecQueryAsync("SQL", "SELECT * FROM table1", Null)
...
Sub SQL_QueryComplete (Success As Boolean, Crsr As Cursor)
    If Success Then
        For i = 0 To Crsr.RowCount - 1
            Crsr.Position = i
            Log(Crsr.GetInt2(0))
        Next
    Else
        Log(LastException)
    End If
End Sub
The first parameter is the "event name". It determines which sub will handle the QueryComplete event.

Batch inserts
SQL.AddNonQueryToBatch / ExecNonQueryBatch allow you to asynchronously process a batch of non-query statements (such as INSERT statements).
You should add the statements by calling AddNonQueryToBatch and eventually call ExecNonQueryBatch.
The task will be processed in the background. The NonQueryComplete event will be raised after all the statements execute.
B4X:
For i = 1 To 10000
        sql1.AddNonQueryToBatch("INSERT INTO table1 VALUES (?)", Array As Object(Rnd(0, 100000)))
Next
sql1.ExecNonQueryBatch("SQL")
...
Sub SQL_NonQueryComplete (Success As Boolean)
    Log("NonQuery: " & Success)
    If Success = False Then Log(LastException)
End Sub
 

Attachments

  • SQL.zip
    8.1 KB · Views: 11,837
Last edited:

Erel

B4X founder
Staff member
Licensed User
Longtime User
Seems like your emulator is not able to access the SD card. You should create a new emulator instance and make sure to set enough space for the SD card.

Please try to run the following code:
B4X:
    Msgbox(File.ExternalWritable, "")
    File.WriteString(File.DirRootExternal, "1.txt", "asdasdasdasd")
It should display a message box with true or false depending on the external storage availability. It will also try to create a text file.
 

a_carignan

Member
Licensed User
Longtime User
I have to create the order
sql1.ExecnonQuery("vacuum")
but at the time of l' execution it marks a error; writing/Reading on the disc.
:sign0163:
 

aklisiewicz

Active Member
Licensed User
Longtime User
so far not to well...

I'm just trying to run this code and all I get is a happy face. Tapping on BACK button closes App. This happens on device and the emulator as well.
Any idea ?
 

eps

Expert
Licensed User
Longtime User
Nope! I just can't make this work!! :sign0104:

I think I've got it to succesfully find the database file, but then it just won't find the tables... I did go over the stuff that was posted about a metadata table and _id..

Any ideas?

I get :

android.database.sqlite.SQLiteException: no such table: favourite: , while compiling: SELECT count(*) FROM favourite

Code is :

Cursor = SQL1.ExecQuery("SELECT count(*) FROM favourite")

I've defined Cursor :

Sub Globals
Dim TabHost1 As TabHost
Dim txtName, txtAnimal, txtColor As EditText
Dim ListView1 As ListView
Dim Label1 As Label
Dim btnNext1 As Button
Dim Cursor As Cursor

DB file attached..

I get the same error if I try to access the other table, event..

hmm... I'm obviously doing something wrong or have missed something but not sure what! :sign0085:
 

Attachments

  • themsc.zip
    1.2 KB · Views: 688

eps

Expert
Licensed User
Longtime User
Certainly. Files attached, although of course they're a WIP... :)

I think that it's "something" to do with the database structure/file tho... but I am a :sign0104:
 

Attachments

  • the_msc.zip
    355.9 KB · Views: 756

klaus

Expert
Licensed User
Longtime User
Are you shure that your db file is in the File.DirInternal ?
In the attached program the de file is copied from File.DirAssets to File.DirInternal if it doesn't exist.
Acces to events works.

Best regards.
 

Attachments

  • the_msc_1.zip
    21.4 KB · Views: 695

eps

Expert
Licensed User
Longtime User
Okay, a really basic question...

What is the actual difference between File.DirAssets and File.DirInternal?
 

klaus

Expert
Licensed User
Longtime User
File.DirAssets
The assets folder includes the files that were added with the file manager. These files are read-only. You can not create new files in this folder (which is actually located inside the apk file).

File.DirInternal / File.DirInternalCache
These two folders are stored in the main memory and are private to your application. Other applications cannot access these files.
The cache folder may get deleted by the OS if it needs more space.

Have a look here.

Best regards.
 

eps

Expert
Licensed User
Longtime User
Klaus

That's excellent, thanks for that. Is this supposed to work in the emulator? I'm guessing not... Which is probably the source of my error.

Hmm... I didn't have an "SD card installed" but I guess that's not the problem either.. but something along these lines.. i.e. I haven't got
the emulator set up properly to allow me to copy the file.. or will it never work in the emulator?

Duh, yep, I guess I hadn't set the emulator up with any storage capabilities...

All good now :)
 
Last edited:

schimanski

Well-Known Member
Licensed User
Longtime User
Storing maptiles in an sql-database

Hello!

I have still no experience with working with sql. So I need a sound rating, before I read several hours about it: Is it perhaps possible to strore maptiles (.png) in an sql-database? I'm still working with normal .png-files in my offline mapviewer, but there are several problems by working with thousands of these files. It takes several hours to copy it to trhe SD-card and by wrong cluster-format, the tiles get to much space on the card.
My idea is, to collect every zoomlevel in one database. But is it possible to fill the database up to more than 2 or 3 GB. And is it fast enough for display the tiles out of the database on the screen?

Thanks for your help....
 

schimanski

Well-Known Member
Licensed User
Longtime User
Thanks, Erel for your efforts!

It is possible to download maptiles in ready sqlite-databases with the Desktop-application Mobile Atlas Creator, for example. I have downloaded such a database with a few maptiles in the OruxMaps SQlite-format. My question ist know, is it possible to get the tiles out of these database? I'm not sure, how to check the structure of these database...

Thanks for any help....
 
Status
Not open for further replies.
Top