Android Question Howto add a "type record" in a list ?

[CR95]

I try to resume my issue in the following example :

Type TestType(Year As String)
Dim Rec As TestType
Rec.Initialize
Dim myList As List
myList.Initialize
Rec.Year = "1900"
myList.Add(Rec)
Rec.Year = "1950"
myList.Add(Rec)
Rec.Year = "2000"
myList.Add(Rec)
For i = 0 To myList.Size-1
Dim z As TestType
z = myList.Get(i)
Log(z)
Next

Log result -> all records are identical to the last loaded

[IsInitialized=true, Year=2000]
[IsInitialized=true, Year=2000]
[IsInitialized=true, Year=2000]

Please could you tell me what is wrong ?

 

[LucaMs]

You must create and initialize a new object of that type each time.

Dim Rec As TestType
Rec.Initialize
Rec.Year = "1900"
myList.Add(Rec)

Dim Rec As TestType
Rec.Initialize
Rec.Year = "1950"
myList.Add(Rec)

To publish source code, use:

 

[Chris2]

If you hover over the type declaration the IDE will offer to make you a 'CreateType...' sub:

Public Sub CreateTestType (Year As String) As TestType
    Dim t1 As TestType
    t1.Initialize
    t1.Year = Year
    Return t1
End Sub

Then you can simplify the process of creating & initialising TestType objects:

Dim Rec As TestType = CreateTestType("1900")
myList.Add(Rec)

'Or put them straight in the list

myList.Add(CreateTestType("1900"))

 

[CR95]

Thanks
Things are so easy....when one knows the solution

 

[kimstudio]

It is important to know why the Initialize is needed here for each List.Add()...

 

[CR95]

@kimstudio
Yes. Why the Initialize is needed EACH TIME ?

 

[LucaMs]

@kimstudio
Yes. Why the Initialize is needed EACH TIME ?

To create a NEW object each time.

 

[kimstudio]

@kimstudio
Yes. Why the Initialize is needed EACH TIME ?

I should say Dim & Initialize is needed each time.

I can only guess it using C++ way: an object with dim/initialize is created in the memory, there is a pointer pointing to this object in the memory, List.Add() will only add this pointer in list. Without dim/initialize the object's property's value is changed each time but it is the same object, so same pointer, List.Add() add three times same pointer to same object. Although the var name is same, each dim/initialize will create a new object/instance.

 

[CR95]

Thanks for the explanations
To be honest, I don't think I have the level to understand all the "internals". But I am happy to be able to use them.

 

[LucaMs]

Thanks for the explanations
To be honest, I don't think I have the level to understand all the "internals". But I am happy to be able to use them.

It is not difficult. Custom types are like classes.

If you have created a class, then you must create objects of the type of that class, creating a variable and initializing it; only at that point will you have an object, which you could add to a List or any other structure (Map, for example).

It's the same thing with custom types.


The editor, as @Chris2 wrote, helps you by generating a function to create a new object of the type you created.

 

[Mahares]

Since we are beating this subject to death, here is a complete example:

Sub Class_Globals
    Private Root As B4XView
    Private xui As XUI
    Type TestType(Year As String)
End Sub

Public Sub Initialize
'    B4XPages.GetManager.LogEvents = True
End Sub

'This event will be called once, before the page becomes visible.
Private Sub B4XPage_Created (Root1 As B4XView)
    Root = Root1
    Dim myList As List
    myList.Initialize
    myList.AddAll(Array(CreateTestType (1900), CreateTestType (1950), CreateTestType (2000)))
    
    For Each z As TestType In myList
        Log(z.Year)
    Next
End Sub

Public Sub CreateTestType (Year As String) As TestType
    Dim t1 As TestType
    t1.Initialize
    t1.Year = Year
    Return t1
End Sub

 

[LucaMs]

myList.AddAll

I don't like AddAll; this will limit the use of the List.

 

[aeric]

If the Type is not Initialize then the fields will remained as Null object.
If it has been initialized, the String field will have a default value of empty String.
This is my observation.

 

[Mahares]

I don't like AddAll; this will limit the use of the List.

Why. If you do not like something, you have to explain why.
This still works:

Dim myList As List
    myList.Initialize
    myList.AddAll(Array(CreateTestType (1900), CreateTestType (1950), CreateTestType (2000)))
    myList.Add(CreateTestType (2020))

 

[LucaMs]

Why. If you do not like something, you have to explain why.

Uhm... because I seem to remember that until some time ago using AddAll the List became a static array, some List methods no longer worked (like InsertAt, RemoveAt).

Now they work; I think things have changed and, what's much worse, I think I've already written this in the past and gotten a response from Erel (who I'm about to look for)

 

[LucaMs]

I think I've already written this in the past and gotten a response from Erel (who I'm about to look for)

Hard to find it. Maybe I remembered this (and the previous one)? I do not think so.

 

[LucaMs]

Maybe I remembered this (and the previous one)?

Maybe yes. I just tried using B4J v. 7 (!) and AddAll hasn't changed since then.

Those limits were due to the way of assignment:

lstXXX = Array(...

not to AddAll.

 

[Mahares]

using AddAll the List became a static array

I will not hold it against you. You are still a powerhouse
Something like this becomes static and will not work:

Dim myList As List = Array(1900, 1950, 2000)
    myList.Add(2020)

 

[LucaMs]

I will not hold it against you. You are still a powerhouse
Something like this becomes static and will not work:

Dim myList As List = Array(1900, 1950, 2000)
    myList.Add(2020)

Yes, that's what's written in that thread, from 2 years ago.
I had confused the two things.

 

[aeric]

Maybe just me. I think the choice of keyword AddAll is a bit misleading. It gave me impression that you add all the items and no longer can add more. Maybe Add2 or AddMore are better.