B4J Question How to add an icon to a button via code

[ivan.tellez]

Its is possible to add an Icon from the Files folder to a button created in code?

This works with files outside the compiled jar:

  Dim tButton As Button
  tButton.Initialize("RibbonButton")
  tButton.Style = "-fx-background-position: center top;  -fx-background-repeat: no-repeat;  -fx-background-image: url('file:///z:/save.png');"
  tButton.Alignment = "BOTTOM_CENTER"
  tSection.AddNode(tButton, 0, 0, 70, 70)

But, how to use images added to the files tab?

Thanks

 

[Roycefer]

Files added to the Files tab will be found in File.DirAssets. You can copy them to a temporary folder and then load them from there.

 

[jmon]

Your code works just load the path of the image this way:

$"-fx-background-image: ${File.GetUri(File.DirAssets, "save.png")};"$

Otherwise, this method is my prefered one:

(Requires JavaObject):

Public Sub NodeSetImage(n As Node, ImageDir As String, ImageFileName As String, Width As Int, Height As Int, ContentDisplay As String)
    'Check that path and filename are valid:
    If ImageDir = "" Or ImageFileName = "" Then Return
    'Set the button image:
    Dim iv As ImageView
    Dim nJo As JavaObject = n
    iv = nJo.RunMethod("getGraphic", Null)
    If iv.IsInitialized Then
        iv.SetImage(fx.LoadImageSample(ImageDir, ImageFileName, iv.Width, iv.Height))
    Else
        iv.Initialize("")
        If Width > -1 Then
            iv.Width = Width
        End If
        If Height > -1 Then
            iv.Height = Height
        End If
        iv.SetImage(fx.LoadImageSample(ImageDir, ImageFileName, iv.Width, iv.Height))
        nJo.RunMethod("setGraphic", Array(iv))
        Dim cd As JavaObject
        cd.InitializeStatic("javafx.scene.control.ContentDisplay")
        nJo.RunMethod("setContentDisplay", Array(cd.RunMethod("valueOf", Array(ContentDisplay))))
    End If
End Sub

Where ContentDisplay is any of the string values here : https://docs.oracle.com/javase/8/javafx/api/javafx/scene/control/ContentDisplay.html
i.e : "LEFT"

Works for both if the image was already set in the designer, or buttons or other nodes without images set.

Works for buttons, labels, titledPanes.

jmon.

 

[Erel]

You can load a file from the assets folder with File.GetUri:

Dim b As Button
b.Initialize("b")
b.Style = $"-fx-background-position: center top;
  -fx-background-repeat: no-repeat;
  -fx-background-image: url('${File.GetUri(File.DirAssets, "smiley.gif")}');"$

MainForm.RootPane.AddNode(b, 10, 10, 100, 100)