Android Tutorial Converting VB6 to B4A

Below is a table listing features of Visual Basic 6 and their equivalents in B4A.

If you find errors or wish to add other features, post a reply here to have your input integrated into the table (which will be updated as needed).

B4X:
This file is primarily for reference when converting Visual Basic 6 source code to B4A.
  VB6                  B4A
  ===                  ===
controls            Views  (button, edittext, label, etc.)
In the VB6 code window, the top left drop-down list contains all
the controls you have placed in the current form and the right list
contains all the events for each control.  The equivalent in B4A can
be found by clicking on Designer - Tools - Generate Members. Once
you have created Subs in the program coding window, the tab "Modules"
on the right side will list each of the Subs.
In B4A, you start by typing "Sub [viewName]" followed by a space and
follow the prompts, pressing Enter after each selection until B4A
ends with "EventName" highlighted. This is where you would type in
the name of the Sub.
editBox = string      editBox.Text = string
In VB6, you can leave ".Text" off the names of controls when assigning
text to them, but this is not allowed in B4A.

Dim/ReDim:
---------
Dim Array(n)        Dim Array(n+1)
While "n" is the last index number in VB6, it indicates the number
of array elements when used in B4A. For example, to Dim an array
with 0-32 elements in VB6, you would say Dim A(32), while to convert
this to B4A, you need to change it to Dim A(33), yet index #33 is
never used (doing so would cause an out-of-range error).
ReDim Preserve      Use a List.
ReDim Array()       Dim Array(n+1) -- to clear an array, just Dim it again.
[Dim a Int: Dim b as Boolean]
If Not b Then...    If Not(b) Then...
If b Then...        same
If b = True Then    same
If a Then...        If a > 0 Then...
                       B4A does not treat any non-zero value as True like VB6.
a = a + b           If b = True Then a = a - 1
                       Boolean's value cannot be used in a math function in B4A.
Global Const x=1    B4A does not have a Global Const function.
                       In Sub Globals, you can say   Dim x as Int: x = 1
                       but x is not a constant (it's value can be changed).

Loops, If-Then, Select Case:
---------------------------
Do [Until/While]    same
Loop [Until/While]  Loop  [Until/While not allowed.]
For - Next          same
For i... - Next i   The loop variable (i) is not allowed with Next.
Exit Do/For         Exit
If - Then - Else    same, except VB's ElseIf is "Else If" in B4A; ditto EndIf
   ---              Continue [Skips to Next in For-Next loop]
For i = 1 to 6        For i = 1 to 6
  If i <> 4 Then        If i = 4 Then Continue
    ...code...          ...code...
  End If                ...
Next                  Next
Select Case [expr]  Select [value]

Colors:
------
L1.BackColor =      L1.Color = Colors.Red
    vbRed
L1.ForeColor =      L1.TextColor = Colors.Black
    vbBlack

Calling a sub:
-------------
SubName x, y        SubName(x, y)
Sub SubName()       Sub SubName() As Int/String/etc. -- a Global variable cannot be
                       a parameter, so say that "player" is a Global variable, you
                       cannot say: PlayCard(player). Instead you have to say:
                       i=player: PlayCard(i)
Function FName()    Sub FName() As [var.type]
   As [var.type]       In B4A, any Sub can be used like a Function by adding a
                       variable type such as
                          Sub CheckX(x As Int) As Boolean
                             ...optional code...
                             If x = [desired value] Then Return True
                             ...optional code...
                          End Sub
                       If no Return is given, then zero/False/"" is returned, but
                       the IDE will give a warning, so it is better to Return 0/False/"".
                       The calling code does not have to reference the returned
                       value, so that while "If CheckX(x) = True..." is valid,
                       so is just "CheckX(x)"
Exit Sub            Return
Exit Function       Return [value]

General:
-------
CInt
DoEvents            same, except that Erel says:
                    "Calling DoEvents in a loop consumes a lot of resources and
                    it doesn't allow the system to process all waiting messages
                    properly." This was in response to my pointing out that while
                    in a Do Loop with DoEvents in it, WebView could not be loaded
                    or if loaded, would not process a hyperlink click. And Agraham
                    says: "Looping is bad practice on mobile devices. The CPU will
                    be constantly executing code and using battery power as the
                    code will never get back to the OS idle loop where the hardware
                    power saving measures are invoked."
Format()            NumberFormat & NumberFormat2 [see documentation]
InputBox($)         InputList(Items as List, Title, CheckedItem as Int) as Int
can list multiple       Shows list of choices with radio buttons. Returns index.
choices for which       CheckedItem is the default.
the user enters a   InputMultiList(Items as List, Title) As List
number to choose.       User can select multiple items via checkboxes.
                        Returns list with the indexes of boxes checked.
MsgBox "text"       MsgBox("text", "title")
i=MsgBox()          MsgBox2(Message, Title, Positive, Cancel, Negative, Icon) as Int
                        Displays three buttons with text to display for buttons
                           (Positive, Cancel, Negative)
                        Icon is displayed near the title and is specified like:
                           LoadBitmap(File.DirAssets, "[filename].gif")
   ---              ToastMessageShow(text, b) [where b=True for long duration]
Following is a Sub from Pfriemler which acts like InputBox:
Sub InputBox(Prompt As String, Title As String, Default As String, Hint As String) As String
    Dim Id As InputDialog
    Id.Hint = Hint
    Id.Input = Default
    ret = Id.Show(Prompt, Title, "OK", "","Abbrechen", Null)
    If ret = -1 Then Return Id.Input Else Return ""
End Sub

Rnd is < 1          Rnd(min, max) is integer >= min to < max
Rnd(-#)             RndSeed(#) - causes Rnd to generate the same random number series
                                 for the same # entered.
Randomize           Not needed in B4A to randomize Rnd.
Round(n)            same, or Round2(n, x) where x=number of decimal places

i = Val(string)     If IsNumber(string) Then i = string Else i = 0 --
                    An attempt to use i=string "throws an exception" if the string is
                    not numbers, even if the string starts with numbers. For example,
                    t = "10:45"
                    i = Val(t) sets i=10 but causes an error in B4A.
                    Instead,
                    i = t.SubString2(0, 2) = 10
control.SetFocus    view.RequestFocus
n / 0 : error       n / 0 = 2147483647 -- B4A does not "throw an exception" for
                       division by 0, but it does return 2147483647 no matter
                       what the value of "n" is.
x = Shell("...")    See "Intent". This is not a complete replacement, but allows
                       code such as the following from the B4A forum (by Erel):
                    Dim pi As PhoneIntents
                    StartActivity (pi.OpenBrowser("[URL]file:///sdcard/yourfile.html[/URL]"))
t = Timer           t = DateTime.Now ' Ticks are number of milliseconds since 1-1-70

TabIndex:
--------
In VB6, TabIndex can be set to control the order in which controls get focus
when Tab is pressed. According to Erel, in B4A:
   "Android handles the sequence according to their position. You can set
    EditText.ForceDone = True in all your EditTexts. Then catch the
    EditText_EnterPressed event and explicitly set the focus to the next
    view (with EditText.RequestFocus)."

Setting Label Transparency:
--------------------------
Properties - Back Style        Designer - Drawable - Alpha

Constants:
---------
""                  Quote = Chr$(34)
vbCr                CRLF = Chr$(10)
vbCrLf              none

String "Members":
----------------
VB6 uses a character position pointer starting with 1.
B4A uses a character Index pointer starting with 0.
        VB6                        B4A
Mid$("abcde", 1, 1) = "a" = letter array index 0 -- "a" = "abcde".CharAt(0)
Mid$("abcde", 2, 1) = "b" = letter array index 1
Mid$("abcde", 3, 1) = "c" = letter array index 2
Mid$("abcde", 4, 1) = "d" = letter array index 3
Mid$("abcde", 5, 1) = "e" = letter array index 4
     VB6                               B4A
     ===                               ===
Mid$(text, n, 1)                    text.CharAt(n-1)
Mid$(text, n)                       text.SubString(n-1)
Mid$(text, n, x) [x=length wanted]  text.SubString2(n-1, n+x-1) [n+x-1=end position]
Mid$(text, n, x) = text2            text = text.SubString2(0, n-2) & _
                                           text2.SubString2(0, x-1) & _
                                           text.SubString(n-1 + z)  where...
                                             z = Min(x, text2.length)
Left$(text, n)  [n=num.of chars.]   text.SubString2(0, n)
Right$(text, n)                     text.SubString(text.Length - n + 1)
If a$ = b$...                       If a.CompareTo(b)...
If Right$(text, n) = text2...       If text.EndsWith(text2)...
If Left$(text, n) = text2...        If text.StartsWith(text2)...
If Lcase$(text) = Lcase$(text2)...  If text.EqualsIgnoreCase(text2)...
Following are some subs from NeoTechni which take the place of VB6
string functions:
Sub Left(Text As String, Length As Long)As String
   If length>text.Length Then length=text.Length
   Return text.SubString2(0, length)
End Sub
Sub Right(Text As String, Length As Long) As String
   If length>text.Length Then length=text.Length
   Return text.SubString(text.Length-length)
End Sub
Sub Mid(Text As String, Start As Int, Length As Int) As String
   Return text.SubString2(start-1,start+length-1)
End Sub
Sub Split(Text As String, Delimiter As String) As String()
   Return Regex.Split(delimter,text)
End Sub

x = Len(text)                       x = text.Length
text = Replace(text, str, str2)     text.Replace(str, str2)
Lcase(text)                         text.ToLowerCase
Ucase(text)                         text.ToUpperCase
Trim(text)                          text.Trim
  (no LTrim or RTrim in B4A)
Instr(text, string)                 text.IndexOf(string)
Instr(int, text, string)            text.IndexOf2(string, int)
                                       Returns -1 if not found.
                                       Returns char. index, not position.
                                       Starts search at "int".
InStrRev(text, str, start, case)    text.LastIndexOf(string)
  Searches from end of string,      text.LastIndexOf(string, start)
    optionally from "start".           Cannot specify case sensitivity.
  case = 0 = case-sensitive
  case = 0 = case-insensitive
                                    A boolean form of IndexOf is -
                                    If text.Contains(string) = True Then...
If Lcase$(x) = Lcase$(y)...         If x.EqualsIgnoreCase(y)...
text = Left$(text, n) & s &         text.Insert(n, s)
          Right$(Text, y)
Asc(s) [where s = a character]      same

Error Trapping:
--------------
VB6:
===
Sub SomeSub
   On [Local] Error GoTo ErrorTrap
      ...some code...
   On Error GoTo 0 [optional end to error trapping]
   ...optional additional code...
   Exit Sub [to avoid executing ErrorTrap code]
ErrorTrap:
   ...optional code for error correction...
   Resume [optional: "Resume Next" or "Resume [line label]".
End Sub
B4A:
===
Sub SomeSub
   Try
      ...some code...
   Catch [only executes if error above]
      Log(LastException) [optional]
      ...optional code for error correction...
   End Try
   ...optional additional code...
End Sub
WIth B4A, if you get an error caught in the middle of a large subroutine, you can
NOT make a correction and resume within the code you were executing. Only the code
in "Catch" gets executed, plus any code following "End Try".
Try-Catch in place of GoTo:
--------------------------
Try-Catch can be used as a substitute for GoTo [line label] for forward, but not
backward, jumps. It cannot be used to replace GoSub, for which B4A has no equivalent.
Start the code with "Try" and replace the [line label] with "Catch".
Replace "GoTo [line label]" with code which will create an exception, which causes
a jump to "Catch", such as OpenInput("bad path", "bad filename").

"Immediate Window" vs "Logs" Tab
--------------------------------
Comments, variable values, etc., can be displayed in VB6's Immediate
Window by entering into the code "Debug.Print ...".
In the B4A environment, the Logs tab on the right side of the IDE is a
way to show the values of variables, etc., while the code is running.
Both VB6 and (now) B4A allow single-stepping through the code while it
is running and viewing the values of variables. VB6 also allows changing
the value of variables, changing the code, jumping to other lines from
the current line, etc. Because B4A runs on a PC while the app runs on
a separate device, B4A is currently unable to duplicate all of these
VB6 debug features.
 
Last edited:

Housefly

Member
Licensed User
CInt in roundup of VB6 to B4A doesn't seem to be working.

The following doesn't seem to be supported. would be cool if it did. :)

B4X:
General:
-------

CInt

so for fun I just used it in my naming conventions, reserved word (in VB) be darned! :p

it casts to the value I want.. perhaps someone knows a better way?

B4X:
Dim CInt as Int

...

CInt = (ListView.Height / ListView.SingleLineLayout.ItemHeight)
 
Last edited:

shb777

Active Member
Licensed User
The best thing about vb 6 was the forms, and controls you could drag onto them, to quickly write programs. Does basic4android have that? That's what we need.
 

Z80CPU

Member
Licensed User
Silly Question

i am OLD school when it comes to programming basic....line numbers and all... ;)

moved from basic for dos to visual basic now to B4A.

my questions are:

in visual basic you have:

#1 - a= "123" + "456" -> a="123456"

#2 - a=chr(65) + chr(66) -> a="ab"

#3 - if x>2 then goto somelabel

#4 -
a=time$: a=a+10
:label
doevents
if time$<a then goto label else goto timesup


#5 - is there a B4A ver of 'doevents' and 'sleep'?


#6 - does the ability to NOT declare variables at start of app, just declare them 'on the fly' except for public/static varis.

example, in vb6, i can write (of course, i must 'turn off' declare in options somewhere):

a="+":b=2:c=3
d=trim(str(b)) + a+trim(str(c))+" = 5"
msgbox d ( d = "2+3 = 5")


all on the 'fly'

what would be the B4A versions of these?

also, is there a more 'complete' crossover guide for vb6 -> B4A than the short one that is listed here and i think in the manual?



you're more than welcome to just email me if you wish:

z80cpu at google's email


thanks for helping a putz VERY MUCH!

:)
 

NJDude

Expert
Licensed User
#1 - a= "123" + "456" -> a="123456"

#2 - a=chr(65) + chr(66) -> a="ab"
These are the B4A equivalents:
B4X:
a= "123" & "456

#3 - if x>2 then goto somelabel
There's no GOTO in B4A

#4 -
a=time$: a=a+10
:label
doevents
if time$<a then goto label else goto timesup


#5 - is there a B4A ver of 'doevents' and 'sleep'?
As explained above there's no GOTO, but there's DoEvents, also, there's no Sleep, you have to use TIMERS
#6 - does the ability to NOT declare variables at start of app, just declare them 'on the fly' except for public/static varis.

example, in vb6, i can write (of course, i must 'turn off' declare in options somewhere):

a="+":b=2:c=3
d=trim(str(b)) + a+trim(str(c))+" = 5"
msgbox d ( d = "2+3 = 5")
Yes, you don't have to declare variables if you don't want to, B4A will default the type to STRING.

For more info I recommend you read the manuals, look at the links on my signature below, especially the DOCUMENTATION one, you will find 2 documents on the top of the screen.

Welcome to B4A!.
 

Beja

Expert
Licensed User
Thanks Klaus so much..

@LucaMs
does this mean that B is the compliment of A.. also this is good because I work on electronics.
B4X:
Dim A, B As Byte
B = 255
A = Bit.Not(B)Log("A = " & A)
'A = 00
 

Beja

Expert
Licensed User
Is this the only use.. In fact now I want to define a value as true or false (not binary negation)
 

Beja

Expert
Licensed User
Button1_Click
DoorOpen = NOT(DoorOpen)

is that correct?
 
Top