B4J Question [SOLVED] Tick beside menu option at JSystray - TrayIcon ?

[Magma]

Hi there...

is it possible to have tick beside a menu option at tray icons like these or more simple... any idea?

Thanks for your answers !!!

 

[Erel]

Sub Class_Globals
    Private Root As B4XView
    Private xui As XUI
    Private tray As SystemTray
End Sub

Public Sub Initialize
'    B4XPages.GetManager.LogEvents = True
End Sub

'This event will be called once, before the page becomes visible.
Private Sub B4XPage_Created (Root1 As B4XView)
    Root = Root1
    Root.LoadLayout("MainPage")
    tray.Initialize
    Dim ti As TrayIcon
    ti.Initialize("ti", xui.LoadBitmap(File.DirAssets, "45973.jpg"), Null)
    tray.AddTrayIcon(ti)
    Dim PopupMenu As JavaObject
    PopupMenu.InitializeNewInstance("java.awt.PopupMenu", Null)
    Dim listener As Object = PopupMenu.CreateEventFromUI("java.awt.event.ItemListener", "MenuItemStateChanged", Null)
    For Each s As String In Array("Item 1", "Item 2", "Item 3")
        Dim MenuItem As JavaObject
        Dim Checked As Boolean = True
        MenuItem.InitializeNewInstance("java.awt.CheckboxMenuItem", Array(s, Checked))
        MenuItem.RunMethod("addItemListener", Array(listener))
        PopupMenu.RunMethod("add", Array(MenuItem))
    Next
    ti.As(JavaObject).RunMethod("setPopupMenu", Array(PopupMenu))
End Sub

Private Sub MenuItemStateChanged_Event (MethodName As String, Args() As Object) As Object
    Dim ItemEvent As JavaObject = Args(0)
    Dim MenuItem As JavaObject = ItemEvent.RunMethod("getItemSelectable", Null)
    Dim Text As String = MenuItem.RunMethod("getLabel", Null)
    Dim checked As Boolean = MenuItem.RunMethod("getState", Null)
    Log(Text & ": " & checked)
    Return Null
End Sub

 

[Erel]

BTW, these two lines deserve some attention:

 Dim Checked As Boolean = True
 MenuItem.InitializeNewInstance("java.awt.CheckboxMenuItem", Array(s, Checked))

This is an example of a "self documenting code".

It is much more maintainable and more clear than:

 MenuItem.InitializeNewInstance("java.awt.CheckboxMenuItem", Array(s, True))

The other reasonable option is:

 MenuItem.InitializeNewInstance("java.awt.CheckboxMenuItem", Array(s, True)) 'last parameter sets the initial checked state.

I prefer the first option.