Android Tutorial Classes tutorial

Basic4android v2.00 adds support for classes modules.

Classes definition from Wikipedia:
In object-oriented programming, a class is a construct that is used to create instances of itself – referred to as class instances, class objects, instance objects or simply objects. A class defines constituent members which enable its instances to have state and behavior. Data field members (member variables or instance variables) enable a class instance to maintain state. Other kinds of members, especially methods, enable the behavior of a class instances. Classes define the type of their instances.

A class usually represents a noun, such as a person, place or thing, or something nominalized. For example, a "Banana" class would represent the properties and functionality of bananas in general. A single, particular banana would be an instance of the "Banana" class, an object of the type "Banana".

Example:
B4X:
'Class Person module
Sub Class_Globals
   Private FirstName, LastName As String
   Private BirthDate As Long
End Sub

Sub Initialize (aFirstName As String, aLastName As String, aBirthDate As Long)
   FirstName = aFirstName
   LastName = aLastName
   BirthDate = aBirthDate
End Sub

Public Sub GetName As String
   Return FirstName & " " & LastName
End Sub

Public Sub GetCurrentAge As Int
   Return GetAgeAt(DateTime.Now)
End Sub

Public Sub GetAgeAt(Date As Long) As Int
   Dim diff As Long
   diff = Date - BirthDate
   Return Floor(diff / DateTime.TicksPerDay / 365)
End Sub

'Main module
...
Dim p As Person
p.Initialize("John", "Doe", DateTime.DateParse("05/12/1970"))
Log(p.GetCurrentAge)

I will start by explaining the differences between classes, code modules and types.

Similar to types, classes are templates. From this template you can instantiate any number of objects.
The type fields are similar to the classes global variables. However unlike types which only define the data structure, classes also define the behavior. The behavior is defined in the classes subs.

Unlike classes which are a template for objects, code modules are collections of subs. Another important difference between code modules and classes is that code modules always run in the context of the calling sub (the activity or service that called the sub). The code module doesn't hold a reference to any context. For that reason it is impossible to handle events or use CallSub with code modules.
Classes store a reference to the context of the activity or service module that called the Initialize sub. This means that classes objects share the same life cycle as the service or activity that initialized them.

Code modules are somewhat similar to singleton or static classes.

Adding a class module
Adding a new or existing class module is done by choosing Project -> Add New Module -> Class module or Add Existing module.
Like other modules, classes are saved as files with bas extension.

Classes structure
Classes must have the following two subs:

Class_Globals - This sub is similar to the activity Globals sub. These variables will be the class global variables (sometimes referred to instance variables or instance members).

Initialize - A class object should be initialized before you can call any other sub. Initializing an object is done by calling the Initialize sub. When you call Initialize you set the object's context (the parent activity or service).
Note that you can modify this sub signature and add arguments as needed.

In the above code we created a class named Person and later instantiate an object of this type:
B4X:
Dim p As Person
p.Initialize("John", "Doe", DateTime.DateParse("05/12/1970"))
Log(p.GetCurrentAge)

Calling initialize is not required if the object itself was already initialized:
B4X:
Dim p2 As Person
p2 = p 'both variables now point to the same Person object.
Log(p2.GetCurrentAge)

Polymorphism
Polymorphism allows you to treat different types of objects that adhere to the same interface in the same way.
Basic4android polymorphism is similar to the Duck typing concept.

As an example we will create two classes named: Square and Circle.
Each class has a sub named Draw that draws the object to a canvas:
B4X:
'Class Square module
Sub Class_Globals
   Private mx, my, mLength As Int
End Sub

'Initializes the object. You can add parameters to this method if needed.
Sub Initialize (x As Int, y As Int, length As Int)
   mx = x
   my = y
   mLength = length
End Sub

Sub Draw(c As Canvas)
   Dim r As Rect
   r.Initialize(mx, my, mx + mLength, my + mLength)
   c.DrawRect(r, Colors.White, False, 1dip)
End Sub
B4X:
'Class Circle module
Sub Class_Globals
   Private mx, my, mRadius As Int
End Sub

'Initializes the object. You can add parameters to this method if needed.
Sub Initialize (x As Int, y As Int, radius As Int)
   mx = x
   my = y
   mRadius = radius
End Sub

Sub Draw(cvs As Canvas)
   cvs.DrawCircle(mx, my, mRadius, Colors.Yellow, False, 1dip)
End Sub

In the main module we create a list with Squares and Circles. We then go over the list and draw all the objects:
B4X:
Sub Process_Globals
   Dim shapes As List
End Sub

Sub Globals
   Dim cvs As Canvas  
End Sub

Sub Activity_Create(FirstTime As Boolean)
   cvs.Initialize(Activity)
   Dim sq1, sq2 As Square
   Dim circle1 As Circle
   sq1.Initialize(100dip, 100dip, 50dip)
   sq2.Initialize(2dip, 2dip, 100dip)
   circle1.Initialize(50%x, 50%y, 100dip)
   shapes.Initialize
   shapes.Add(sq1)
   shapes.Add(sq2)
   shapes.Add(circle1)
   DrawAllShapes
End Sub

Sub DrawAllShapes
   For i = 0 To shapes.Size - 1
      CallSub2(shapes.Get(i), "Draw", cvs) 'Call Draw of each object
   Next
   Activity.Invalidate
End Sub
(the example code is attached)

As you can see, we do not know the specific type of each object in the list. We just assume that it has a Draw method that expects a single Canvas argument. Later we can easily add more types of shapes.
You can use the SubExists keyword to check whether an object includes a specific sub.

You can also use the Is keyword to check if an object is of a specific type.

Self reference
The Me keyword returns a reference to the current object. 'Me' keyword can only be used inside a class module.
Consider the above example. We could have passed the shapes list to the Initialize sub and then add each object to the list from the Initialize sub:
B4X:
Sub Initialize (Shapes As List, x As Int, y As Int, radius As Int)
   mx = x
   my = y
   mRadius = radius
   Shapes.Add(Me) 'Me is used to add this object to the list
End Sub

Activity object
This point is related to the activities special life cycle. Make sure to first read the activities and processes life-cycle tutorial.

Android UI elements hold a reference to the parent activity. As the OS is allowed to kill background activities in order to free memory, UI elements cannot be declared as process global variables (these variables live as long as the process lives). Such elements are named Activity objects. The same is true for custom classes. If one or more of the class global variables is of a UI type (or any activity object type) then the class will be treated as an "activity object". The meaning is that instances of this class cannot be declared as process global variables.

Properties
Starting from B4A v2.70, classes support properties. Properties syntax can be considered a syntactic sugar.
Properties combine two methods into a single "field" like member.
For example the two following methods:
B4X:
'Gets or sets the text
Sub getText As String
   Return btn.Text
End Sub

Sub setText(t As String)
   btn.Text = t
End Sub
Are merged automatically into a single property:

SS-2013-05-12_11.42.31.png


The property can be treated like any other field:
B4X:
Dim c1 As SomeClass
c1.Text = "abc"
Log(c1.Text)

The rules for properties:
- Only relevant for classes.
- One or two subs with the format get<prop> / set<prop>. Note that get / set must be lower case.
- A property can be read-only (only get), write-only (only set) or both.
- The two subs types (parameter in the set sub and return type in the get sub) must be the same.
- Within the class you should call the methods directly. The property will not appear.
- The property cannot have the same name as a global variable.

Related links:
Built-in documentation
Variables & Objects
Variables & Subs visibility
 

Attachments

  • Draw.zip
    7.1 KB · Views: 2,036
Last edited:

alienhunter

Active Member
Licensed User
Having spent many hours hunched over a candle lite computer trying to get these new properties to work I finally nailed it.
They work really well but there is a little trick to it, now if you are a better programmer than me you will probably say that it is obvious but it wasn't obvious to me with very little documentation to go on.
The trick is in the naming -
If you declare a variable in your class - Dim Headache as string
then create a sub like this

Sub getHeadache as string
Return Headache
End Sub

You will find it wont work, the documentation suggests that it should be a property of some sort but if you declare Headache as a label and return Headache.Text it still wont work.
However if you declare a variable - Dim Head as string
then the sub as
Sub getHeadache as string
Return Head
End Sub
It seems to work
The trick seems to be making sure the private variable has a different name to the sub name(following set/get).
I hope this will save someone from going slowly crazy


:BangHead::sign0148:
now i am more confused as before
:sign0013:
:)

you have some example ?
 

alexis

Member
Licensed User
Class Name

Hello Guys,
In the example on the first post , in "Dim p As Person" when we create the variable P: Person is the same name we'll use to save the class when we create it?

P.S. Erel, crew, and fellow members: Great work as always!
 

basic4mace

New Member
Licensed User
Classes and Events

Basic4android v2.00 adds support for classes modules.

Unlike classes which are a template for objects, code modules are collections of subs. Another important difference between code modules and classes is that code modules always run in the context of the calling sub (the activity or service that called the sub). The code module doesn't hold a reference to any context. For that reason it is impossible to handle events or use CallSub with code modules.
Classes store a reference to the context of the activity or service module that called the Initialize sub. This means that classes objects share the same life cycle as the service or activity that initialized them.


Does this paragraph imply that Classes can handle or raise events?

If so how?

Thanks.
 

kanaida

Active Member
Licensed User
I'm trying to initialize an image view from a sub inside a class and got this. Tries adding the activity in there, but maybe i'm using the wrong syntax or something. Whats the proper way to add the global activity object?


Parsing code. 0.01
Compiling code. Error
Error compiling program.
Error description: An Activity context is required.
This class has a process context.
Adding a global "Activity object" variable will fix this issue.
Occurred on line: 25
IV.Initialize("")
Word: initialize
 

eelias

Active Member
Licensed User
Erel,

I am using the Polymorphism idea extensivelly creating a kind of OOP.

However I am not sure if that is causing a problem in on specific situation that I did not pay attention before.

Can I use CallSub to call another created object while the application still in Activity_Create section?

Is callsub only available after Activity_Create ended?

Thanks Eduardo
 

Kevin

Well-Known Member
Licensed User
Just wanted to post a quick message on how awesome classes are in B4A! Admittedly I wasn't exactly following the concept when they were first announced but I have recently added a couple pre-made classes to my project and while modifying them to better suit my needs I started to understand their power and flexibility and I am really liking these!

No wonder so many people here were excited when they were first announced! This has opened up some possibilities in my app that previously seemed like it would be too much work but with classes it's turning out to be a breeze.

Thanks!!!

:sign0098:
 

ttsolution

Member
Licensed User
Hi Erel,

I created a module class with 03 members
- Id
- Name
- Age

How can I load 100 Person to ListView and just display the Name. Do module class support ToString function just return the Name only?

many thanks

Jonh,
 

Computersmith64

Well-Known Member
Licensed User
Hi Erel,

Am I right in assuming that you can't use a MsgBox within a class?

Thanks - Colin.
 

Computersmith64

Well-Known Member
Licensed User
Thanks Erel. I'm seeing an issue that I thought might have been due to a MsgBox in a class I wrote, but I guess it's something else.


- Colin
 

LucaMs

Expert
Licensed User
Yes. Handling events is done in the same way that it is done in any other module.

Raising events is done with CallSub. See this example:
Custom View with Designer Support

What is the purpose of declaring the events, since they can work without the declaration?
(in the first post is missing an argument "Events").

How you can implement the functionality of the editor "Sub +Tab" to show the available events?
 

thedesolatesoul

Expert
Licensed User
What is the purpose of declaring the events, since they can work without the declaration?
(in the first post is missing an argument "Events").

How you can implement the functionality of the editor "Sub +Tab" to show the available events?
Declaring the events allows the autocomplete "Sub +Tab" functionality in the IDE.
 

LucaMs

Expert
Licensed User
Currently the events will only be listed in the IDE when you compile the class into a library.

I was sure I had tried just compiling a custom view ... I suspect that I remembered wrong, because now it works :D

Thank, 'Soul & Erel
 
Top