New feature: Resumable Subs - simpler asynchronous programming

Martin Larsen · Apr 3, 2017

billzhan said:
Will it be possible to implement timeout?

You can set a variable with a timestamp before entering the loop and simply break the loop when the desired time has elapsed.

billzhan · Apr 3, 2017

Get it. Tks

Erel · Apr 3, 2017

First example with Wait For:

Code: Copy

Sub AppStart (Form1 As Form, Args() As String)
   MainForm = Form1
   MainForm.RootPane.LoadLayout("1")
   gmap.Initialize2("gmap", Null, "xxxxxxxxYNLkvBkQ2LhGujrM")
   Pane1.AddNode(gmap.AsPane, 0, 0, Pane1.Width, Pane1.Height)
   MainForm.Show
  
   Wait For Gmap_Ready '<----------------
  
   btnResetMap.Enabled = True
   btnJumpToEiffel.Enabled = True
   For i = 1 To 10
      gmap.AddMarker(10 * i, 10 * i, "Marker #" & i)
   Next
End Sub

This is equivalent to handling the GoogleMap_Ready event in a different sub. The advantage is that you handle everything in the same sub and you can access the local variables.

And a bit more sophisticated usage:
A method that downloads an image and sets it to an ImageView:

Code: Copy

Sub AppStart (Form1 As Form, Args() As String)
   MainForm = Form1
   MainForm.RootPane.LoadLayout("1")
   MainForm.Show
   SetImage(ImageView1, "https://cdn.pixabay.com/photo/2016/09/04/08/46/butterfly-1643510_960_720.jpg")
   SetImage(ImageView2, "https://cdn.pixabay.com/photo/2017/03/29/07/29/windmill-2184353__340.jpg")
   SetImage(ImageView3, "https://cdn.pix3abay.com/photo/2017/04/02/09/08/bulldozer-2195329__340.jpg")
End Sub

Sub SetImage(iv As ImageView, link As String)
   'show a progress indicator while downloading
   Dim pb As ProgressIndicator
   pb.Initialize("")
   Dim parent As Pane = iv.Parent
   parent.AddNode(pb, iv.Left, iv.Top, iv.Width, iv.Height)
   pb.Progress = -1
   Dim j As HttpJob
   j.Initialize("j", Me)
   j.Download(link)
   'wait for JobDone event
   Wait For (j) JobDone(j As HttpJob)
   'Remove the progress indicator
   pb.RemoveNodeFromParent
   If j.Success Then
     iv.SetImage(j.GetBitmap)
   Else
     Log(j.ErrorMessage)
     iv.SetImage(fx.LoadImage(File.DirAssets, "Sorry-image-not-available.png"))
   End If
End Sub

Example of downloading three images one after another (a very common question in the forum):

Code: Copy

Sub MakeSeveralDownloadsSequentially
   Dim j As HttpJob
   j.Initialize("j", Me)
   j.Download("https://cdn.pixabay.com/photo/2016/09/04/08/46/butterfly-1643510_960_720.jpg")
   Wait For JobDone(j As HttpJob)
   If j.Success Then
     Log("First image downloaded successfully")
   End If
   j.Release

   j.Initialize("j", Me)
   j.Download("https://cdn.pixabay.com/photo/2017/03/29/07/29/windmill-2184353__340.jpg")
   Wait For JobDone(j As HttpJob)
   If j.Success Then
     Log("Second image downloaded successfully")
   End If
   j.Release

   j.Initialize("j", Me)
   j.Download("https://cdn.pixabay.com/photo/2017/04/02/09/08/bulldozer-2195329__340.jpg")
   Wait For JobDone(j As HttpJob)
   If j.Success Then
     Log("Third image downloaded successfully")
   End If
   j.Release
End Sub

Erel · Apr 3, 2017

Yes, you can use Sleep instead of CallSubDelayed:
Instead of:

Code: Copy

Sub Rec (i as int, lim as int)
   if i < lim then
     dosomething
     callsubdelayed3(me,"rec",i+1,50)
   end if
end sub

You can do:

Code: Copy

Sub Rec
For i = 1 to 1000
  DoSomething
  Sleep(0)
  'Or sleep every 10 iterations
  If i Mod 10 = 0 Then
    Sleep(0)
  End If
Next
End Sub

No need to split the work. You can handle it all inside the sub.

Erel · Apr 3, 2017

Sleep(0) means that it sleeps for the shortest possible period. It is very similar to CallSubDelayed. It will allow all messages in the internal message queue to be processed (and keep the UI responsive).

Erel · Apr 4, 2017

Not exactly.
Sleep pauses the current execution and resumes it after the specified period.
Wait For pauses the current execution and resumes it when the event is raised.

aaronk · Apr 5, 2017

Does this mean I can do something like:

Code: Copy

Socket.connect(IP,Port,0)
Sleep(4000)
If socket.connected = False Then
    log("failed to connect")
  else
    log("connected OK")
End if

Based on the above example, connect to a TCP/IP socket then wait 4 seconds, and then log if it connected or not.

Is that what this sleep feature does ?

I know I could log once it connects or when it fails etc. but just using the above as an example.

I see that it will be added to B4J first and probably be available in May or June, what about B4A & B4i.. Any ETA when it will be added to them as well providing it is successful in B4J in May/June ?

Erel · Apr 5, 2017

aaronk said:
Does this mean I can do something like:

Yes, but it is better to use Wait For in this case:

Code: Copy

Socket.Connect(IP, Port, 4000)
Wait For Socket_Connected (Success As Boolean)
If Success Then 
 ...
Else
 ...
End If

aaronk said:
what about B4A & B4i.. Any ETA when it will be added to them as well providing it is successful in B4J in May/June ?

It will probably be available in B4A and B4i in June or July.

Erel · Apr 5, 2017

Quiz:
What is the output of this code:

Code: Copy

'non-ui project!!!
Sub AppStart (Args() As String)
   DoSomething
   StartMessageLoop
   Log("done!")
End Sub

Sub DoSomething
   For i = 1 To 10
     Log(i)
     Sleep(100)
   Next
   StopMessageLoop
End Sub

And this one:

Code: Copy

'non-ui project!!!
Sub AppStart (Args() As String)
   For i = 1 To 10
     Log(i)
     Sleep(100)
   Next
   StartMessageLoop
   Log("done!")
End Sub

Tip: Sleep ≈ Return

LucaMs · Apr 5, 2017

done!
1
2
3
4
5
6
7
8
9
10

Both

Martin Larsen · Apr 5, 2017

Erel said:
StartMessageLoop

What is the purpose of StartMessageLoop and StopMessageLoop?

Erel · Apr 5, 2017

Luca you need to think again...

Martin Larsen said:
What is the purpose of StartMessageLoop and StopMessageLoop?

https://www.b4x.com/android/forum/threads/non-ui-applications.34657/#content

LucaMs · Apr 5, 2017

Erel said:
Luca you need to think again...

I think but my two neurons do not

narek adonts · Apr 5, 2017

Erel said:

Quiz:
What is the output of this code:

Code: Copy

'non-ui project!!!
Sub AppStart (Args() As String)
   DoSomething
   StartMessageLoop
   Log("done!")
End Sub

Sub DoSomething
   For i = 1 To 10
     Log(i)
     Sleep(100)
   Next
   StopMessageLoop
End Sub

And this one:

Code: Copy

'non-ui project!!!
Sub AppStart (Args() As String)
   For i = 1 To 10
     Log(i)
     Sleep(100)
   Next
   StartMessageLoop
   Log("done!")
End Sub

Tip: Sleep ≈ Return

1.

1
2
3
4
5
6
7
8
9
10

2.

1
2
3
4
5
6
7
8
10
Done

LordZenzo · Apr 5, 2017

1: e 2:

1
done
2
3
4
5
6
7
8
9
10

Toley · Apr 5, 2017

1 done 2 3 4 5 6 7 8 9 10
1 2 3 4 5 6 7 8 9 10 done

LucaMs · Apr 5, 2017

BINGO

LucaMs · Apr 6, 2017

Erel said:
Luca you need to think again

I'm trying right now (2 am!)

First "project":

Code: Copy

'non-ui project!!!
Sub AppStart (Args() As String)
   DoSomething
   StartMessageLoop
   Log("done!")
End Sub

Sub DoSomething
   For i = 1 To 10
     Log(i)
     Sleep(100)
   Next
   StopMessageLoop
End Sub

1) "app" starts;
2) call DoSomething;
3) first log: 1:
4) Sleep 100 means: "system, do whatever you want, but after 100 (ms? I hope, I have to read again) give me the control again:
5) StartMessageLoop - I thought that this was to be the last statement of AppStart routine, ie that subsequent instructions were not be executed (or at least only after a StopMessageLoop);
6) log done!, because I think that StartMessageLoop takes less than 100ms (but what if not? What if I set Sleep(1)?)
7) log the rest, from 2 to 10, then StopMessageLoop.

So the log should be: 1, done!, 2,3,4,5,6,7,8,9,10.

------------------

Second "project":

Code: Copy

'non-ui project!!!
Sub AppStart (Args() As String)
   For i = 1 To 10
     Log(i)
     Sleep(100)
   Next
   StartMessageLoop
   Log("done!")
End Sub

1) log 1;
2) Sleep for 100ms, don't stopping the thread (main); but there are no other subs to be executed, then wait 100ms and execute Next.

So the log should be: 1,2,3,4,5,6,7,8,9,10, (StartMessageLoop), done!

[same as @Toley's "result" #79]

[Now I have one neuron only; the other is dead

]

Erel · Apr 6, 2017

Maybe it was an unfair quiz

Rules (non-ui projects):
- Code after StartMessageLoop will only be executed after StopMessageLoop is called.
- Events go through the message queue (there are some exceptions to this rule).
- Resumable subs work in the same way that events work. This means that resumable subs will only be resumed when the owner thread (main thread in most cases) processes the message loop.
- A call to Sleep or Wait For always causes the thread to return from the current sub.
- Non-ui programs end after the thread returns from AppStart.

The difference between non-ui programs to ui programs or B4A / B4i programs is that the call to StartMessageLoop happens internally.
Similar to this pseudo code:

Code: Copy

Sub InternalAppStart
 AppStart(...)
 StartMessageLoop
End Sub

Answer 1:
1, 2, 3, 4, 5, 6, 7, 8, 9, 10, done!

Answer 2:
1

LucaMs · Apr 6, 2017

Erel said:
- Code after StartMessageLoop will only be executed after StopMessageLoop is called.

LucaMs said:
I thought that this was to be the last statement of AppStart routine, ie that subsequent instructions were not be executed (or at least only after a StopMessageLoop);

... and since I thought this, I wanted tried and it seems that it is not so: a log was executed after StartMessageLoop, I did not wrote StopMessageLoop and I did not stop the server

New feature: Resumable Subs - simpler asynchronous programming

Active Member

Active Member

B4X founder

B4X founder

B4X founder

B4X founder

Well-Known Member

B4X founder

B4X founder

Expert

Active Member

B4X founder

Expert

Well-Known Member

Well-Known Member

Active Member

Expert

Expert

B4X founder

Expert