Android Question Getting data from [B4X] CLVExpandable

[Sergey_New]

Sub Activity_Create(FirstTime As Boolean)
    Activity.LoadLayout("1")
    expandable.Initialize(clv1)
    For i = 1 To 20
        Dim p As B4XView = CreateItem(Rnd(0xFF000000, 0xFFFFFFFF), "Item #" & i, Rnd(100dip, 300dip) + 60dip)
        clv1.Add(p, expandable.CreateValue(p, "value" & i))
    Next
End Sub

Tell me how to get the passed "value" & i on the clv1_ItemClick event?

Sub clv1_ItemClick (Index As Int, Value As Object)
    expandable.ToggleItem(Index)
    '???
End Sub

 

[stevel05]

Try either:

    Log(expandable.GetValue(Index))
    
    'Or
    
    Dim V As ExpandableItemData = Value
    Log(V.Value)

 

[Sergey_New]

stevel05, thanks a lot!

 

[Sergey_New]

I am trying to pass multiple values with:

Type PersonData (name As String, sex As String)

Spoiler

Sub Activity_Create(FirstTime As Boolean)
    Activity.LoadLayout("1")
    expandable.Initialize(clv1)
    Dim psd As PersonData
    psd.Initialize
    psd.name="name1"
    psd.sex="M"
    Dim p As B4XView
    p=CreateItem(Rnd(0xFF000000, 0xFFFFFFFF), "ItemM", Rnd(100dip, 300dip) + 60dip)
    clv1.Add(p, expandable.CreateValue(p, psd))
    psd.Initialize
    psd.name="name2"
    psd.sex="F"
    p=CreateItem(Rnd(0xFF000000, 0xFFFFFFFF), "ItemF", Rnd(100dip, 300dip) + 60dip)
    clv1.Add(p, expandable.CreateValue(p, psd))
End Sub

I get the same values for two lines:

Spoiler

Sub clv1_ItemClick (Index As Int, Value As Object)
    expandable.ToggleItem(Index)
    Dim V As ExpandableItemData = Value
    Dim psd As PersonData=V.Value
    Log(psd.name)
    Log(psd.sex)
End Sub

How to fix?

 

[LucaMs]

You have to declare a new PersonData (line Dim psd As PersonData before psd.Initialize)

 

[klaus]

Try to add Dim p As B4XView for each new item.

 

[LucaMs]

... too!

 

[Sergey_New]

The LucaMs variant works.
Thanks!

 

[Sergey_New]

... too!

This advice does not work

 

[LucaMs]

This advice does not work

To have 2 items, both are needed, new panel (B4XView) and new PersonData variable.

 

[LucaMs]

Sub AddItem(Name As String, Sex As String)
    Dim psd As PersonData
    psd.Initialize
    psd.name=Name
    psd.sex=Sex
    Dim p As B4XView
    p=CreateItem(Rnd(0xFF000000, 0xFFFFFFFF), "ItemM", Rnd(100dip, 300dip) + 60dip)
    clv1.Add(p, expandable.CreateValue(p, psd))
End Sub

 

[Sergey_New]

Got it, thank you!
But the first tip worked.